git.squeep.com Git - akkoma/blob - lib/pleroma/gopher/server.ex

   1 defmodule Pleroma.Gopher.Server do
   2   use GenServer
   3   require Logger
   4   @gopher Application.get_env(:pleroma, :gopher)
   5
   6   def start_link() do
   7     ip = Keyword.get(@gopher, :ip, {0, 0, 0, 0})
   8     port = Keyword.get(@gopher, :port, 1234)
   9     GenServer.start_link(__MODULE__, [ip, port], [])
  10   end
  11
  12   def init([ip, port]) do
  13     if Keyword.get(@gopher, :enabled, false) do
  14       Logger.info("Starting gopher server on #{port}")
  15
  16       :ranch.start_listener(
  17         :gopher,
  18         100,
  19         :ranch_tcp,
  20         [port: port],
  21         __MODULE__.ProtocolHandler,
  22         []
  23       )
  24
  25       {:ok, %{ip: ip, port: port}}
  26     else
  27       Logger.info("Gopher server disabled")
  28       {:ok, nil}
  29     end
  30   end
  31 end
  32
  33 defmodule Pleroma.Gopher.Server.ProtocolHandler do
  34   alias Pleroma.Web.ActivityPub.ActivityPub
  35   alias Pleroma.User
  36   alias Pleroma.Activity
  37   alias Pleroma.Repo
  38   alias Pleroma.HTML
  39
  40   @instance Application.get_env(:pleroma, :instance)
  41   @gopher Application.get_env(:pleroma, :gopher)
  42
  43   def start_link(ref, socket, transport, opts) do
  44     pid = spawn_link(__MODULE__, :init, [ref, socket, transport, opts])
  45     {:ok, pid}
  46   end
  47
  48   def init(ref, socket, transport, _Opts = []) do
  49     :ok = :ranch.accept_ack(ref)
  50     loop(socket, transport)
  51   end
  52
  53   def info(text) do
  54     text = String.replace(text, ~r/[\t\n]/, "")
  55
  56     String.split(text, "\r")
  57     |> Enum.map(fn text ->
  58       "i#{text}\tfake\t(NULL)\t0\r\n"
  59     end)
  60     |> Enum.join("")
  61   end
  62
  63   def link(name, selector, type \\ 1) do
  64     address = Pleroma.Web.Endpoint.host()
  65     port = Keyword.get(@gopher, :port, 1234)
  66     "#{type}#{name}\t#{selector}\t#{address}\t#{port}\r\n"
  67   end
  68
  69   def render_activities(activities) do
  70     activities
  71     |> Enum.reverse()
  72     |> Enum.map(fn activity ->
  73       user = User.get_cached_by_ap_id(activity.data["actor"])
  74
  75       object = activity.data["object"]
  76       like_count = object["like_count"] || 0
  77       announcement_count = object["announcement_count"] || 0
  78
  79       link("Post ##{activity.id} by #{user.nickname}", "/notices/#{activity.id}") <>
  80         info("#{like_count} likes, #{announcement_count} repeats") <>
  81         "i\tfake\t(NULL)\t0\r\n" <>
  82         info(
  83           HTML.strip_tags(
  84             String.replace(activity.data["object"]["content"], "<br>", "\r")
  85           )
  86         )
  87     end)
  88     |> Enum.join("i\tfake\t(NULL)\t0\r\n")
  89   end
  90
  91   def response("") do
  92     info("Welcome to #{Keyword.get(@instance, :name, "Pleroma")}!") <>
  93       link("Public Timeline", "/main/public") <>
  94       link("Federated Timeline", "/main/all") <> ".\r\n"
  95   end
  96
  97   def response("/main/public") do
  98     posts =
  99       ActivityPub.fetch_public_activities(%{"type" => ["Create"], "local_only" => true})
 100       |> render_activities
 101
 102     info("Welcome to the Public Timeline!") <> posts <> ".\r\n"
 103   end
 104
 105   def response("/main/all") do
 106     posts =
 107       ActivityPub.fetch_public_activities(%{"type" => ["Create"]})
 108       |> render_activities
 109
 110     info("Welcome to the Federated Timeline!") <> posts <> ".\r\n"
 111   end
 112
 113   def response("/notices/" <> id) do
 114     with %Activity{} = activity <- Repo.get(Activity, id),
 115          true <- ActivityPub.is_public?(activity) do
 116       activities =
 117         ActivityPub.fetch_activities_for_context(activity.data["context"])
 118         |> render_activities
 119
 120       user = User.get_cached_by_ap_id(activity.data["actor"])
 121
 122       info("Post #{activity.id} by #{user.nickname}") <>
 123         link("More posts by #{user.nickname}", "/users/#{user.nickname}") <> activities <> ".\r\n"
 124     else
 125       _e ->
 126         info("Not public") <> ".\r\n"
 127     end
 128   end
 129
 130   def response("/users/" <> nickname) do
 131     with %User{} = user <- User.get_cached_by_nickname(nickname) do
 132       params = %{
 133         "type" => ["Create"],
 134         "actor_id" => user.ap_id
 135       }
 136
 137       activities =
 138         ActivityPub.fetch_public_activities(params)
 139         |> render_activities
 140
 141       info("Posts by #{user.nickname}") <> activities <> ".\r\n"
 142     else
 143       _e ->
 144         info("No such user") <> ".\r\n"
 145     end
 146   end
 147
 148   def loop(socket, transport) do
 149     case transport.recv(socket, 0, 5000) do
 150       {:ok, data} ->
 151         data = String.trim_trailing(data, "\r\n")
 152         transport.send(socket, response(data))
 153         :ok = transport.close(socket)
 154
 155       _ ->
 156         :ok = transport.close(socket)
 157     end
 158   end
 159 end