git.squeep.com Git - akkoma/blob - lib/pleroma/http/http.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.HTTP do
   6   @moduledoc """
   7     Wrapper for `Tesla.request/2`.
   8   """
   9
  10   alias Pleroma.HTTP.Connection
  11   alias Pleroma.HTTP.Request
  12   alias Pleroma.HTTP.RequestBuilder, as: Builder
  13   alias Tesla.Client
  14   alias Tesla.Env
  15
  16   require Logger
  17
  18   @type t :: __MODULE__
  19
  20   @doc """
  21   Performs GET request.
  22
  23   See `Pleroma.HTTP.request/5`
  24   """
  25   @spec get(Request.url() | nil, Request.headers(), keyword()) ::
  26           nil | {:ok, Env.t()} | {:error, any()}
  27   def get(url, headers \\ [], options \\ [])
  28   def get(nil, _, _), do: nil
  29   def get(url, headers, options), do: request(:get, url, "", headers, options)
  30
  31   @doc """
  32   Performs POST request.
  33
  34   See `Pleroma.HTTP.request/5`
  35   """
  36   @spec post(Request.url(), String.t(), Request.headers(), keyword()) ::
  37           {:ok, Env.t()} | {:error, any()}
  38   def post(url, body, headers \\ [], options \\ []),
  39     do: request(:post, url, body, headers, options)
  40
  41   @doc """
  42   Builds and performs http request.
  43
  44   # Arguments:
  45   `method` - :get, :post, :put, :delete
  46   `url` - full url
  47   `body` - request body
  48   `headers` - a keyworld list of headers, e.g. `[{"content-type", "text/plain"}]`
  49   `options` - custom, per-request middleware or adapter options
  50
  51   # Returns:
  52   `{:ok, %Tesla.Env{}}` or `{:error, error}`
  53
  54   """
  55   @spec request(atom(), Request.url(), String.t(), Request.headers(), keyword()) ::
  56           {:ok, Env.t()} | {:error, any()}
  57   def request(method, url, body, headers, options) when is_binary(url) do
  58     with uri <- URI.parse(url),
  59          received_adapter_opts <- Keyword.get(options, :adapter, []),
  60          adapter_opts <- Connection.options(uri, received_adapter_opts),
  61          options <- put_in(options[:adapter], adapter_opts),
  62          params <- Keyword.get(options, :params, []),
  63          request <- build_request(method, headers, options, url, body, params),
  64          client <- Tesla.client([Tesla.Middleware.FollowRedirects], tesla_adapter()),
  65          pid <- Process.whereis(adapter_opts[:pool]) do
  66       pool_alive? =
  67         if tesla_adapter() == Tesla.Adapter.Gun do
  68           if pid, do: Process.alive?(pid), else: false
  69         else
  70           false
  71         end
  72
  73       request_opts =
  74         adapter_opts
  75         |> Enum.into(%{})
  76         |> Map.put(:env, Pleroma.Config.get([:env]))
  77         |> Map.put(:pool_alive?, pool_alive?)
  78
  79       response =
  80         request(
  81           client,
  82           request,
  83           request_opts
  84         )
  85
  86       Connection.after_request(adapter_opts)
  87
  88       response
  89     end
  90   end
  91
  92   @spec request(Client.t(), keyword(), map()) :: {:ok, Env.t()} | {:error, any()}
  93   def request(%Client{} = client, request, %{env: :test}), do: request_try(client, request)
  94
  95   def request(%Client{} = client, request, %{body_as: :chunks}) do
  96     request_try(client, request)
  97   end
  98
  99   def request(%Client{} = client, request, %{pool_alive?: false}) do
 100     request_try(client, request)
 101   end
 102
 103   def request(%Client{} = client, request, %{pool: pool, timeout: timeout}) do
 104     try do
 105       :poolboy.transaction(
 106         pool,
 107         &Pleroma.Pool.Request.execute(&1, client, request, timeout + 500),
 108         timeout + 1_000
 109       )
 110     rescue
 111       e ->
 112         {:error, e}
 113     catch
 114       :exit, {:timeout, _} ->
 115         Logger.warn("Receive response from pool failed #{request[:url]}")
 116         {:error, :recv_pool_timeout}
 117
 118       :exit, e ->
 119         {:error, e}
 120     end
 121   end
 122
 123   @spec request_try(Client.t(), keyword()) :: {:ok, Env.t()} | {:error, any()}
 124   def request_try(client, request) do
 125     try do
 126       Tesla.request(client, request)
 127     rescue
 128       e ->
 129         {:error, e}
 130     catch
 131       :exit, e ->
 132         {:error, e}
 133     end
 134   end
 135
 136   defp build_request(method, headers, options, url, body, params) do
 137     Builder.new()
 138     |> Builder.method(method)
 139     |> Builder.headers(headers)
 140     |> Builder.opts(options)
 141     |> Builder.url(url)
 142     |> Builder.add_param(:body, :body, body)
 143     |> Builder.add_param(:query, :query, params)
 144     |> Builder.convert_to_keyword()
 145   end
 146
 147   defp tesla_adapter, do: Application.get_env(:tesla, :adapter)
 148 end