git.squeep.com Git - akkoma/blob - lib/pleroma/jobs.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Jobs do
   6   @moduledoc """
   7   A basic job queue
   8   """
   9   use GenServer
  10
  11   require Logger
  12
  13   def init(args) do
  14     {:ok, args}
  15   end
  16
  17   def start_link do
  18     queues =
  19       Pleroma.Config.get(Pleroma.Jobs)
  20       |> Enum.map(fn {name, _} -> create_queue(name) end)
  21       |> Enum.into(%{})
  22
  23     state = %{
  24       queues: queues,
  25       refs: %{}
  26     }
  27
  28     GenServer.start_link(__MODULE__, state, name: __MODULE__)
  29   end
  30
  31   def create_queue(name) do
  32     {name, {:sets.new(), []}}
  33   end
  34
  35   @doc """
  36   Enqueues a job.
  37
  38   Returns `:ok`.
  39
  40   ## Arguments
  41
  42   - `queue_name` - a queue name(must be specified in the config).
  43   - `mod` - a worker module (must have `perform` function).
  44   - `args` - a list of arguments for the `perform` function of the worker module.
  45   - `priority` - a job priority (`0` by default).
  46
  47   ## Examples
  48
  49   Enqueue `Module.perform/0` with `priority=1`:
  50
  51       iex> Pleroma.Jobs.enqueue(:example_queue, Module, [])
  52       :ok
  53
  54   Enqueue `Module.perform(:job_name)` with `priority=5`:
  55
  56       iex> Pleroma.Jobs.enqueue(:example_queue, Module, [:job_name], 5)
  57       :ok
  58
  59   Enqueue `Module.perform(:another_job, data)` with `priority=1`:
  60
  61       iex> data = "foobar"
  62       iex> Pleroma.Jobs.enqueue(:example_queue, Module, [:another_job, data])
  63       :ok
  64
  65   Enqueue `Module.perform(:foobar_job, :foo, :bar, 42)` with `priority=1`:
  66
  67       iex> Pleroma.Jobs.enqueue(:example_queue, Module, [:foobar_job, :foo, :bar, 42])
  68       :ok
  69
  70   """
  71
  72   def enqueue(queue_name, mod, args, priority \\ 1)
  73
  74   if Mix.env() == :test do
  75     def enqueue(_queue_name, mod, args, _priority) do
  76       apply(mod, :perform, args)
  77     end
  78   else
  79     def enqueue(queue_name, mod, args, priority) do
  80       GenServer.cast(__MODULE__, {:enqueue, queue_name, mod, args, priority})
  81     end
  82   end
  83
  84   def handle_cast({:enqueue, queue_name, mod, args, priority}, state) do
  85     {running_jobs, queue} = state[:queues][queue_name]
  86
  87     queue = enqueue_sorted(queue, {mod, args}, priority)
  88
  89     state =
  90       state
  91       |> update_queue(queue_name, {running_jobs, queue})
  92       |> maybe_start_job(queue_name, running_jobs, queue)
  93
  94     {:noreply, state}
  95   end
  96
  97   def handle_info({:DOWN, ref, :process, _pid, _reason}, state) do
  98     queue_name = state.refs[ref]
  99
 100     {running_jobs, queue} = state[:queues][queue_name]
 101
 102     running_jobs = :sets.del_element(ref, running_jobs)
 103
 104     state = state |> remove_ref(ref) |> maybe_start_job(queue_name, running_jobs, queue)
 105
 106     {:noreply, state}
 107   end
 108
 109   def maybe_start_job(state, queue_name, running_jobs, queue) do
 110     if :sets.size(running_jobs) < Pleroma.Config.get([__MODULE__, queue_name, :max_jobs]) &&
 111          queue != [] do
 112       {{mod, args}, queue} = queue_pop(queue)
 113       {:ok, pid} = Task.start(fn -> apply(mod, :perform, args) end)
 114       mref = Process.monitor(pid)
 115
 116       state
 117       |> add_ref(queue_name, mref)
 118       |> update_queue(queue_name, {:sets.add_element(mref, running_jobs), queue})
 119     else
 120       update_queue(state, queue_name, {running_jobs, queue})
 121     end
 122   end
 123
 124   def enqueue_sorted(queue, element, priority) do
 125     [%{item: element, priority: priority} | queue]
 126     |> Enum.sort_by(fn %{priority: priority} -> priority end)
 127   end
 128
 129   def queue_pop([%{item: element} | queue]) do
 130     {element, queue}
 131   end
 132
 133   defp add_ref(state, queue_name, ref) do
 134     refs = Map.put(state[:refs], ref, queue_name)
 135     Map.put(state, :refs, refs)
 136   end
 137
 138   defp remove_ref(state, ref) do
 139     refs = Map.delete(state[:refs], ref)
 140     Map.put(state, :refs, refs)
 141   end
 142
 143   defp update_queue(state, queue_name, data) do
 144     queues = Map.put(state[:queues], queue_name, data)
 145     Map.put(state, :queues, queues)
 146   end
 147 end