git.squeep.com Git - akkoma/blob - lib/pleroma/gopher/server.ex

   1 defmodule Pleroma.Gopher.Server do
   2   use GenServer
   3   require Logger
   4
   5   def start_link() do
   6     config = Pleroma.Config.get(:gopher, [])
   7     ip = Keyword.get(config, :ip, {0, 0, 0, 0})
   8     port = Keyword.get(config, :port, 1234)
   9
  10     if Keyword.get(config, :enabled, false) do
  11       GenServer.start_link(__MODULE__, [ip, port], [])
  12     else
  13       Logger.info("Gopher server disabled")
  14       :ignore
  15     end
  16   end
  17
  18   def init([ip, port]) do
  19     Logger.info("Starting gopher server on #{port}")
  20
  21     :ranch.start_listener(
  22       :gopher,
  23       100,
  24       :ranch_tcp,
  25       [ip: ip, port: port],
  26       __MODULE__.ProtocolHandler,
  27       []
  28     )
  29
  30     {:ok, %{ip: ip, port: port}}
  31   end
  32 end
  33
  34 defmodule Pleroma.Gopher.Server.ProtocolHandler do
  35   alias Pleroma.Web.ActivityPub.ActivityPub
  36   alias Pleroma.User
  37   alias Pleroma.Activity
  38   alias Pleroma.Repo
  39   alias Pleroma.HTML
  40
  41   def start_link(ref, socket, transport, opts) do
  42     pid = spawn_link(__MODULE__, :init, [ref, socket, transport, opts])
  43     {:ok, pid}
  44   end
  45
  46   def init(ref, socket, transport, _Opts = []) do
  47     :ok = :ranch.accept_ack(ref)
  48     loop(socket, transport)
  49   end
  50
  51   def info(text) do
  52     text = String.replace(text, ~r/[\t\n]/, "")
  53
  54     String.split(text, "\r")
  55     |> Enum.map(fn text ->
  56       "i#{text}\tfake\t(NULL)\t0\r\n"
  57     end)
  58     |> Enum.join("")
  59   end
  60
  61   def link(name, selector, type \\ 1) do
  62     address = Pleroma.Web.Endpoint.host()
  63     port = Pleroma.Config.get([:gopher, :port], 1234)
  64     "#{type}#{name}\t#{selector}\t#{address}\t#{port}\r\n"
  65   end
  66
  67   def render_activities(activities) do
  68     activities
  69     |> Enum.reverse()
  70     |> Enum.map(fn activity ->
  71       user = User.get_cached_by_ap_id(activity.data["actor"])
  72
  73       object = activity.data["object"]
  74       like_count = object["like_count"] || 0
  75       announcement_count = object["announcement_count"] || 0
  76
  77       link("Post ##{activity.id} by #{user.nickname}", "/notices/#{activity.id}") <>
  78         info("#{like_count} likes, #{announcement_count} repeats") <>
  79         "i\tfake\t(NULL)\t0\r\n" <>
  80         info(HTML.strip_tags(String.replace(activity.data["object"]["content"], "<br>", "\r")))
  81     end)
  82     |> Enum.join("i\tfake\t(NULL)\t0\r\n")
  83   end
  84
  85   def response("") do
  86     info("Welcome to #{Pleroma.Config.get([:instance, :name], "Pleroma")}!") <>
  87       link("Public Timeline", "/main/public") <>
  88       link("Federated Timeline", "/main/all") <> ".\r\n"
  89   end
  90
  91   def response("/main/public") do
  92     posts =
  93       ActivityPub.fetch_public_activities(%{"type" => ["Create"], "local_only" => true})
  94       |> render_activities
  95
  96     info("Welcome to the Public Timeline!") <> posts <> ".\r\n"
  97   end
  98
  99   def response("/main/all") do
 100     posts =
 101       ActivityPub.fetch_public_activities(%{"type" => ["Create"]})
 102       |> render_activities
 103
 104     info("Welcome to the Federated Timeline!") <> posts <> ".\r\n"
 105   end
 106
 107   def response("/notices/" <> id) do
 108     with %Activity{} = activity <- Repo.get(Activity, id),
 109          true <- ActivityPub.is_public?(activity) do
 110       activities =
 111         ActivityPub.fetch_activities_for_context(activity.data["context"])
 112         |> render_activities
 113
 114       user = User.get_cached_by_ap_id(activity.data["actor"])
 115
 116       info("Post #{activity.id} by #{user.nickname}") <>
 117         link("More posts by #{user.nickname}", "/users/#{user.nickname}") <> activities <> ".\r\n"
 118     else
 119       _e ->
 120         info("Not public") <> ".\r\n"
 121     end
 122   end
 123
 124   def response("/users/" <> nickname) do
 125     with %User{} = user <- User.get_cached_by_nickname(nickname) do
 126       params = %{
 127         "type" => ["Create"],
 128         "actor_id" => user.ap_id
 129       }
 130
 131       activities =
 132         ActivityPub.fetch_public_activities(params)
 133         |> render_activities
 134
 135       info("Posts by #{user.nickname}") <> activities <> ".\r\n"
 136     else
 137       _e ->
 138         info("No such user") <> ".\r\n"
 139     end
 140   end
 141
 142   def loop(socket, transport) do
 143     case transport.recv(socket, 0, 5000) do
 144       {:ok, data} ->
 145         data = String.trim_trailing(data, "\r\n")
 146         transport.send(socket, response(data))
 147         :ok = transport.close(socket)
 148
 149       _ ->
 150         :ok = transport.close(socket)
 151     end
 152   end
 153 end