git.squeep.com Git - akkoma/blob - lib/pleroma/gopher/server.ex

   1 defmodule Pleroma.Gopher.Server do
   2   use GenServer
   3   require Logger
   4   @gopher Application.get_env(:pleroma, :gopher)
   5
   6   def start_link() do
   7     ip = Keyword.get(@gopher, :ip, {0, 0, 0, 0})
   8     port = Keyword.get(@gopher, :port, 1234)
   9     GenServer.start_link(__MODULE__, [ip, port], [])
  10   end
  11
  12   def init([ip, port]) do
  13     if Keyword.get(@gopher, :enabled, false) do
  14       Logger.info("Starting gopher server on #{port}")
  15
  16       :ranch.start_listener(
  17         :gopher,
  18         100,
  19         :ranch_tcp,
  20         [port: port],
  21         __MODULE__.ProtocolHandler,
  22         []
  23       )
  24
  25       {:ok, %{ip: ip, port: port}}
  26     else
  27       Logger.info("Gopher server disabled")
  28       {:ok, nil}
  29     end
  30   end
  31 end
  32
  33 defmodule Pleroma.Gopher.Server.ProtocolHandler do
  34   alias Pleroma.Web.ActivityPub.ActivityPub
  35   alias Pleroma.User
  36   alias Pleroma.Activity
  37   alias Pleroma.Repo
  38
  39   @instance Application.get_env(:pleroma, :instance)
  40   @gopher Application.get_env(:pleroma, :gopher)
  41
  42   def start_link(ref, socket, transport, opts) do
  43     pid = spawn_link(__MODULE__, :init, [ref, socket, transport, opts])
  44     {:ok, pid}
  45   end
  46
  47   def init(ref, socket, transport, _Opts = []) do
  48     :ok = :ranch.accept_ack(ref)
  49     loop(socket, transport)
  50   end
  51
  52   def info(text) do
  53     "#{text}\tfake\(NULL)\t0\r\n"
  54   end
  55
  56   def link(name, selector, type \\ 1) do
  57     address = Pleroma.Web.Endpoint.host()
  58     port = Keyword.get(@gopher, :port, 1234)
  59     "#{type}#{name}\t#{selector}\t#{address}\t#{port}\r\n"
  60   end
  61
  62   def response("") do
  63     info("Welcome to #{Keyword.get(@instance, :name, "Pleroma")}!") <>
  64       link("Public Timeline", "/main/public") <>
  65       link("Federated Timeline", "/main/all") <> ".\r\n"
  66   end
  67
  68   def render_activities(activities) do
  69     activities
  70     |> Enum.reverse()
  71     |> Enum.map(fn activity ->
  72       user = User.get_cached_by_ap_id(activity.data["actor"])
  73
  74       link("Post ##{activity.id} by #{user.nickname}", "/notices/#{activity.id}") <>
  75         info(HtmlSanitizeEx.strip_tags(activity.data["object"]["content"]))
  76     end)
  77     |> Enum.join("\r\n")
  78   end
  79
  80   def response("/main/public") do
  81     posts =
  82       ActivityPub.fetch_public_activities(%{"type" => ["Create"], "local_only" => true})
  83       |> render_activities
  84
  85     info("Welcome to the Public Timeline!") <> posts <> ".\r\n"
  86   end
  87
  88   def response("/main/all") do
  89     posts =
  90       ActivityPub.fetch_public_activities(%{"type" => ["Create"]})
  91       |> render_activities
  92
  93     info("Welcome to the Federated Timeline!") <> posts <> ".\r\n"
  94   end
  95
  96   def response("/notices/" <> id) do
  97     with %Activity{} = activity <- Repo.get(Activity, id),
  98          true <- ActivityPub.is_public?(activity) do
  99       activities =
 100         ActivityPub.fetch_activities_for_context(activity.data["context"])
 101         |> render_activities
 102
 103       user = User.get_cached_by_ap_id(activity.data["actor"])
 104
 105       info("Post #{activity.id} by #{user.nickname}") <>
 106         link("More posts by #{user.nickname}", "/users/#{user.nickname}") <> activities <> ".\r\n"
 107     else
 108       _e ->
 109         info("Not public") <> ".\r\n"
 110     end
 111   end
 112
 113   def response("/users/" <> nickname) do
 114     with %User{} = user <- User.get_cached_by_nickname(nickname) do
 115       params = %{
 116         "type" => ["Create"],
 117         "actor_id" => user.ap_id
 118       }
 119
 120       activities =
 121         ActivityPub.fetch_public_activities(params)
 122         |> render_activities
 123
 124       info("Posts by #{user.nickname}") <> activities <> ".\r\n"
 125     else
 126       _e ->
 127         info("No such user") <> ".\r\n"
 128     end
 129   end
 130
 131   def loop(socket, transport) do
 132     case transport.recv(socket, 0, 5000) do
 133       {:ok, data} ->
 134         data = String.trim_trailing(data, "\r\n")
 135         transport.send(socket, response(data))
 136         :ok = transport.close(socket)
 137
 138       _ ->
 139         :ok = transport.close(socket)
 140     end
 141   end
 142 end