git.squeep.com Git - akkoma/blob - lib/pleroma/http/request_builder.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.HTTP.RequestBuilder do
   6   @moduledoc """
   7   Helper functions for building Tesla requests
   8   """
   9
  10   @doc """
  11   Specify the request method when building a request
  12
  13   ## Parameters
  14
  15   - request (Map) - Collected request options
  16   - m (atom) - Request method
  17
  18   ## Returns
  19
  20   Map
  21   """
  22   @spec method(map(), atom) :: map()
  23   def method(request, m) do
  24     Map.put_new(request, :method, m)
  25   end
  26
  27   @doc """
  28   Specify the request method when building a request
  29
  30   ## Parameters
  31
  32   - request (Map) - Collected request options
  33   - u (String) - Request URL
  34
  35   ## Returns
  36
  37   Map
  38   """
  39   @spec url(map(), String.t()) :: map()
  40   def url(request, u) do
  41     Map.put_new(request, :url, u)
  42   end
  43
  44   @doc """
  45   Add headers to the request
  46   """
  47   @spec headers(map(), list(tuple)) :: map()
  48   def headers(request, header_list) do
  49     header_list = header_list ++ [{"User-Agent", Pleroma.Application.user_agent()}]
  50     Map.put_new(request, :headers, header_list)
  51   end
  52
  53   @doc """
  54   Add custom, per-request middleware or adapter options to the request
  55   """
  56   @spec opts(map(), Keyword.t()) :: map()
  57   def opts(request, options) do
  58     Map.put_new(request, :opts, options)
  59   end
  60
  61   @doc """
  62   Add optional parameters to the request
  63
  64   ## Parameters
  65
  66   - request (Map) - Collected request options
  67   - definitions (Map) - Map of parameter name to parameter location.
  68   - options (KeywordList) - The provided optional parameters
  69
  70   ## Returns
  71
  72   Map
  73   """
  74   @spec add_optional_params(map(), %{optional(atom) => atom}, keyword()) :: map()
  75   def add_optional_params(request, _, []), do: request
  76
  77   def add_optional_params(request, definitions, [{key, value} | tail]) do
  78     case definitions do
  79       %{^key => location} ->
  80         request
  81         |> add_param(location, key, value)
  82         |> add_optional_params(definitions, tail)
  83
  84       _ ->
  85         add_optional_params(request, definitions, tail)
  86     end
  87   end
  88
  89   @doc """
  90   Add optional parameters to the request
  91
  92   ## Parameters
  93
  94   - request (Map) - Collected request options
  95   - location (atom) - Where to put the parameter
  96   - key (atom) - The name of the parameter
  97   - value (any) - The value of the parameter
  98
  99   ## Returns
 100
 101   Map
 102   """
 103   @spec add_param(map(), atom, atom, any()) :: map()
 104   def add_param(request, :query, :query, values), do: Map.put(request, :query, values)
 105
 106   def add_param(request, :body, :body, value), do: Map.put(request, :body, value)
 107
 108   def add_param(request, :body, key, value) do
 109     request
 110     |> Map.put_new_lazy(:body, &Tesla.Multipart.new/0)
 111     |> Map.update!(
 112       :body,
 113       &Tesla.Multipart.add_field(
 114         &1,
 115         key,
 116         Jason.encode!(value),
 117         headers: [{:"Content-Type", "application/json"}]
 118       )
 119     )
 120   end
 121
 122   def add_param(request, :file, name, path) do
 123     request
 124     |> Map.put_new_lazy(:body, &Tesla.Multipart.new/0)
 125     |> Map.update!(:body, &Tesla.Multipart.add_file(&1, path, name: name))
 126   end
 127
 128   def add_param(request, :form, name, value) do
 129     request
 130     |> Map.update(:body, %{name => value}, &Map.put(&1, name, value))
 131   end
 132
 133   def add_param(request, location, key, value) do
 134     Map.update(request, location, [{key, value}], &(&1 ++ [{key, value}]))
 135   end
 136 end