git.squeep.com Git - akkoma/blob - lib/pleroma/helpers/media_helper.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Helpers.MediaHelper do
   6   @moduledoc """
   7   Handles common media-related operations.
   8   """
   9
  10   @tmp_base "/tmp/pleroma-media_preview-pipe"
  11
  12   def image_resize(url, options) do
  13     with executable when is_binary(executable) <- System.find_executable("convert"),
  14          {:ok, args} <- prepare_resize_args(options),
  15          url = Pleroma.Web.MediaProxy.url(url),
  16          {:ok, env} <- Pleroma.HTTP.get(url),
  17          {:ok, fifo_path} <- mkfifo()
  18     do
  19       run_fifo(fifo_path, env, executable, args)
  20     else
  21       nil -> {:error, {:convert, :command_not_found}}
  22       {:error, _} = error -> error
  23     end
  24   end
  25
  26   defp prepare_resize_args(%{max_width: max_width, max_height: max_height} = options) do
  27     quality = options[:quality] || 85
  28     resize = Enum.join([max_width, "x", max_height, ">"])
  29     args = [
  30     "-resize", resize,
  31     "-quality", to_string(quality)
  32     ]
  33     {:ok, args}
  34   end
  35
  36   defp prepare_resize_args(_), do: {:error, :missing_options}
  37
  38   defp run_fifo(fifo_path, env, executable, args) do
  39     args = List.flatten([fifo_path, args, "jpg:fd:1"])
  40     pid = Port.open({:spawn_executable, executable}, [:use_stdio, :stream, :exit_status, :binary, args: args])
  41     fifo = Port.open(to_charlist(fifo_path), [:eof, :binary, :stream, :out])
  42     true = Port.command(fifo, env.body)
  43     :erlang.port_close(fifo)
  44     loop_recv(pid)
  45   after
  46     File.rm(fifo_path)
  47   end
  48
  49   defp mkfifo() do
  50     path = "#{@tmp_base}#{to_charlist(:erlang.phash2(self()))}"
  51     case System.cmd("mkfifo", [path]) do
  52       {_, 0} ->
  53         spawn(fifo_guard(path))
  54         {:ok, path}
  55       {_, err} ->
  56         {:error, {:fifo_failed, err}}
  57     end
  58   end
  59
  60   defp fifo_guard(path) do
  61     pid = self()
  62     fn() ->
  63       ref = Process.monitor(pid)
  64       receive do
  65         {:DOWN, ^ref, :process, ^pid, _} ->
  66           File.rm(path)
  67       end
  68     end
  69   end
  70
  71   defp loop_recv(pid) do
  72     loop_recv(pid, <<>>)
  73   end
  74
  75   defp loop_recv(pid, acc) do
  76     receive do
  77       {^pid, {:data, data}} ->
  78         loop_recv(pid, acc <> data)
  79       {^pid, {:exit_status, 0}} ->
  80         {:ok, acc}
  81       {^pid, {:exit_status, status}} ->
  82         {:error, status}
  83      after
  84        5000 ->
  85          :erlang.port_close(pid)
  86          {:error, :timeout}
  87     end
  88   end
  89 end