git.squeep.com Git - akkoma/blob - lib/pleroma/gopher/server.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Gopher.Server do
   6   use GenServer
   7   require Logger
   8
   9   def start_link do
  10     config = Pleroma.Config.get(:gopher, [])
  11     ip = Keyword.get(config, :ip, {0, 0, 0, 0})
  12     port = Keyword.get(config, :port, 1234)
  13
  14     if Keyword.get(config, :enabled, false) do
  15       GenServer.start_link(__MODULE__, [ip, port], [])
  16     else
  17       Logger.info("Gopher server disabled")
  18       :ignore
  19     end
  20   end
  21
  22   def init([ip, port]) do
  23     Logger.info("Starting gopher server on #{port}")
  24
  25     :ranch.start_listener(
  26       :gopher,
  27       100,
  28       :ranch_tcp,
  29       [ip: ip, port: port],
  30       __MODULE__.ProtocolHandler,
  31       []
  32     )
  33
  34     {:ok, %{ip: ip, port: port}}
  35   end
  36 end
  37
  38 defmodule Pleroma.Gopher.Server.ProtocolHandler do
  39   alias Pleroma.Activity
  40   alias Pleroma.HTML
  41   alias Pleroma.User
  42   alias Pleroma.Web.ActivityPub.ActivityPub
  43   alias Pleroma.Web.ActivityPub.Visibility
  44
  45   def start_link(ref, socket, transport, opts) do
  46     pid = spawn_link(__MODULE__, :init, [ref, socket, transport, opts])
  47     {:ok, pid}
  48   end
  49
  50   def init(ref, socket, transport, [] = _Opts) do
  51     :ok = :ranch.accept_ack(ref)
  52     loop(socket, transport)
  53   end
  54
  55   def info(text) do
  56     text = String.replace(text, ~r/[\t\n]/, "")
  57
  58     String.split(text, "\r")
  59     |> Enum.map(fn text ->
  60       "i#{text}\tfake\t(NULL)\t0\r\n"
  61     end)
  62     |> Enum.join("")
  63   end
  64
  65   def link(name, selector, type \\ 1) do
  66     address = Pleroma.Web.Endpoint.host()
  67     port = Pleroma.Config.get([:gopher, :port], 1234)
  68     dstport = Pleroma.Config.get([:gopher, :dstport], port)
  69     "#{type}#{name}\t#{selector}\t#{address}\t#{dstport}\r\n"
  70   end
  71
  72   def render_activities(activities) do
  73     activities
  74     |> Enum.reverse()
  75     |> Enum.map(fn activity ->
  76       user = User.get_cached_by_ap_id(activity.data["actor"])
  77
  78       object = activity.data["object"]
  79       like_count = object["like_count"] || 0
  80       announcement_count = object["announcement_count"] || 0
  81
  82       link("Post ##{activity.id} by #{user.nickname}", "/notices/#{activity.id}") <>
  83         info("#{like_count} likes, #{announcement_count} repeats") <>
  84         "i\tfake\t(NULL)\t0\r\n" <>
  85         info(HTML.strip_tags(String.replace(activity.data["object"]["content"], "<br>", "\r")))
  86     end)
  87     |> Enum.join("i\tfake\t(NULL)\t0\r\n")
  88   end
  89
  90   def response("") do
  91     info("Welcome to #{Pleroma.Config.get([:instance, :name], "Pleroma")}!") <>
  92       link("Public Timeline", "/main/public") <>
  93       link("Federated Timeline", "/main/all") <> ".\r\n"
  94   end
  95
  96   def response("/main/public") do
  97     posts =
  98       ActivityPub.fetch_public_activities(%{"type" => ["Create"], "local_only" => true})
  99       |> render_activities
 100
 101     info("Welcome to the Public Timeline!") <> posts <> ".\r\n"
 102   end
 103
 104   def response("/main/all") do
 105     posts =
 106       ActivityPub.fetch_public_activities(%{"type" => ["Create"]})
 107       |> render_activities
 108
 109     info("Welcome to the Federated Timeline!") <> posts <> ".\r\n"
 110   end
 111
 112   def response("/notices/" <> id) do
 113     with %Activity{} = activity <- Activity.get_by_id(id),
 114          true <- Visibility.is_public?(activity) do
 115       activities =
 116         ActivityPub.fetch_activities_for_context(activity.data["context"])
 117         |> render_activities
 118
 119       user = User.get_cached_by_ap_id(activity.data["actor"])
 120
 121       info("Post #{activity.id} by #{user.nickname}") <>
 122         link("More posts by #{user.nickname}", "/users/#{user.nickname}") <> activities <> ".\r\n"
 123     else
 124       _e ->
 125         info("Not public") <> ".\r\n"
 126     end
 127   end
 128
 129   def response("/users/" <> nickname) do
 130     with %User{} = user <- User.get_cached_by_nickname(nickname) do
 131       params = %{
 132         "type" => ["Create"],
 133         "actor_id" => user.ap_id
 134       }
 135
 136       activities =
 137         ActivityPub.fetch_public_activities(params)
 138         |> render_activities
 139
 140       info("Posts by #{user.nickname}") <> activities <> ".\r\n"
 141     else
 142       _e ->
 143         info("No such user") <> ".\r\n"
 144     end
 145   end
 146
 147   def loop(socket, transport) do
 148     case transport.recv(socket, 0, 5000) do
 149       {:ok, data} ->
 150         data = String.trim_trailing(data, "\r\n")
 151         transport.send(socket, response(data))
 152         :ok = transport.close(socket)
 153
 154       _ ->
 155         :ok = transport.close(socket)
 156     end
 157   end
 158 end