git.squeep.com Git - akkoma/blob - lib/pleroma/http/http.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2018 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.HTTP do
   6   @moduledoc """
   7
   8   """
   9
  10   alias Pleroma.HTTP.Connection
  11   alias Pleroma.HTTP.RequestBuilder, as: Builder
  12
  13   @doc """
  14   Builds and perform http request.
  15
  16   # Arguments:
  17   `method` - :get, :post, :put, :delete
  18   `url`
  19   `body`
  20   `headers` - a keyworld list of headers, e.g. `[{"content-type", "text/plain"}]`
  21   `options` - custom, per-request middleware or adapter options
  22
  23   # Returns:
  24   `{:ok, %Tesla.Env{}}` or `{:error, error}`
  25
  26   """
  27   def request(method, url, body \\ "", headers \\ [], options \\ []) do
  28     options =
  29       process_request_options(options)
  30       |> process_sni_options(url)
  31
  32     %{}
  33     |> Builder.method(method)
  34     |> Builder.headers(headers)
  35     |> Builder.opts(options)
  36     |> Builder.url(url)
  37     |> Builder.add_param(:body, :body, body)
  38     |> Enum.into([])
  39     |> (&Tesla.request(Connection.new(), &1)).()
  40   end
  41
  42   defp process_sni_options(options, nil), do: options
  43
  44   defp process_sni_options(options, url) do
  45     uri = URI.parse(url)
  46     host = uri.host |> to_charlist()
  47
  48     case uri.scheme do
  49       "https" -> options ++ [ssl: [server_name_indication: host]]
  50       _ -> options
  51     end
  52   end
  53
  54   def process_request_options(options) do
  55     config = Application.get_env(:pleroma, :http, [])
  56     proxy = Keyword.get(config, :proxy_url, nil)
  57     options = options ++ [adapter: [pool: :default]]
  58
  59     case proxy do
  60       nil -> options
  61       _ -> options ++ [proxy: proxy]
  62     end
  63   end
  64
  65   @doc """
  66   Performs GET request.
  67
  68   See `Pleroma.HTTP.request/5`
  69   """
  70   def get(url, headers \\ [], options \\ []),
  71     do: request(:get, url, "", headers, options)
  72
  73   @doc """
  74   Performs POST request.
  75
  76   See `Pleroma.HTTP.request/5`
  77   """
  78   def post(url, body, headers \\ [], options \\ []),
  79     do: request(:post, url, body, headers, options)
  80 end