git.squeep.com Git - akkoma/blob - lib/pleroma/hashtag.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Hashtag do
   6   use Ecto.Schema
   7
   8   import Ecto.Changeset
   9   import Ecto.Query
  10
  11   alias Ecto.Multi
  12   alias Pleroma.Hashtag
  13   alias Pleroma.Object
  14   alias Pleroma.Repo
  15
  16   schema "hashtags" do
  17     field(:name, :string)
  18
  19     many_to_many(:objects, Object, join_through: "hashtags_objects", on_replace: :delete)
  20
  21     timestamps()
  22   end
  23
  24   def normalize_name(name) do
  25     name
  26     |> String.downcase()
  27     |> String.trim()
  28   end
  29
  30   def get_by_name(name) do
  31     Repo.get_by(Hashtag, name: normalize_name(name))
  32   end
  33
  34   def get_or_create_by_name(name) when is_bitstring(name) do
  35     with %Hashtag{} = hashtag <- get_by_name(name) do
  36       {:ok, hashtag}
  37     else
  38       _ ->
  39         %Hashtag{}
  40         |> changeset(%{name: name})
  41         |> Repo.insert()
  42     end
  43   end
  44
  45   def get_or_create_by_names(names) when is_list(names) do
  46     names = Enum.map(names, &normalize_name/1)
  47     timestamp = NaiveDateTime.truncate(NaiveDateTime.utc_now(), :second)
  48
  49     structs =
  50       Enum.map(names, fn name ->
  51         %Hashtag{}
  52         |> changeset(%{name: name})
  53         |> Map.get(:changes)
  54         |> Map.merge(%{inserted_at: timestamp, updated_at: timestamp})
  55       end)
  56
  57     try do
  58       with {:ok, %{query_op: hashtags}} <-
  59              Multi.new()
  60              |> Multi.insert_all(:insert_all_op, Hashtag, structs,
  61                on_conflict: :nothing,
  62                conflict_target: :name
  63              )
  64              |> Multi.run(:query_op, fn _repo, _changes ->
  65                {:ok, Repo.all(from(ht in Hashtag, where: ht.name in ^names))}
  66              end)
  67              |> Repo.transaction() do
  68         {:ok, hashtags}
  69       else
  70         {:error, _name, value, _changes_so_far} -> {:error, value}
  71       end
  72     rescue
  73       e -> {:error, e}
  74     end
  75   end
  76
  77   def changeset(%Hashtag{} = struct, params) do
  78     struct
  79     |> cast(params, [:name])
  80     |> update_change(:name, &normalize_name/1)
  81     |> validate_required([:name])
  82     |> unique_constraint(:name)
  83   end
  84
  85   def unlink(%Object{id: object_id}) do
  86     with {_, hashtag_ids} <-
  87            from(hto in "hashtags_objects",
  88              where: hto.object_id == ^object_id,
  89              select: hto.hashtag_id
  90            )
  91            |> Repo.delete_all(),
  92          {:ok, unreferenced_count} <- delete_unreferenced(hashtag_ids) do
  93       {:ok, length(hashtag_ids), unreferenced_count}
  94     end
  95   end
  96
  97   @delete_unreferenced_query """
  98   DELETE FROM hashtags WHERE id IN
  99     (SELECT hashtags.id FROM hashtags
 100       LEFT OUTER JOIN hashtags_objects
 101         ON hashtags_objects.hashtag_id = hashtags.id
 102       WHERE hashtags_objects.hashtag_id IS NULL AND hashtags.id = ANY($1));
 103   """
 104
 105   def delete_unreferenced(ids) do
 106     with {:ok, %{num_rows: deleted_count}} <- Repo.query(@delete_unreferenced_query, [ids]) do
 107       {:ok, deleted_count}
 108     end
 109   end
 110 end