git.squeep.com Git - akkoma/blob - lib/pleroma/gopher/server.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Gopher.Server do
   6   use GenServer
   7   require Logger
   8
   9   def start_link() do
  10     config = Pleroma.Config.get(:gopher, [])
  11     ip = Keyword.get(config, :ip, {0, 0, 0, 0})
  12     port = Keyword.get(config, :port, 1234)
  13
  14     if Keyword.get(config, :enabled, false) do
  15       GenServer.start_link(__MODULE__, [ip, port], [])
  16     else
  17       Logger.info("Gopher server disabled")
  18       :ignore
  19     end
  20   end
  21
  22   def init([ip, port]) do
  23     Logger.info("Starting gopher server on #{port}")
  24
  25     :ranch.start_listener(
  26       :gopher,
  27       100,
  28       :ranch_tcp,
  29       [ip: ip, port: port],
  30       __MODULE__.ProtocolHandler,
  31       []
  32     )
  33
  34     {:ok, %{ip: ip, port: port}}
  35   end
  36 end
  37
  38 defmodule Pleroma.Gopher.Server.ProtocolHandler do
  39   alias Pleroma.Web.ActivityPub.ActivityPub
  40   alias Pleroma.User
  41   alias Pleroma.Activity
  42   alias Pleroma.Repo
  43   alias Pleroma.HTML
  44
  45   def start_link(ref, socket, transport, opts) do
  46     pid = spawn_link(__MODULE__, :init, [ref, socket, transport, opts])
  47     {:ok, pid}
  48   end
  49
  50   def init(ref, socket, transport, _Opts = []) do
  51     :ok = :ranch.accept_ack(ref)
  52     loop(socket, transport)
  53   end
  54
  55   def info(text) do
  56     text = String.replace(text, ~r/[\t\n]/, "")
  57
  58     String.split(text, "\r")
  59     |> Enum.map(fn text ->
  60       "i#{text}\tfake\t(NULL)\t0\r\n"
  61     end)
  62     |> Enum.join("")
  63   end
  64
  65   def link(name, selector, type \\ 1) do
  66     address = Pleroma.Web.Endpoint.host()
  67     port = Pleroma.Config.get([:gopher, :port], 1234)
  68     "#{type}#{name}\t#{selector}\t#{address}\t#{port}\r\n"
  69   end
  70
  71   def render_activities(activities) do
  72     activities
  73     |> Enum.reverse()
  74     |> Enum.map(fn activity ->
  75       user = User.get_cached_by_ap_id(activity.data["actor"])
  76
  77       object = activity.data["object"]
  78       like_count = object["like_count"] || 0
  79       announcement_count = object["announcement_count"] || 0
  80
  81       link("Post ##{activity.id} by #{user.nickname}", "/notices/#{activity.id}") <>
  82         info("#{like_count} likes, #{announcement_count} repeats") <>
  83         "i\tfake\t(NULL)\t0\r\n" <>
  84         info(HTML.strip_tags(String.replace(activity.data["object"]["content"], "<br>", "\r")))
  85     end)
  86     |> Enum.join("i\tfake\t(NULL)\t0\r\n")
  87   end
  88
  89   def response("") do
  90     info("Welcome to #{Pleroma.Config.get([:instance, :name], "Pleroma")}!") <>
  91       link("Public Timeline", "/main/public") <>
  92       link("Federated Timeline", "/main/all") <> ".\r\n"
  93   end
  94
  95   def response("/main/public") do
  96     posts =
  97       ActivityPub.fetch_public_activities(%{"type" => ["Create"], "local_only" => true})
  98       |> render_activities
  99
 100     info("Welcome to the Public Timeline!") <> posts <> ".\r\n"
 101   end
 102
 103   def response("/main/all") do
 104     posts =
 105       ActivityPub.fetch_public_activities(%{"type" => ["Create"]})
 106       |> render_activities
 107
 108     info("Welcome to the Federated Timeline!") <> posts <> ".\r\n"
 109   end
 110
 111   def response("/notices/" <> id) do
 112     with %Activity{} = activity <- Repo.get(Activity, id),
 113          true <- ActivityPub.is_public?(activity) do
 114       activities =
 115         ActivityPub.fetch_activities_for_context(activity.data["context"])
 116         |> render_activities
 117
 118       user = User.get_cached_by_ap_id(activity.data["actor"])
 119
 120       info("Post #{activity.id} by #{user.nickname}") <>
 121         link("More posts by #{user.nickname}", "/users/#{user.nickname}") <> activities <> ".\r\n"
 122     else
 123       _e ->
 124         info("Not public") <> ".\r\n"
 125     end
 126   end
 127
 128   def response("/users/" <> nickname) do
 129     with %User{} = user <- User.get_cached_by_nickname(nickname) do
 130       params = %{
 131         "type" => ["Create"],
 132         "actor_id" => user.ap_id
 133       }
 134
 135       activities =
 136         ActivityPub.fetch_public_activities(params)
 137         |> render_activities
 138
 139       info("Posts by #{user.nickname}") <> activities <> ".\r\n"
 140     else
 141       _e ->
 142         info("No such user") <> ".\r\n"
 143     end
 144   end
 145
 146   def loop(socket, transport) do
 147     case transport.recv(socket, 0, 5000) do
 148       {:ok, data} ->
 149         data = String.trim_trailing(data, "\r\n")
 150         transport.send(socket, response(data))
 151         :ok = transport.close(socket)
 152
 153       _ ->
 154         :ok = transport.close(socket)
 155     end
 156   end
 157 end