git.squeep.com Git - akkoma/blob - lib/pleroma/gopher/server.ex

   1 defmodule Pleroma.Gopher.Server do
   2   use GenServer
   3   require Logger
   4
   5   def start_link() do
   6     config = Pleroma.Config.get(:gopher, [])
   7     ip = Keyword.get(config, :ip, {0, 0, 0, 0})
   8     port = Keyword.get(config, :port, 1234)
   9
  10     if Keyword.get(config, :enabled, false) do
  11       GenServer.start_link(__MODULE__, [ip, port], [])
  12     else
  13       Logger.info("Gopher server disabled")
  14       :ignore
  15     end
  16   end
  17
  18   def init([ip, port]) do
  19     Logger.info("Starting gopher server on #{port}")
  20
  21     :ranch.start_listener(
  22       :gopher,
  23       100,
  24       :ranch_tcp,
  25       [port: port],
  26       __MODULE__.ProtocolHandler,
  27       []
  28     )
  29
  30     {:ok, %{ip: ip, port: port}}
  31   end
  32 end
  33
  34 defmodule Pleroma.Gopher.Server.ProtocolHandler do
  35   alias Pleroma.Web.ActivityPub.ActivityPub
  36   alias Pleroma.User
  37   alias Pleroma.Activity
  38   alias Pleroma.Repo
  39   alias Pleroma.HTML
  40   alias Pleroma.Object
  41
  42   def start_link(ref, socket, transport, opts) do
  43     pid = spawn_link(__MODULE__, :init, [ref, socket, transport, opts])
  44     {:ok, pid}
  45   end
  46
  47   def init(ref, socket, transport, _Opts = []) do
  48     :ok = :ranch.accept_ack(ref)
  49     loop(socket, transport)
  50   end
  51
  52   def info(text) do
  53     text = String.replace(text, ~r/[\t\n]/, "")
  54
  55     String.split(text, "\r")
  56     |> Enum.map(fn text ->
  57       "i#{text}\tfake\t(NULL)\t0\r\n"
  58     end)
  59     |> Enum.join("")
  60   end
  61
  62   def link(name, selector, type \\ 1) do
  63     address = Pleroma.Web.Endpoint.host()
  64     port = Pleroma.Config.get([:gopher, :port], 1234)
  65     "#{type}#{name}\t#{selector}\t#{address}\t#{port}\r\n"
  66   end
  67
  68   def render_activities(activities) do
  69     activities
  70     |> Enum.reverse()
  71     |> Enum.map(fn activity ->
  72       user = User.get_cached_by_ap_id(activity.data["actor"])
  73
  74       object = Object.normalize(activity.data["object"])
  75       like_count = object["like_count"] || 0
  76       announcement_count = object["announcement_count"] || 0
  77
  78       link("Post ##{activity.id} by #{user.nickname}", "/notices/#{activity.id}") <>
  79         info("#{like_count} likes, #{announcement_count} repeats") <>
  80         "i\tfake\t(NULL)\t0\r\n" <>
  81         info(HTML.strip_tags(String.replace(object["content"], "<br>", "\r")))
  82     end)
  83     |> Enum.join("i\tfake\t(NULL)\t0\r\n")
  84   end
  85
  86   def response("") do
  87     info("Welcome to #{Pleroma.Config.get([:instance, :name], "Pleroma")}!") <>
  88       link("Public Timeline", "/main/public") <>
  89       link("Federated Timeline", "/main/all") <> ".\r\n"
  90   end
  91
  92   def response("/main/public") do
  93     posts =
  94       ActivityPub.fetch_public_activities(%{"type" => ["Create"], "local_only" => true})
  95       |> render_activities
  96
  97     info("Welcome to the Public Timeline!") <> posts <> ".\r\n"
  98   end
  99
 100   def response("/main/all") do
 101     posts =
 102       ActivityPub.fetch_public_activities(%{"type" => ["Create"]})
 103       |> render_activities
 104
 105     info("Welcome to the Federated Timeline!") <> posts <> ".\r\n"
 106   end
 107
 108   def response("/notices/" <> id) do
 109     with %Activity{} = activity <- Repo.get(Activity, id),
 110          true <- ActivityPub.is_public?(activity) do
 111       activities =
 112         ActivityPub.fetch_activities_for_context(activity.data["context"])
 113         |> render_activities
 114
 115       user = User.get_cached_by_ap_id(activity.data["actor"])
 116
 117       info("Post #{activity.id} by #{user.nickname}") <>
 118         link("More posts by #{user.nickname}", "/users/#{user.nickname}") <> activities <> ".\r\n"
 119     else
 120       _e ->
 121         info("Not public") <> ".\r\n"
 122     end
 123   end
 124
 125   def response("/users/" <> nickname) do
 126     with %User{} = user <- User.get_cached_by_nickname(nickname) do
 127       params = %{
 128         "type" => ["Create"],
 129         "actor_id" => user.ap_id
 130       }
 131
 132       activities =
 133         ActivityPub.fetch_public_activities(params)
 134         |> render_activities
 135
 136       info("Posts by #{user.nickname}") <> activities <> ".\r\n"
 137     else
 138       _e ->
 139         info("No such user") <> ".\r\n"
 140     end
 141   end
 142
 143   def loop(socket, transport) do
 144     case transport.recv(socket, 0, 5000) do
 145       {:ok, data} ->
 146         data = String.trim_trailing(data, "\r\n")
 147         transport.send(socket, response(data))
 148         :ok = transport.close(socket)
 149
 150       _ ->
 151         :ok = transport.close(socket)
 152     end
 153   end
 154 end