git.squeep.com Git - akkoma/blob - lib/pleroma/http/request_builder.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.HTTP.RequestBuilder do
   6   @moduledoc """
   7   Helper functions for building Tesla requests
   8   """
   9
  10   @doc """
  11   Specify the request method when building a request
  12
  13   ## Parameters
  14
  15   - request (Map) - Collected request options
  16   - m (atom) - Request method
  17
  18   ## Returns
  19
  20   Map
  21   """
  22   @spec method(map(), atom) :: map()
  23   def method(request, m) do
  24     Map.put_new(request, :method, m)
  25   end
  26
  27   @doc """
  28   Specify the request method when building a request
  29
  30   ## Parameters
  31
  32   - request (Map) - Collected request options
  33   - u (String) - Request URL
  34
  35   ## Returns
  36
  37   Map
  38   """
  39   @spec url(map(), String.t()) :: map()
  40   def url(request, u) do
  41     Map.put_new(request, :url, u)
  42   end
  43
  44   @doc """
  45   Add headers to the request
  46   """
  47   @spec headers(map(), list(tuple)) :: map()
  48   def headers(request, h) do
  49     Map.put_new(request, :headers, h)
  50   end
  51
  52   @doc """
  53   Add custom, per-request middleware or adapter options to the request
  54   """
  55   @spec opts(map(), Keyword.t()) :: map()
  56   def opts(request, options) do
  57     Map.put_new(request, :opts, options)
  58   end
  59
  60   @doc """
  61   Add optional parameters to the request
  62
  63   ## Parameters
  64
  65   - request (Map) - Collected request options
  66   - definitions (Map) - Map of parameter name to parameter location.
  67   - options (KeywordList) - The provided optional parameters
  68
  69   ## Returns
  70
  71   Map
  72   """
  73   @spec add_optional_params(map(), %{optional(atom) => atom}, keyword()) :: map()
  74   def add_optional_params(request, _, []), do: request
  75
  76   def add_optional_params(request, definitions, [{key, value} | tail]) do
  77     case definitions do
  78       %{^key => location} ->
  79         request
  80         |> add_param(location, key, value)
  81         |> add_optional_params(definitions, tail)
  82
  83       _ ->
  84         add_optional_params(request, definitions, tail)
  85     end
  86   end
  87
  88   @doc """
  89   Add optional parameters to the request
  90
  91   ## Parameters
  92
  93   - request (Map) - Collected request options
  94   - location (atom) - Where to put the parameter
  95   - key (atom) - The name of the parameter
  96   - value (any) - The value of the parameter
  97
  98   ## Returns
  99
 100   Map
 101   """
 102   @spec add_param(map(), atom, atom, any()) :: map()
 103   def add_param(request, :query, :query, values), do: Map.put(request, :query, values)
 104
 105   def add_param(request, :body, :body, value), do: Map.put(request, :body, value)
 106
 107   def add_param(request, :body, key, value) do
 108     request
 109     |> Map.put_new_lazy(:body, &Tesla.Multipart.new/0)
 110     |> Map.update!(
 111       :body,
 112       &Tesla.Multipart.add_field(
 113         &1,
 114         key,
 115         Jason.encode!(value),
 116         headers: [{:"Content-Type", "application/json"}]
 117       )
 118     )
 119   end
 120
 121   def add_param(request, :file, name, path) do
 122     request
 123     |> Map.put_new_lazy(:body, &Tesla.Multipart.new/0)
 124     |> Map.update!(:body, &Tesla.Multipart.add_file(&1, path, name: name))
 125   end
 126
 127   def add_param(request, :form, name, value) do
 128     request
 129     |> Map.update(:body, %{name => value}, &Map.put(&1, name, value))
 130   end
 131
 132   def add_param(request, location, key, value) do
 133     Map.update(request, location, [{key, value}], &(&1 ++ [{key, value}]))
 134   end
 135 end