git.squeep.com Git - akkoma/blob - lib/pleroma/http/adapter_helper/gun.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.HTTP.AdapterHelper.Gun do
   6   @behaviour Pleroma.HTTP.AdapterHelper
   7
   8   alias Pleroma.Config
   9   alias Pleroma.Gun.ConnectionPool
  10   alias Pleroma.HTTP.AdapterHelper
  11
  12   require Logger
  13
  14   @defaults [
  15     connect_timeout: 5_000,
  16     domain_lookup_timeout: 5_000,
  17     tls_handshake_timeout: 5_000,
  18     retry: 1,
  19     retry_timeout: 1000,
  20     await_up_timeout: 5_000
  21   ]
  22
  23   @spec options(keyword(), URI.t()) :: keyword()
  24   def options(incoming_opts \\ [], %URI{} = uri) do
  25     proxy =
  26       [:http, :proxy_url]
  27       |> Config.get()
  28       |> AdapterHelper.format_proxy()
  29
  30     config_opts = Config.get([:http, :adapter], [])
  31
  32     @defaults
  33     |> Keyword.merge(config_opts)
  34     |> add_scheme_opts(uri)
  35     |> AdapterHelper.maybe_add_proxy(proxy)
  36     |> Keyword.merge(incoming_opts)
  37   end
  38
  39   defp add_scheme_opts(opts, %{scheme: "http"}), do: opts
  40
  41   defp add_scheme_opts(opts, %{scheme: "https"}) do
  42     Keyword.put(opts, :certificates_verification, true)
  43   end
  44
  45   @spec get_conn(URI.t(), keyword()) :: {:ok, keyword()} | {:error, atom()}
  46   def get_conn(uri, opts) do
  47     case ConnectionPool.get_conn(uri, opts) do
  48       {:ok, conn_pid} -> {:ok, Keyword.merge(opts, conn: conn_pid, close_conn: false)}
  49       err -> err
  50     end
  51   end
  52
  53   @prefix Pleroma.Gun.ConnectionPool
  54   def limiter_setup do
  55     wait = Config.get([:connections_pool, :connection_acquisition_wait])
  56     retries = Config.get([:connections_pool, :connection_acquisition_retries])
  57
  58     :pools
  59     |> Config.get([])
  60     |> Enum.each(fn {name, opts} ->
  61       max_running = Keyword.get(opts, :size, 50)
  62       max_waiting = Keyword.get(opts, :max_waiting, 10)
  63
  64       result =
  65         ConcurrentLimiter.new(:"#{@prefix}.#{name}", max_running, max_waiting,
  66           wait: wait,
  67           max_retries: retries
  68         )
  69
  70       case result do
  71         :ok -> :ok
  72         {:error, :existing} -> :ok
  73       end
  74     end)
  75
  76     :ok
  77   end
  78 end