git.squeep.com Git - akkoma/blob - lib/pleroma/gopher/server.ex

   1 defmodule Pleroma.Gopher.Server do
   2   use GenServer
   3   require Logger
   4   @gopher Application.get_env(:pleroma, :gopher)
   5
   6   def start_link() do
   7     ip = Keyword.get(@gopher, :ip, {0, 0, 0, 0})
   8     port = Keyword.get(@gopher, :port, 1234)
   9     GenServer.start_link(__MODULE__, [ip, port], [])
  10   end
  11
  12   def init([ip, port]) do
  13     if Keyword.get(@gopher, :enabled, false) do
  14       Logger.info("Starting gopher server on #{port}")
  15
  16       :ranch.start_listener(
  17         :gopher,
  18         100,
  19         :ranch_tcp,
  20         [port: port],
  21         __MODULE__.ProtocolHandler,
  22         []
  23       )
  24
  25       {:ok, %{ip: ip, port: port}}
  26     else
  27       Logger.info("Gopher server disabled")
  28       {:ok, nil}
  29     end
  30   end
  31 end
  32
  33 defmodule Pleroma.Gopher.Server.ProtocolHandler do
  34   alias Pleroma.Web.ActivityPub.ActivityPub
  35   alias Pleroma.User
  36   alias Pleroma.Activity
  37   alias Pleroma.Repo
  38
  39   @instance Application.get_env(:pleroma, :instance)
  40   @gopher Application.get_env(:pleroma, :gopher)
  41
  42   def start_link(ref, socket, transport, opts) do
  43     pid = spawn_link(__MODULE__, :init, [ref, socket, transport, opts])
  44     {:ok, pid}
  45   end
  46
  47   def init(ref, socket, transport, _Opts = []) do
  48     :ok = :ranch.accept_ack(ref)
  49     loop(socket, transport)
  50   end
  51
  52   def info(text) do
  53     text = String.replace(text, ~r/[\t\r\n]/, " ")
  54     "#{text}\tfake\(NULL)\t0\r\n"
  55   end
  56
  57   def link(name, selector, type \\ 1) do
  58     address = Pleroma.Web.Endpoint.host()
  59     port = Keyword.get(@gopher, :port, 1234)
  60     "#{type}#{name}\t#{selector}\t#{address}\t#{port}\r\n"
  61   end
  62
  63   def response("") do
  64     info("Welcome to #{Keyword.get(@instance, :name, "Pleroma")}!") <>
  65       link("Public Timeline", "/main/public") <>
  66       link("Federated Timeline", "/main/all") <> ".\r\n"
  67   end
  68
  69   def render_activities(activities) do
  70     activities
  71     |> Enum.reverse()
  72     |> Enum.map(fn activity ->
  73       user = User.get_cached_by_ap_id(activity.data["actor"])
  74
  75       object = activity.data["object"]
  76       like_count = object["like_count"] || 0
  77       announcement_count = object["announcement_count"] || 0
  78
  79       link("Post ##{activity.id} by #{user.nickname}", "/notices/#{activity.id}") <>
  80         info("#{like_count} likes, #{announcement_count} repeats") <>
  81         "\r\n" <> info(HtmlSanitizeEx.strip_tags(activity.data["object"]["content"]))
  82     end)
  83     |> Enum.join("\r\n")
  84   end
  85
  86   def response("/main/public") do
  87     posts =
  88       ActivityPub.fetch_public_activities(%{"type" => ["Create"], "local_only" => true})
  89       |> render_activities
  90
  91     info("Welcome to the Public Timeline!") <> posts <> ".\r\n"
  92   end
  93
  94   def response("/main/all") do
  95     posts =
  96       ActivityPub.fetch_public_activities(%{"type" => ["Create"]})
  97       |> render_activities
  98
  99     info("Welcome to the Federated Timeline!") <> posts <> ".\r\n"
 100   end
 101
 102   def response("/notices/" <> id) do
 103     with %Activity{} = activity <- Repo.get(Activity, id),
 104          true <- ActivityPub.is_public?(activity) do
 105       activities =
 106         ActivityPub.fetch_activities_for_context(activity.data["context"])
 107         |> render_activities
 108
 109       user = User.get_cached_by_ap_id(activity.data["actor"])
 110
 111       info("Post #{activity.id} by #{user.nickname}") <>
 112         link("More posts by #{user.nickname}", "/users/#{user.nickname}") <> activities <> ".\r\n"
 113     else
 114       _e ->
 115         info("Not public") <> ".\r\n"
 116     end
 117   end
 118
 119   def response("/users/" <> nickname) do
 120     with %User{} = user <- User.get_cached_by_nickname(nickname) do
 121       params = %{
 122         "type" => ["Create"],
 123         "actor_id" => user.ap_id
 124       }
 125
 126       activities =
 127         ActivityPub.fetch_public_activities(params)
 128         |> render_activities
 129
 130       info("Posts by #{user.nickname}") <> activities <> ".\r\n"
 131     else
 132       _e ->
 133         info("No such user") <> ".\r\n"
 134     end
 135   end
 136
 137   def loop(socket, transport) do
 138     case transport.recv(socket, 0, 5000) do
 139       {:ok, data} ->
 140         data = String.trim_trailing(data, "\r\n")
 141         transport.send(socket, response(data))
 142         :ok = transport.close(socket)
 143
 144       _ ->
 145         :ok = transport.close(socket)
 146     end
 147   end
 148 end