git.squeep.com Git - akkoma/blob - lib/pleroma/hashtag.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Hashtag do
   6   use Ecto.Schema
   7
   8   import Ecto.Changeset
   9   import Ecto.Query
  10
  11   alias Ecto.Multi
  12   alias Pleroma.Hashtag
  13   alias Pleroma.Object
  14   alias Pleroma.Repo
  15
  16   schema "hashtags" do
  17     field(:name, :string)
  18
  19     many_to_many(:objects, Object, join_through: "hashtags_objects", on_replace: :delete)
  20
  21     timestamps()
  22   end
  23
  24   def get_by_name(name) do
  25     Repo.get_by(Hashtag, name: name)
  26   end
  27
  28   def get_or_create_by_name(name) when is_bitstring(name) do
  29     with %Hashtag{} = hashtag <- get_by_name(name) do
  30       {:ok, hashtag}
  31     else
  32       _ ->
  33         %Hashtag{}
  34         |> changeset(%{name: name})
  35         |> Repo.insert()
  36     end
  37   end
  38
  39   def get_or_create_by_names(names) when is_list(names) do
  40     timestamp = NaiveDateTime.truncate(NaiveDateTime.utc_now(), :second)
  41
  42     structs =
  43       Enum.map(names, fn name ->
  44         %Hashtag{}
  45         |> changeset(%{name: name})
  46         |> Map.get(:changes)
  47         |> Map.merge(%{inserted_at: timestamp, updated_at: timestamp})
  48       end)
  49
  50     with {:ok, %{query_op: hashtags}} <-
  51            Multi.new()
  52            |> Multi.insert_all(:insert_all_op, Hashtag, structs, on_conflict: :nothing)
  53            |> Multi.run(:query_op, fn _repo, _changes ->
  54              {:ok, Repo.all(from(ht in Hashtag, where: ht.name in ^names))}
  55            end)
  56            |> Repo.transaction() do
  57       {:ok, hashtags}
  58     else
  59       {:error, _name, value, _changes_so_far} -> {:error, value}
  60     end
  61   end
  62
  63   def changeset(%Hashtag{} = struct, params) do
  64     struct
  65     |> cast(params, [:name])
  66     |> update_change(:name, &String.downcase/1)
  67     |> validate_required([:name])
  68     |> unique_constraint(:name)
  69   end
  70
  71   def unlink(%Object{id: object_id}) do
  72     with {_, hashtag_ids} <-
  73            from(hto in "hashtags_objects",
  74              where: hto.object_id == ^object_id,
  75              select: hto.hashtag_id
  76            )
  77            |> Repo.delete_all() do
  78       delete_unreferenced(hashtag_ids)
  79     end
  80   end
  81
  82   @delete_unreferenced_query """
  83   DELETE FROM hashtags WHERE id IN
  84     (SELECT hashtags.id FROM hashtags
  85       LEFT OUTER JOIN hashtags_objects
  86         ON hashtags_objects.hashtag_id = hashtags.id
  87       WHERE hashtags_objects.hashtag_id IS NULL AND hashtags.id = ANY($1));
  88   """
  89
  90   def delete_unreferenced(ids) do
  91     with {:ok, %{num_rows: deleted_count}} <- Repo.query(@delete_unreferenced_query, [ids]) do
  92       {:ok, deleted_count}
  93     end
  94   end
  95 end