git.squeep.com Git - akkoma/blob - lib/pleroma/gun/connection_pool/worker_supervisor.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2021 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Gun.ConnectionPool.WorkerSupervisor do
   6   @moduledoc "Supervisor for pool workers. Does not do anything except enforce max connection limit"
   7
   8   use DynamicSupervisor
   9
  10   def start_link(opts) do
  11     DynamicSupervisor.start_link(__MODULE__, opts, name: __MODULE__)
  12   end
  13
  14   def init(_opts) do
  15     DynamicSupervisor.init(
  16       strategy: :one_for_one,
  17       max_children: Pleroma.Config.get([:connections_pool, :max_connections])
  18     )
  19   end
  20
  21   def start_worker(opts, retry \\ false) do
  22     case DynamicSupervisor.start_child(__MODULE__, {Pleroma.Gun.ConnectionPool.Worker, opts}) do
  23       {:error, :max_children} ->
  24         if retry or free_pool() == :error do
  25           :telemetry.execute([:pleroma, :connection_pool, :provision_failure], %{opts: opts})
  26           {:error, :pool_full}
  27         else
  28           start_worker(opts, true)
  29         end
  30
  31       res ->
  32         res
  33     end
  34   end
  35
  36   defp free_pool do
  37     wait_for_reclaimer_finish(Pleroma.Gun.ConnectionPool.Reclaimer.start_monitor())
  38   end
  39
  40   defp wait_for_reclaimer_finish({pid, mon}) do
  41     receive do
  42       {:DOWN, ^mon, :process, ^pid, :no_unused_conns} ->
  43         :error
  44
  45       {:DOWN, ^mon, :process, ^pid, :normal} ->
  46         :ok
  47     end
  48   end
  49 end