git.squeep.com Git - akkoma/blob - lib/pleroma/gopher/server.ex

   1 defmodule Pleroma.Gopher.Server do
   2   use GenServer
   3   require Logger
   4   @gopher Application.get_env(:pleroma, :gopher)
   5
   6   def start_link() do
   7     ip = Keyword.get(@gopher, :ip, {0, 0, 0, 0})
   8     port = Keyword.get(@gopher, :port, 1234)
   9     GenServer.start_link(__MODULE__, [ip, port], [])
  10   end
  11
  12   def init([ip, port]) do
  13     if Keyword.get(@gopher, :enabled, false) do
  14       Logger.info("Starting gopher server on #{port}")
  15
  16       :ranch.start_listener(
  17         :gopher,
  18         100,
  19         :ranch_tcp,
  20         [port: port],
  21         __MODULE__.ProtocolHandler,
  22         []
  23       )
  24
  25       {:ok, %{ip: ip, port: port}}
  26     else
  27       Logger.info("Gopher server disabled")
  28       {:ok, nil}
  29     end
  30   end
  31 end
  32
  33 defmodule Pleroma.Gopher.Server.ProtocolHandler do
  34   alias Pleroma.Web.ActivityPub.ActivityPub
  35   alias Pleroma.User
  36   alias Pleroma.Activity
  37   alias Pleroma.Repo
  38
  39   @instance Application.get_env(:pleroma, :instance)
  40   @gopher Application.get_env(:pleroma, :gopher)
  41
  42   def start_link(ref, socket, transport, opts) do
  43     pid = spawn_link(__MODULE__, :init, [ref, socket, transport, opts])
  44     {:ok, pid}
  45   end
  46
  47   def init(ref, socket, transport, _Opts = []) do
  48     :ok = :ranch.accept_ack(ref)
  49     loop(socket, transport)
  50   end
  51
  52   def info(text) do
  53     "#{text}\tfake\(NULL)\t0\r\n"
  54   end
  55
  56   def link(name, selector, type \\ 1) do
  57     address = Pleroma.Web.Endpoint.host()
  58     port = Keyword.get(@gopher, :port, 1234)
  59     "#{type}#{name}\t#{selector}\t#{address}\t#{port}\r\n"
  60   end
  61
  62   def response("") do
  63     info("Welcome to #{Keyword.get(@instance, :name, "Pleroma")}!") <>
  64       link("Public Timeline", "/main/public") <>
  65       link("Federated Timeline", "/main/all") <> ".\r\n"
  66   end
  67
  68   def render_activities(activities) do
  69     activities
  70     |> Enum.reverse()
  71     |> Enum.map(fn activity ->
  72       user = User.get_cached_by_ap_id(activity.data["actor"])
  73
  74       object = activity.data["object"]
  75       like_count = object["like_count"] || 0
  76       announcement_count = object["announcement_count"] || 0
  77
  78       link("Post ##{activity.id} by #{user.nickname}", "/notices/#{activity.id}") <>
  79         info("#{like_count} likes, #{announcement_count} repeats") <>
  80         "\r\n" <> info(HtmlSanitizeEx.strip_tags(activity.data["object"]["content"]))
  81     end)
  82     |> Enum.join("\r\n")
  83   end
  84
  85   def response("/main/public") do
  86     posts =
  87       ActivityPub.fetch_public_activities(%{"type" => ["Create"], "local_only" => true})
  88       |> render_activities
  89
  90     info("Welcome to the Public Timeline!") <> posts <> ".\r\n"
  91   end
  92
  93   def response("/main/all") do
  94     posts =
  95       ActivityPub.fetch_public_activities(%{"type" => ["Create"]})
  96       |> render_activities
  97
  98     info("Welcome to the Federated Timeline!") <> posts <> ".\r\n"
  99   end
 100
 101   def response("/notices/" <> id) do
 102     with %Activity{} = activity <- Repo.get(Activity, id),
 103          true <- ActivityPub.is_public?(activity) do
 104       activities =
 105         ActivityPub.fetch_activities_for_context(activity.data["context"])
 106         |> render_activities
 107
 108       user = User.get_cached_by_ap_id(activity.data["actor"])
 109
 110       info("Post #{activity.id} by #{user.nickname}") <>
 111         link("More posts by #{user.nickname}", "/users/#{user.nickname}") <> activities <> ".\r\n"
 112     else
 113       _e ->
 114         info("Not public") <> ".\r\n"
 115     end
 116   end
 117
 118   def response("/users/" <> nickname) do
 119     with %User{} = user <- User.get_cached_by_nickname(nickname) do
 120       params = %{
 121         "type" => ["Create"],
 122         "actor_id" => user.ap_id
 123       }
 124
 125       activities =
 126         ActivityPub.fetch_public_activities(params)
 127         |> render_activities
 128
 129       info("Posts by #{user.nickname}") <> activities <> ".\r\n"
 130     else
 131       _e ->
 132         info("No such user") <> ".\r\n"
 133     end
 134   end
 135
 136   def loop(socket, transport) do
 137     case transport.recv(socket, 0, 5000) do
 138       {:ok, data} ->
 139         data = String.trim_trailing(data, "\r\n")
 140         transport.send(socket, response(data))
 141         :ok = transport.close(socket)
 142
 143       _ ->
 144         :ok = transport.close(socket)
 145     end
 146   end
 147 end