git.squeep.com Git - akkoma/blob - lib/pleroma/http/request_builder.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.HTTP.RequestBuilder do
   6   @moduledoc """
   7   Helper functions for building Tesla requests
   8   """
   9
  10   alias Pleroma.HTTP.Request
  11   alias Tesla.Multipart
  12
  13   @doc """
  14   Creates new request
  15   """
  16   @spec new(Request.t()) :: Request.t()
  17   def new(%Request{} = request \\ %Request{}), do: request
  18
  19   @doc """
  20   Specify the request method when building a request
  21   """
  22   @spec method(Request.t(), Request.method()) :: Request.t()
  23   def method(request, m), do: %{request | method: m}
  24
  25   @doc """
  26   Specify the request method when building a request
  27   """
  28   @spec url(Request.t(), Request.url()) :: Request.t()
  29   def url(request, u), do: %{request | url: u}
  30
  31   @doc """
  32   Add headers to the request
  33   """
  34   @spec headers(Request.t(), Request.headers()) :: Request.t()
  35   def headers(request, headers) do
  36     headers_list =
  37       if Pleroma.Config.get([:http, :send_user_agent]) do
  38         [{"user-agent", Pleroma.Application.user_agent()} | headers]
  39       else
  40         headers
  41       end
  42
  43     %{request | headers: headers_list}
  44   end
  45
  46   @doc """
  47   Add custom, per-request middleware or adapter options to the request
  48   """
  49   @spec opts(Request.t(), keyword()) :: Request.t()
  50   def opts(request, options), do: %{request | opts: options}
  51
  52   # NOTE: isn't used anywhere
  53   @doc """
  54   Add optional parameters to the request
  55
  56   """
  57   @spec add_optional_params(Request.t(), %{optional(atom) => atom}, keyword()) :: map()
  58   def add_optional_params(request, _, []), do: request
  59
  60   def add_optional_params(request, definitions, [{key, value} | tail]) do
  61     case definitions do
  62       %{^key => location} ->
  63         request
  64         |> add_param(location, key, value)
  65         |> add_optional_params(definitions, tail)
  66
  67       _ ->
  68         add_optional_params(request, definitions, tail)
  69     end
  70   end
  71
  72   @doc """
  73   Add optional parameters to the request
  74   """
  75   @spec add_param(Request.t(), atom(), atom(), any()) :: Request.t()
  76   def add_param(request, :query, :query, values), do: %{request | query: values}
  77
  78   def add_param(request, :body, :body, value), do: %{request | body: value}
  79
  80   def add_param(request, :body, key, value) do
  81     request
  82     |> Map.put(:body, Multipart.new())
  83     |> Map.update!(
  84       :body,
  85       &Multipart.add_field(
  86         &1,
  87         key,
  88         Jason.encode!(value),
  89         headers: [{"content-type", "application/json"}]
  90       )
  91     )
  92   end
  93
  94   def add_param(request, :file, name, path) do
  95     request
  96     |> Map.put(:body, Multipart.new())
  97     |> Map.update!(:body, &Multipart.add_file(&1, path, name: name))
  98   end
  99
 100   def add_param(request, :form, name, value) do
 101     Map.update(request, :body, %{name => value}, &Map.put(&1, name, value))
 102   end
 103
 104   def add_param(request, location, key, value) do
 105     Map.update(request, location, [{key, value}], &(&1 ++ [{key, value}]))
 106   end
 107
 108   def convert_to_keyword(request) do
 109     request
 110     |> Map.from_struct()
 111     |> Enum.into([])
 112   end
 113 end