git.squeep.com Git - akkoma/blob - lib/pleroma/gopher/server.ex

   1 defmodule Pleroma.Gopher.Server do
   2   use GenServer
   3   require Logger
   4   @gopher Application.get_env(:pleroma, :gopher)
   5
   6   def start_link() do
   7     ip = Keyword.get(@gopher, :ip, {0, 0, 0, 0})
   8     port = Keyword.get(@gopher, :port, 1234)
   9     GenServer.start_link(__MODULE__, [ip, port], [])
  10   end
  11
  12   def init([ip, port]) do
  13     if Keyword.get(@gopher, :enabled, false) do
  14       Logger.info("Starting gopher server on #{port}")
  15
  16       :ranch.start_listener(
  17         :gopher,
  18         100,
  19         :ranch_tcp,
  20         [port: port],
  21         __MODULE__.ProtocolHandler,
  22         []
  23       )
  24
  25       {:ok, %{ip: ip, port: port}}
  26     else
  27       Logger.info("Gopher server disabled")
  28       {:ok, nil}
  29     end
  30   end
  31 end
  32
  33 defmodule Pleroma.Gopher.Server.ProtocolHandler do
  34   alias Pleroma.Web.ActivityPub.ActivityPub
  35   alias Pleroma.User
  36   alias Pleroma.Activity
  37   alias Pleroma.Repo
  38
  39   @instance Application.get_env(:pleroma, :instance)
  40   @gopher Application.get_env(:pleroma, :gopher)
  41
  42   def start_link(ref, socket, transport, opts) do
  43     pid = spawn_link(__MODULE__, :init, [ref, socket, transport, opts])
  44     {:ok, pid}
  45   end
  46
  47   def init(ref, socket, transport, _Opts = []) do
  48     :ok = :ranch.accept_ack(ref)
  49     loop(socket, transport)
  50   end
  51
  52   def info(text) do
  53     text = String.replace(text, ~r/[\t\n]/, "")
  54
  55     String.split(text, "\r")
  56     |> Enum.map(fn text ->
  57       "i#{text}\tfake\t(NULL)\t0\r\n"
  58     end)
  59     |> Enum.join("")
  60   end
  61
  62   def link(name, selector, type \\ 1) do
  63     address = Pleroma.Web.Endpoint.host()
  64     port = Keyword.get(@gopher, :port, 1234)
  65     "#{type}#{name}\t#{selector}\t#{address}\t#{port}\r\n"
  66   end
  67
  68   def render_activities(activities) do
  69     activities
  70     |> Enum.reverse()
  71     |> Enum.map(fn activity ->
  72       user = User.get_cached_by_ap_id(activity.data["actor"])
  73
  74       object = activity.data["object"]
  75       like_count = object["like_count"] || 0
  76       announcement_count = object["announcement_count"] || 0
  77
  78       link("Post ##{activity.id} by #{user.nickname}", "/notices/#{activity.id}") <>
  79         info("#{like_count} likes, #{announcement_count} repeats") <>
  80         "i\tfake\t(NULL)\t0\r\n" <>
  81         info(
  82           HtmlSanitizeEx.strip_tags(
  83             String.replace(activity.data["object"]["content"], "<br>", "\r")
  84           )
  85         )
  86     end)
  87     |> Enum.join("i\tfake\t(NULL)\t0\r\n")
  88   end
  89
  90   def response("") do
  91     info("Welcome to #{Keyword.get(@instance, :name, "Pleroma")}!") <>
  92       link("Public Timeline", "/main/public") <>
  93       link("Federated Timeline", "/main/all") <> ".\r\n"
  94   end
  95
  96   def response("/main/public") do
  97     posts =
  98       ActivityPub.fetch_public_activities(%{"type" => ["Create"], "local_only" => true})
  99       |> render_activities
 100
 101     info("Welcome to the Public Timeline!") <> posts <> ".\r\n"
 102   end
 103
 104   def response("/main/all") do
 105     posts =
 106       ActivityPub.fetch_public_activities(%{"type" => ["Create"]})
 107       |> render_activities
 108
 109     info("Welcome to the Federated Timeline!") <> posts <> ".\r\n"
 110   end
 111
 112   def response("/notices/" <> id) do
 113     with %Activity{} = activity <- Repo.get(Activity, id),
 114          true <- ActivityPub.is_public?(activity) do
 115       activities =
 116         ActivityPub.fetch_activities_for_context(activity.data["context"])
 117         |> render_activities
 118
 119       user = User.get_cached_by_ap_id(activity.data["actor"])
 120
 121       info("Post #{activity.id} by #{user.nickname}") <>
 122         link("More posts by #{user.nickname}", "/users/#{user.nickname}") <> activities <> ".\r\n"
 123     else
 124       _e ->
 125         info("Not public") <> ".\r\n"
 126     end
 127   end
 128
 129   def response("/users/" <> nickname) do
 130     with %User{} = user <- User.get_cached_by_nickname(nickname) do
 131       params = %{
 132         "type" => ["Create"],
 133         "actor_id" => user.ap_id
 134       }
 135
 136       activities =
 137         ActivityPub.fetch_public_activities(params)
 138         |> render_activities
 139
 140       info("Posts by #{user.nickname}") <> activities <> ".\r\n"
 141     else
 142       _e ->
 143         info("No such user") <> ".\r\n"
 144     end
 145   end
 146
 147   def loop(socket, transport) do
 148     case transport.recv(socket, 0, 5000) do
 149       {:ok, data} ->
 150         data = String.trim_trailing(data, "\r\n")
 151         transport.send(socket, response(data))
 152         :ok = transport.close(socket)
 153
 154       _ ->
 155         :ok = transport.close(socket)
 156     end
 157   end
 158 end