git.squeep.com Git - akkoma/blob - lib/pleroma/html.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.HTML do
   6   alias HtmlSanitizeEx.Scrubber
   7
   8   defp get_scrubbers(scrubber) when is_atom(scrubber), do: [scrubber]
   9   defp get_scrubbers(scrubbers) when is_list(scrubbers), do: scrubbers
  10   defp get_scrubbers(_), do: [Pleroma.HTML.Scrubber.Default]
  11
  12   def get_scrubbers do
  13     Pleroma.Config.get([:markup, :scrub_policy])
  14     |> get_scrubbers
  15   end
  16
  17   def filter_tags(html, nil) do
  18     filter_tags(html, get_scrubbers())
  19   end
  20
  21   def filter_tags(html, scrubbers) when is_list(scrubbers) do
  22     Enum.reduce(scrubbers, html, fn scrubber, html ->
  23       filter_tags(html, scrubber)
  24     end)
  25   end
  26
  27   def filter_tags(html, scrubber), do: Scrubber.scrub(html, scrubber)
  28   def filter_tags(html), do: filter_tags(html, nil)
  29   def strip_tags(html), do: Scrubber.scrub(html, Scrubber.StripTags)
  30
  31   def get_cached_scrubbed_html_for_object(content, scrubbers, object, module) do
  32     key = "#{module}#{generate_scrubber_signature(scrubbers)}|#{object.id}"
  33     Cachex.fetch!(:scrubber_cache, key, fn _key -> ensure_scrubbed_html(content, scrubbers) end)
  34   end
  35
  36   def get_cached_stripped_html_for_object(content, object, module) do
  37     get_cached_scrubbed_html_for_object(
  38       content,
  39       HtmlSanitizeEx.Scrubber.StripTags,
  40       object,
  41       module
  42     )
  43   end
  44
  45   def ensure_scrubbed_html(
  46         content,
  47         scrubbers
  48       ) do
  49     {:commit, filter_tags(content, scrubbers)}
  50   end
  51
  52   defp generate_scrubber_signature(scrubber) when is_atom(scrubber) do
  53     generate_scrubber_signature([scrubber])
  54   end
  55
  56   defp generate_scrubber_signature(scrubbers) do
  57     Enum.reduce(scrubbers, "", fn scrubber, signature ->
  58       "#{signature}#{to_string(scrubber)}"
  59     end)
  60   end
  61
  62   def extract_first_external_url(_, nil), do: {:error, "No content"}
  63
  64   def extract_first_external_url(object, content) do
  65     key = "URL|#{object.id}"
  66
  67     Cachex.fetch!(:scrubber_cache, key, fn _key ->
  68       result =
  69         content
  70         |> Floki.filter_out("a.mention")
  71         |> Floki.attribute("a", "href")
  72         |> Enum.at(0)
  73
  74       {:commit, {:ok, result}}
  75     end)
  76   end
  77 end
  78
  79 defmodule Pleroma.HTML.Scrubber.TwitterText do
  80   @moduledoc """
  81   An HTML scrubbing policy which limits to twitter-style text.  Only
  82   paragraphs, breaks and links are allowed through the filter.
  83   """
  84
  85   @markup Application.get_env(:pleroma, :markup)
  86   @valid_schemes Pleroma.Config.get([:uri_schemes, :valid_schemes], [])
  87
  88   require HtmlSanitizeEx.Scrubber.Meta
  89   alias HtmlSanitizeEx.Scrubber.Meta
  90
  91   Meta.remove_cdata_sections_before_scrub()
  92   Meta.strip_comments()
  93
  94   # links
  95   Meta.allow_tag_with_uri_attributes("a", ["href", "data-user", "data-tag"], @valid_schemes)
  96   Meta.allow_tag_with_these_attributes("a", ["name", "title", "class"])
  97
  98   Meta.allow_tag_with_this_attribute_values("a", "rel", [
  99     "tag",
 100     "nofollow",
 101     "noopener",
 102     "noreferrer"
 103   ])
 104
 105   # paragraphs and linebreaks
 106   Meta.allow_tag_with_these_attributes("br", [])
 107   Meta.allow_tag_with_these_attributes("p", [])
 108
 109   # microformats
 110   Meta.allow_tag_with_these_attributes("span", ["class"])
 111
 112   # allow inline images for custom emoji
 113   @allow_inline_images Keyword.get(@markup, :allow_inline_images)
 114
 115   if @allow_inline_images do
 116     # restrict img tags to http/https only, because of MediaProxy.
 117     Meta.allow_tag_with_uri_attributes("img", ["src"], ["http", "https"])
 118
 119     Meta.allow_tag_with_these_attributes("img", [
 120       "width",
 121       "height",
 122       "title",
 123       "alt"
 124     ])
 125   end
 126
 127   Meta.strip_everything_not_covered()
 128 end
 129
 130 defmodule Pleroma.HTML.Scrubber.Default do
 131   @doc "The default HTML scrubbing policy: no "
 132
 133   require HtmlSanitizeEx.Scrubber.Meta
 134   alias HtmlSanitizeEx.Scrubber.Meta
 135   # credo:disable-for-previous-line
 136   # No idea how to fix this one…
 137
 138   @markup Application.get_env(:pleroma, :markup)
 139   @valid_schemes Pleroma.Config.get([:uri_schemes, :valid_schemes], [])
 140
 141   Meta.remove_cdata_sections_before_scrub()
 142   Meta.strip_comments()
 143
 144   Meta.allow_tag_with_uri_attributes("a", ["href", "data-user", "data-tag"], @valid_schemes)
 145   Meta.allow_tag_with_these_attributes("a", ["name", "title", "class"])
 146
 147   Meta.allow_tag_with_this_attribute_values("a", "rel", [
 148     "tag",
 149     "nofollow",
 150     "noopener",
 151     "noreferrer"
 152   ])
 153
 154   Meta.allow_tag_with_these_attributes("abbr", ["title"])
 155
 156   Meta.allow_tag_with_these_attributes("b", [])
 157   Meta.allow_tag_with_these_attributes("blockquote", [])
 158   Meta.allow_tag_with_these_attributes("br", [])
 159   Meta.allow_tag_with_these_attributes("code", [])
 160   Meta.allow_tag_with_these_attributes("del", [])
 161   Meta.allow_tag_with_these_attributes("em", [])
 162   Meta.allow_tag_with_these_attributes("i", [])
 163   Meta.allow_tag_with_these_attributes("li", [])
 164   Meta.allow_tag_with_these_attributes("ol", [])
 165   Meta.allow_tag_with_these_attributes("p", [])
 166   Meta.allow_tag_with_these_attributes("pre", [])
 167   Meta.allow_tag_with_these_attributes("span", ["class"])
 168   Meta.allow_tag_with_these_attributes("strong", [])
 169   Meta.allow_tag_with_these_attributes("u", [])
 170   Meta.allow_tag_with_these_attributes("ul", [])
 171
 172   @allow_inline_images Keyword.get(@markup, :allow_inline_images)
 173
 174   if @allow_inline_images do
 175     # restrict img tags to http/https only, because of MediaProxy.
 176     Meta.allow_tag_with_uri_attributes("img", ["src"], ["http", "https"])
 177
 178     Meta.allow_tag_with_these_attributes("img", [
 179       "width",
 180       "height",
 181       "title",
 182       "alt"
 183     ])
 184   end
 185
 186   @allow_tables Keyword.get(@markup, :allow_tables)
 187
 188   if @allow_tables do
 189     Meta.allow_tag_with_these_attributes("table", [])
 190     Meta.allow_tag_with_these_attributes("tbody", [])
 191     Meta.allow_tag_with_these_attributes("td", [])
 192     Meta.allow_tag_with_these_attributes("th", [])
 193     Meta.allow_tag_with_these_attributes("thead", [])
 194     Meta.allow_tag_with_these_attributes("tr", [])
 195   end
 196
 197   @allow_headings Keyword.get(@markup, :allow_headings)
 198
 199   if @allow_headings do
 200     Meta.allow_tag_with_these_attributes("h1", [])
 201     Meta.allow_tag_with_these_attributes("h2", [])
 202     Meta.allow_tag_with_these_attributes("h3", [])
 203     Meta.allow_tag_with_these_attributes("h4", [])
 204     Meta.allow_tag_with_these_attributes("h5", [])
 205   end
 206
 207   @allow_fonts Keyword.get(@markup, :allow_fonts)
 208
 209   if @allow_fonts do
 210     Meta.allow_tag_with_these_attributes("font", ["face"])
 211   end
 212
 213   Meta.strip_everything_not_covered()
 214 end
 215
 216 defmodule Pleroma.HTML.Transform.MediaProxy do
 217   @moduledoc "Transforms inline image URIs to use MediaProxy."
 218
 219   alias Pleroma.Web.MediaProxy
 220
 221   def before_scrub(html), do: html
 222
 223   def scrub_attribute("img", {"src", "http" <> target}) do
 224     media_url =
 225       ("http" <> target)
 226       |> MediaProxy.url()
 227
 228     {"src", media_url}
 229   end
 230
 231   def scrub_attribute(_tag, attribute), do: attribute
 232
 233   def scrub({"img", attributes, children}) do
 234     attributes =
 235       attributes
 236       |> Enum.map(fn attr -> scrub_attribute("img", attr) end)
 237       |> Enum.reject(&is_nil(&1))
 238
 239     {"img", attributes, children}
 240   end
 241
 242   def scrub({:comment, _children}), do: ""
 243
 244   def scrub({tag, attributes, children}), do: {tag, attributes, children}
 245   def scrub({_tag, children}), do: children
 246   def scrub(text), do: text
 247 end