git.squeep.com Git - akkoma/blob - lib/pleroma/helpers/media_helper.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Helpers.MediaHelper do
   6   @moduledoc """
   7   Handles common media-related operations.
   8   """
   9
  10   @tmp_base "/tmp/pleroma-media_preview-pipe"
  11
  12   def image_resize(url, options) do
  13     with executable when is_binary(executable) <- System.find_executable("convert"),
  14          {:ok, args} <- prepare_resize_args(options),
  15          url = Pleroma.Web.MediaProxy.url(url),
  16          {:ok, env} <- Pleroma.HTTP.get(url),
  17          {:ok, fifo_path} <- mkfifo()
  18     do
  19       run_fifo(fifo_path, env, executable, args)
  20     else
  21       nil -> {:error, {:convert, :command_not_found}}
  22       {:error, _} = error -> error
  23     end
  24   end
  25
  26   defp prepare_resize_args(%{max_width: max_width, max_height: max_height} = options) do
  27     quality = options[:quality] || 85
  28     resize = Enum.join([max_width, "x", max_height, ">"])
  29     args = [
  30     "-auto-orient", # Support for EXIF rotation
  31     "-resize", resize,
  32     "-quality", to_string(quality)
  33     ]
  34     {:ok, args}
  35   end
  36
  37   defp prepare_resize_args(_), do: {:error, :missing_options}
  38
  39   defp run_fifo(fifo_path, env, executable, args) do
  40     args = List.flatten([fifo_path, args, "jpg:fd:1"])
  41     pid = Port.open({:spawn_executable, executable}, [:use_stdio, :stream, :exit_status, :binary, args: args])
  42     fifo = Port.open(to_charlist(fifo_path), [:eof, :binary, :stream, :out])
  43     true = Port.command(fifo, env.body)
  44     :erlang.port_close(fifo)
  45     loop_recv(pid)
  46   after
  47     File.rm(fifo_path)
  48   end
  49
  50   defp mkfifo() do
  51     path = "#{@tmp_base}#{to_charlist(:erlang.phash2(self()))}"
  52     case System.cmd("mkfifo", [path]) do
  53       {_, 0} ->
  54         spawn(fifo_guard(path))
  55         {:ok, path}
  56       {_, err} ->
  57         {:error, {:fifo_failed, err}}
  58     end
  59   end
  60
  61   defp fifo_guard(path) do
  62     pid = self()
  63     fn() ->
  64       ref = Process.monitor(pid)
  65       receive do
  66         {:DOWN, ^ref, :process, ^pid, _} ->
  67           File.rm(path)
  68       end
  69     end
  70   end
  71
  72   defp loop_recv(pid) do
  73     loop_recv(pid, <<>>)
  74   end
  75
  76   defp loop_recv(pid, acc) do
  77     receive do
  78       {^pid, {:data, data}} ->
  79         loop_recv(pid, acc <> data)
  80       {^pid, {:exit_status, 0}} ->
  81         {:ok, acc}
  82       {^pid, {:exit_status, status}} ->
  83         {:error, status}
  84      after
  85        5000 ->
  86          :erlang.port_close(pid)
  87          {:error, :timeout}
  88     end
  89   end
  90 end