git.squeep.com Git - akkoma/blob - lib/pleroma/http/request_builder.ex

   1 defmodule Pleroma.HTTP.RequestBuilder do
   2   @moduledoc """
   3   Helper functions for building Tesla requests
   4   """
   5
   6   @doc """
   7   Specify the request method when building a request
   8
   9   ## Parameters
  10
  11   - request (Map) - Collected request options
  12   - m (atom) - Request method
  13
  14   ## Returns
  15
  16   Map
  17   """
  18   @spec method(map(), atom) :: map()
  19   def method(request, m) do
  20     Map.put_new(request, :method, m)
  21   end
  22
  23   @doc """
  24   Specify the request method when building a request
  25
  26   ## Parameters
  27
  28   - request (Map) - Collected request options
  29   - u (String) - Request URL
  30
  31   ## Returns
  32
  33   Map
  34   """
  35   @spec url(map(), String.t()) :: map()
  36   def url(request, u) do
  37     Map.put_new(request, :url, u)
  38   end
  39
  40   @doc """
  41   Add headers to the request
  42   """
  43   @spec headers(map(), list(tuple)) :: map()
  44   def headers(request, h) do
  45     Map.put_new(request, :headers, h)
  46   end
  47
  48   @doc """
  49   Add custom, per-request middleware or adapter options to the request
  50   """
  51   @spec opts(map(), Keyword.t()) :: map()
  52   def opts(request, options) do
  53     Map.put_new(request, :opts, options)
  54   end
  55
  56   @doc """
  57   Add optional parameters to the request
  58
  59   ## Parameters
  60
  61   - request (Map) - Collected request options
  62   - definitions (Map) - Map of parameter name to parameter location.
  63   - options (KeywordList) - The provided optional parameters
  64
  65   ## Returns
  66
  67   Map
  68   """
  69   @spec add_optional_params(map(), %{optional(atom) => atom}, keyword()) :: map()
  70   def add_optional_params(request, _, []), do: request
  71
  72   def add_optional_params(request, definitions, [{key, value} | tail]) do
  73     case definitions do
  74       %{^key => location} ->
  75         request
  76         |> add_param(location, key, value)
  77         |> add_optional_params(definitions, tail)
  78
  79       _ ->
  80         add_optional_params(request, definitions, tail)
  81     end
  82   end
  83
  84   @doc """
  85   Add optional parameters to the request
  86
  87   ## Parameters
  88
  89   - request (Map) - Collected request options
  90   - location (atom) - Where to put the parameter
  91   - key (atom) - The name of the parameter
  92   - value (any) - The value of the parameter
  93
  94   ## Returns
  95
  96   Map
  97   """
  98   @spec add_param(map(), atom, atom, any()) :: map()
  99   def add_param(request, :body, :body, value), do: Map.put(request, :body, value)
 100
 101   def add_param(request, :body, key, value) do
 102     request
 103     |> Map.put_new_lazy(:body, &Tesla.Multipart.new/0)
 104     |> Map.update!(
 105       :body,
 106       &Tesla.Multipart.add_field(&1, key, Poison.encode!(value),
 107         headers: [{:"Content-Type", "application/json"}]
 108       )
 109     )
 110   end
 111
 112   def add_param(request, :file, name, path) do
 113     request
 114     |> Map.put_new_lazy(:body, &Tesla.Multipart.new/0)
 115     |> Map.update!(:body, &Tesla.Multipart.add_file(&1, path, name: name))
 116   end
 117
 118   def add_param(request, :form, name, value) do
 119     request
 120     |> Map.update(:body, %{name => value}, &Map.put(&1, name, value))
 121   end
 122
 123   def add_param(request, location, key, value) do
 124     Map.update(request, location, [{key, value}], &(&1 ++ [{key, value}]))
 125   end
 126 end