git.squeep.com Git - akkoma/blob - lib/pleroma/helpers/media_helper.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Helpers.MediaHelper do
   6   @moduledoc """
   7   Handles common media-related operations.
   8   """
   9
  10   @tmp_base "/tmp/pleroma-media_preview-pipe"
  11
  12   def image_resize(url, options) do
  13     with executable when is_binary(executable) <- System.find_executable("convert"),
  14          {:ok, args} <- prepare_image_resize_args(options),
  15          url = Pleroma.Web.MediaProxy.url(url),
  16          {:ok, env} <- Pleroma.HTTP.get(url),
  17          {:ok, fifo_path} <- mkfifo()
  18     do
  19       run_fifo(fifo_path, env, executable, args)
  20     else
  21       nil -> {:error, {:convert, :command_not_found}}
  22       {:error, _} = error -> error
  23     end
  24   end
  25
  26   defp prepare_image_resize_args(%{max_width: max_width, max_height: max_height} = options) do
  27     quality = options[:quality] || 85
  28     resize = Enum.join([max_width, "x", max_height, ">"])
  29     args = [
  30     "-interlace", "Plane",
  31     "-resize", resize,
  32     "-quality", to_string(quality),
  33     "jpg:-"
  34     ]
  35     {:ok, args}
  36   end
  37
  38   defp prepare_image_resize_args(_), do: {:error, :missing_options}
  39
  40   def video_framegrab(url) do
  41     with executable when is_binary(executable) <- System.find_executable("ffmpeg"),
  42          url = Pleroma.Web.MediaProxy.url(url),
  43          {:ok, env} <- Pleroma.HTTP.get(url),
  44          {:ok, fifo_path} <- mkfifo(),
  45          args = [
  46            "-i", fifo_path,
  47            "-vframes", "1",
  48            "-f", "mjpeg",
  49            "-loglevel", "error",
  50            "-"
  51          ] do
  52       run_fifo(fifo_path, env, executable, args)
  53     else
  54       nil -> {:error, {:ffmpeg, :command_not_found}}
  55       {:error, _} = error -> error
  56     end
  57   end
  58
  59   defp run_fifo(fifo_path, env, executable, args) do
  60     args =
  61       if _executable = System.find_executable("convert") do
  62         List.flatten([fifo_path, args])
  63       else
  64         args
  65       end
  66     pid = Port.open({:spawn_executable, executable}, [:use_stdio, :stream, :exit_status, :binary, args: args])
  67     fifo = Port.open(to_charlist(fifo_path), [:eof, :binary, :stream, :out])
  68     true = Port.command(fifo, env.body)
  69     :erlang.port_close(fifo)
  70     loop_recv(pid)
  71   after
  72     File.rm(fifo_path)
  73   end
  74
  75   defp mkfifo() do
  76     path = "#{@tmp_base}#{to_charlist(:erlang.phash2(self()))}"
  77     case System.cmd("mkfifo", [path]) do
  78       {_, 0} ->
  79         spawn(fifo_guard(path))
  80         {:ok, path}
  81       {_, err} ->
  82         {:error, {:fifo_failed, err}}
  83     end
  84   end
  85
  86   defp fifo_guard(path) do
  87     pid = self()
  88     fn() ->
  89       ref = Process.monitor(pid)
  90       receive do
  91         {:DOWN, ^ref, :process, ^pid, _} ->
  92           File.rm(path)
  93       end
  94     end
  95   end
  96
  97   defp loop_recv(pid) do
  98     loop_recv(pid, <<>>)
  99   end
 100
 101   defp loop_recv(pid, acc) do
 102     receive do
 103       {^pid, {:data, data}} ->
 104         loop_recv(pid, acc <> data)
 105       {^pid, {:exit_status, 0}} ->
 106         {:ok, acc}
 107       {^pid, {:exit_status, status}} ->
 108         {:error, status}
 109      after
 110        5000 ->
 111          :erlang.port_close(pid)
 112          {:error, :timeout}
 113     end
 114   end
 115 end