git.squeep.com Git - akkoma/blob - lib/pleroma/gopher/server.ex

   1 defmodule Pleroma.Gopher.Server do
   2   use GenServer
   3   require Logger
   4   @gopher Application.get_env(:pleroma, :gopher)
   5
   6   def start_link() do
   7     ip = Keyword.get(@gopher, :ip, {0, 0, 0, 0})
   8     port = Keyword.get(@gopher, :port, 1234)
   9     GenServer.start_link(__MODULE__, [ip, port], [])
  10   end
  11
  12   def init([ip, port]) do
  13     if Keyword.get(@gopher, :enabled, false) do
  14       Logger.info("Starting gopher server on #{port}")
  15
  16       :ranch.start_listener(
  17         :gopher,
  18         100,
  19         :ranch_tcp,
  20         [port: port],
  21         __MODULE__.ProtocolHandler,
  22         []
  23       )
  24
  25       {:ok, %{ip: ip, port: port}}
  26     else
  27       Logger.info("Gopher server disabled")
  28       {:ok, nil}
  29     end
  30   end
  31 end
  32
  33 defmodule Pleroma.Gopher.Server.ProtocolHandler do
  34   alias Pleroma.Web.ActivityPub.ActivityPub
  35   alias Pleroma.User
  36   alias Pleroma.Activity
  37   alias Pleroma.Repo
  38   alias Pleroma.HTML
  39
  40   @instance Application.get_env(:pleroma, :instance)
  41   @gopher Application.get_env(:pleroma, :gopher)
  42
  43   def start_link(ref, socket, transport, opts) do
  44     pid = spawn_link(__MODULE__, :init, [ref, socket, transport, opts])
  45     {:ok, pid}
  46   end
  47
  48   def init(ref, socket, transport, _Opts = []) do
  49     :ok = :ranch.accept_ack(ref)
  50     loop(socket, transport)
  51   end
  52
  53   def info(text) do
  54     text = String.replace(text, ~r/[\t\n]/, "")
  55
  56     String.split(text, "\r")
  57     |> Enum.map(fn text ->
  58       "i#{text}\tfake\t(NULL)\t0\r\n"
  59     end)
  60     |> Enum.join("")
  61   end
  62
  63   def link(name, selector, type \\ 1) do
  64     address = Pleroma.Web.Endpoint.host()
  65     port = Keyword.get(@gopher, :port, 1234)
  66     "#{type}#{name}\t#{selector}\t#{address}\t#{port}\r\n"
  67   end
  68
  69   def render_activities(activities) do
  70     activities
  71     |> Enum.reverse()
  72     |> Enum.map(fn activity ->
  73       user = User.get_cached_by_ap_id(activity.data["actor"])
  74
  75       object = activity.data["object"]
  76       like_count = object["like_count"] || 0
  77       announcement_count = object["announcement_count"] || 0
  78
  79       link("Post ##{activity.id} by #{user.nickname}", "/notices/#{activity.id}") <>
  80         info("#{like_count} likes, #{announcement_count} repeats") <>
  81         "i\tfake\t(NULL)\t0\r\n" <>
  82         info(HTML.strip_tags(String.replace(activity.data["object"]["content"], "<br>", "\r")))
  83     end)
  84     |> Enum.join("i\tfake\t(NULL)\t0\r\n")
  85   end
  86
  87   def response("") do
  88     info("Welcome to #{Keyword.get(@instance, :name, "Pleroma")}!") <>
  89       link("Public Timeline", "/main/public") <>
  90       link("Federated Timeline", "/main/all") <> ".\r\n"
  91   end
  92
  93   def response("/main/public") do
  94     posts =
  95       ActivityPub.fetch_public_activities(%{"type" => ["Create"], "local_only" => true})
  96       |> render_activities
  97
  98     info("Welcome to the Public Timeline!") <> posts <> ".\r\n"
  99   end
 100
 101   def response("/main/all") do
 102     posts =
 103       ActivityPub.fetch_public_activities(%{"type" => ["Create"]})
 104       |> render_activities
 105
 106     info("Welcome to the Federated Timeline!") <> posts <> ".\r\n"
 107   end
 108
 109   def response("/notices/" <> id) do
 110     with %Activity{} = activity <- Repo.get(Activity, id),
 111          true <- ActivityPub.is_public?(activity) do
 112       activities =
 113         ActivityPub.fetch_activities_for_context(activity.data["context"])
 114         |> render_activities
 115
 116       user = User.get_cached_by_ap_id(activity.data["actor"])
 117
 118       info("Post #{activity.id} by #{user.nickname}") <>
 119         link("More posts by #{user.nickname}", "/users/#{user.nickname}") <> activities <> ".\r\n"
 120     else
 121       _e ->
 122         info("Not public") <> ".\r\n"
 123     end
 124   end
 125
 126   def response("/users/" <> nickname) do
 127     with %User{} = user <- User.get_cached_by_nickname(nickname) do
 128       params = %{
 129         "type" => ["Create"],
 130         "actor_id" => user.ap_id
 131       }
 132
 133       activities =
 134         ActivityPub.fetch_public_activities(params)
 135         |> render_activities
 136
 137       info("Posts by #{user.nickname}") <> activities <> ".\r\n"
 138     else
 139       _e ->
 140         info("No such user") <> ".\r\n"
 141     end
 142   end
 143
 144   def loop(socket, transport) do
 145     case transport.recv(socket, 0, 5000) do
 146       {:ok, data} ->
 147         data = String.trim_trailing(data, "\r\n")
 148         transport.send(socket, response(data))
 149         :ok = transport.close(socket)
 150
 151       _ ->
 152         :ok = transport.close(socket)
 153     end
 154   end
 155 end