git.squeep.com Git - akkoma/blob - lib/pleroma/http/http.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.HTTP do
   6   @moduledoc """
   7     Wrapper for `Tesla.request/2`.
   8   """
   9
  10   alias Pleroma.HTTP.Connection
  11   alias Pleroma.HTTP.Request
  12   alias Pleroma.HTTP.RequestBuilder, as: Builder
  13   alias Tesla.Client
  14   alias Tesla.Env
  15
  16   require Logger
  17
  18   @type t :: __MODULE__
  19
  20   @doc """
  21   Performs GET request.
  22
  23   See `Pleroma.HTTP.request/5`
  24   """
  25   @spec get(Request.url() | nil, Request.headers(), keyword()) ::
  26           nil | {:ok, Env.t()} | {:error, any()}
  27   def get(url, headers \\ [], options \\ [])
  28   def get(nil, _, _), do: nil
  29   def get(url, headers, options), do: request(:get, url, "", headers, options)
  30
  31   @doc """
  32   Performs POST request.
  33
  34   See `Pleroma.HTTP.request/5`
  35   """
  36   @spec post(Request.url(), String.t(), Request.headers(), keyword()) ::
  37           {:ok, Env.t()} | {:error, any()}
  38   def post(url, body, headers \\ [], options \\ []),
  39     do: request(:post, url, body, headers, options)
  40
  41   @doc """
  42   Builds and performs http request.
  43
  44   # Arguments:
  45   `method` - :get, :post, :put, :delete
  46   `url` - full url
  47   `body` - request body
  48   `headers` - a keyworld list of headers, e.g. `[{"content-type", "text/plain"}]`
  49   `options` - custom, per-request middleware or adapter options
  50
  51   # Returns:
  52   `{:ok, %Tesla.Env{}}` or `{:error, error}`
  53
  54   """
  55   @spec request(atom(), Request.url(), String.t(), Request.headers(), keyword()) ::
  56           {:ok, Env.t()} | {:error, any()}
  57   def request(method, url, body, headers, options) when is_binary(url) do
  58     uri = URI.parse(url)
  59     received_adapter_opts = Keyword.get(options, :adapter, [])
  60     adapter_opts = Connection.options(uri, received_adapter_opts)
  61     options = put_in(options[:adapter], adapter_opts)
  62     params = Keyword.get(options, :params, [])
  63     request = build_request(method, headers, options, url, body, params)
  64
  65     adapter = Application.get_env(:tesla, :adapter)
  66     client = Tesla.client([Tesla.Middleware.FollowRedirects], adapter)
  67
  68     pid = Process.whereis(adapter_opts[:pool])
  69
  70     pool_alive? =
  71       if adapter == Tesla.Adapter.Gun && pid do
  72         Process.alive?(pid)
  73       else
  74         false
  75       end
  76
  77     request_opts =
  78       adapter_opts
  79       |> Enum.into(%{})
  80       |> Map.put(:env, Pleroma.Config.get([:env]))
  81       |> Map.put(:pool_alive?, pool_alive?)
  82
  83     response = request(client, request, request_opts)
  84
  85     Connection.after_request(adapter_opts)
  86
  87     response
  88   end
  89
  90   @spec request(Client.t(), keyword(), map()) :: {:ok, Env.t()} | {:error, any()}
  91   def request(%Client{} = client, request, %{env: :test}), do: request_try(client, request)
  92
  93   def request(%Client{} = client, request, %{body_as: :chunks}) do
  94     request_try(client, request)
  95   end
  96
  97   def request(%Client{} = client, request, %{pool_alive?: false}) do
  98     request_try(client, request)
  99   end
 100
 101   def request(%Client{} = client, request, %{pool: pool, timeout: timeout}) do
 102     :poolboy.transaction(
 103       pool,
 104       &Pleroma.Pool.Request.execute(&1, client, request, timeout),
 105       timeout
 106     )
 107   end
 108
 109   @spec request_try(Client.t(), keyword()) :: {:ok, Env.t()} | {:error, any()}
 110   def request_try(client, request) do
 111     try do
 112       Tesla.request(client, request)
 113     rescue
 114       e ->
 115         {:error, e}
 116     catch
 117       :exit, e ->
 118         {:error, e}
 119     end
 120   end
 121
 122   defp build_request(method, headers, options, url, body, params) do
 123     Builder.new()
 124     |> Builder.method(method)
 125     |> Builder.headers(headers)
 126     |> Builder.opts(options)
 127     |> Builder.url(url)
 128     |> Builder.add_param(:body, :body, body)
 129     |> Builder.add_param(:query, :query, params)
 130     |> Builder.convert_to_keyword()
 131   end
 132 end