git.squeep.com Git - akkoma/blob - lib/pleroma/gopher/server.ex

   1 defmodule Pleroma.Gopher.Server do
   2   use GenServer
   3   require Logger
   4
   5   def start_link() do
   6     config = Pleroma.Config.get(:gopher, [])
   7     ip = Keyword.get(config, :ip, {0, 0, 0, 0})
   8     port = Keyword.get(config, :port, 1234)
   9     GenServer.start_link(__MODULE__, [ip, port], [])
  10   end
  11
  12   def init([ip, port]) do
  13     if Pleroma.Config.get([:gopher, :enabled], false) do
  14       Logger.info("Starting gopher server on #{port}")
  15
  16       :ranch.start_listener(
  17         :gopher,
  18         100,
  19         :ranch_tcp,
  20         [port: port],
  21         __MODULE__.ProtocolHandler,
  22         []
  23       )
  24
  25       {:ok, %{ip: ip, port: port}}
  26     else
  27       Logger.info("Gopher server disabled")
  28       {:ok, nil}
  29     end
  30   end
  31 end
  32
  33 defmodule Pleroma.Gopher.Server.ProtocolHandler do
  34   alias Pleroma.Web.ActivityPub.ActivityPub
  35   alias Pleroma.User
  36   alias Pleroma.Activity
  37   alias Pleroma.Repo
  38   alias Pleroma.HTML
  39
  40   def start_link(ref, socket, transport, opts) do
  41     pid = spawn_link(__MODULE__, :init, [ref, socket, transport, opts])
  42     {:ok, pid}
  43   end
  44
  45   def init(ref, socket, transport, _Opts = []) do
  46     :ok = :ranch.accept_ack(ref)
  47     loop(socket, transport)
  48   end
  49
  50   def info(text) do
  51     text = String.replace(text, ~r/[\t\n]/, "")
  52
  53     String.split(text, "\r")
  54     |> Enum.map(fn text ->
  55       "i#{text}\tfake\t(NULL)\t0\r\n"
  56     end)
  57     |> Enum.join("")
  58   end
  59
  60   def link(name, selector, type \\ 1) do
  61     address = Pleroma.Web.Endpoint.host()
  62     port = Pleroma.Config.get([:gopher, :port], 1234)
  63     "#{type}#{name}\t#{selector}\t#{address}\t#{port}\r\n"
  64   end
  65
  66   def render_activities(activities) do
  67     activities
  68     |> Enum.reverse()
  69     |> Enum.map(fn activity ->
  70       user = User.get_cached_by_ap_id(activity.data["actor"])
  71
  72       object = activity.data["object"]
  73       like_count = object["like_count"] || 0
  74       announcement_count = object["announcement_count"] || 0
  75
  76       link("Post ##{activity.id} by #{user.nickname}", "/notices/#{activity.id}") <>
  77         info("#{like_count} likes, #{announcement_count} repeats") <>
  78         "i\tfake\t(NULL)\t0\r\n" <>
  79         info(HTML.strip_tags(String.replace(activity.data["object"]["content"], "<br>", "\r")))
  80     end)
  81     |> Enum.join("i\tfake\t(NULL)\t0\r\n")
  82   end
  83
  84   def response("") do
  85     info("Welcome to #{Pleroma.Config.get([:instance, :name], "Pleroma")}!") <>
  86       link("Public Timeline", "/main/public") <>
  87       link("Federated Timeline", "/main/all") <> ".\r\n"
  88   end
  89
  90   def response("/main/public") do
  91     posts =
  92       ActivityPub.fetch_public_activities(%{"type" => ["Create"], "local_only" => true})
  93       |> render_activities
  94
  95     info("Welcome to the Public Timeline!") <> posts <> ".\r\n"
  96   end
  97
  98   def response("/main/all") do
  99     posts =
 100       ActivityPub.fetch_public_activities(%{"type" => ["Create"]})
 101       |> render_activities
 102
 103     info("Welcome to the Federated Timeline!") <> posts <> ".\r\n"
 104   end
 105
 106   def response("/notices/" <> id) do
 107     with %Activity{} = activity <- Repo.get(Activity, id),
 108          true <- ActivityPub.is_public?(activity) do
 109       activities =
 110         ActivityPub.fetch_activities_for_context(activity.data["context"])
 111         |> render_activities
 112
 113       user = User.get_cached_by_ap_id(activity.data["actor"])
 114
 115       info("Post #{activity.id} by #{user.nickname}") <>
 116         link("More posts by #{user.nickname}", "/users/#{user.nickname}") <> activities <> ".\r\n"
 117     else
 118       _e ->
 119         info("Not public") <> ".\r\n"
 120     end
 121   end
 122
 123   def response("/users/" <> nickname) do
 124     with %User{} = user <- User.get_cached_by_nickname(nickname) do
 125       params = %{
 126         "type" => ["Create"],
 127         "actor_id" => user.ap_id
 128       }
 129
 130       activities =
 131         ActivityPub.fetch_public_activities(params)
 132         |> render_activities
 133
 134       info("Posts by #{user.nickname}") <> activities <> ".\r\n"
 135     else
 136       _e ->
 137         info("No such user") <> ".\r\n"
 138     end
 139   end
 140
 141   def loop(socket, transport) do
 142     case transport.recv(socket, 0, 5000) do
 143       {:ok, data} ->
 144         data = String.trim_trailing(data, "\r\n")
 145         transport.send(socket, response(data))
 146         :ok = transport.close(socket)
 147
 148       _ ->
 149         :ok = transport.close(socket)
 150     end
 151   end
 152 end