git.squeep.com Git - akkoma/blob - lib/pleroma/formatter.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Formatter do
   6   alias Pleroma.HTML
   7   alias Pleroma.User
   8
   9   @safe_mention_regex ~r/^(\s*(?<mentions>(@.+?\s+){1,})+)(?<rest>.*)/s
  10   @link_regex ~r"((?:http(s)?:\/\/)?[\w.-]+(?:\.[\w\.-]+)+[\w\-\._~%:/?#[\]@!\$&'\(\)\*\+,;=.]+)|[0-9a-z+\-\.]+:[0-9a-z$-_.+!*'(),]+"ui
  11   @markdown_characters_regex ~r/(`|\*|_|{|}|[|]|\(|\)|#|\+|-|\.|!)/
  12
  13   @auto_linker_config hashtag: true,
  14                       hashtag_handler: &Pleroma.Formatter.hashtag_handler/4,
  15                       mention: true,
  16                       mention_handler: &Pleroma.Formatter.mention_handler/4
  17
  18   def escape_mention_handler("@" <> nickname = mention, buffer, _, _) do
  19     case User.get_cached_by_nickname(nickname) do
  20       %User{} ->
  21         # escape markdown characters with `\\`
  22         # (we don't want something like @user__name to be parsed by markdown)
  23         String.replace(mention, @markdown_characters_regex, "\\\\\\1")
  24
  25       _ ->
  26         buffer
  27     end
  28   end
  29
  30   def mention_handler("@" <> nickname, buffer, opts, acc) do
  31     case User.get_cached_by_nickname(nickname) do
  32       %User{id: id} = user ->
  33         ap_id = get_ap_id(user)
  34         nickname_text = get_nickname_text(nickname, opts)
  35
  36         link =
  37           ~s(<span class="h-card"><a data-user="#{id}" class="u-url mention" href="#{ap_id}" rel="ugc">@<span>#{
  38             nickname_text
  39           }</span></a></span>)
  40
  41         {link, %{acc | mentions: MapSet.put(acc.mentions, {"@" <> nickname, user})}}
  42
  43       _ ->
  44         {buffer, acc}
  45     end
  46   end
  47
  48   def hashtag_handler("#" <> tag = tag_text, _buffer, _opts, acc) do
  49     tag = String.downcase(tag)
  50     url = "#{Pleroma.Web.base_url()}/tag/#{tag}"
  51     link = ~s(<a class="hashtag" data-tag="#{tag}" href="#{url}" rel="tag ugc">#{tag_text}</a>)
  52
  53     {link, %{acc | tags: MapSet.put(acc.tags, {tag_text, tag})}}
  54   end
  55
  56   @doc """
  57   Parses a text and replace plain text links with HTML. Returns a tuple with a result text, mentions, and hashtags.
  58
  59   If the 'safe_mention' option is given, only consecutive mentions at the start the post are actually mentioned.
  60   """
  61   @spec linkify(String.t(), keyword()) ::
  62           {String.t(), [{String.t(), User.t()}], [{String.t(), String.t()}]}
  63   def linkify(text, options \\ []) do
  64     options = options ++ @auto_linker_config
  65
  66     if options[:safe_mention] && Regex.named_captures(@safe_mention_regex, text) do
  67       %{"mentions" => mentions, "rest" => rest} = Regex.named_captures(@safe_mention_regex, text)
  68       acc = %{mentions: MapSet.new(), tags: MapSet.new()}
  69
  70       {text_mentions, %{mentions: mentions}} = AutoLinker.link_map(mentions, acc, options)
  71       {text_rest, %{tags: tags}} = AutoLinker.link_map(rest, acc, options)
  72
  73       {text_mentions <> text_rest, MapSet.to_list(mentions), MapSet.to_list(tags)}
  74     else
  75       acc = %{mentions: MapSet.new(), tags: MapSet.new()}
  76       {text, %{mentions: mentions, tags: tags}} = AutoLinker.link_map(text, acc, options)
  77
  78       {text, MapSet.to_list(mentions), MapSet.to_list(tags)}
  79     end
  80   end
  81
  82   @doc """
  83   Escapes a special characters in mention names.
  84   """
  85   def mentions_escape(text, options \\ []) do
  86     options =
  87       Keyword.merge(options,
  88         mention: true,
  89         url: false,
  90         mention_handler: &Pleroma.Formatter.escape_mention_handler/4
  91       )
  92
  93     if options[:safe_mention] && Regex.named_captures(@safe_mention_regex, text) do
  94       %{"mentions" => mentions, "rest" => rest} = Regex.named_captures(@safe_mention_regex, text)
  95       AutoLinker.link(mentions, options) <> AutoLinker.link(rest, options)
  96     else
  97       AutoLinker.link(text, options)
  98     end
  99   end
 100
 101   def html_escape({text, mentions, hashtags}, type) do
 102     {html_escape(text, type), mentions, hashtags}
 103   end
 104
 105   def html_escape(text, "text/html") do
 106     HTML.filter_tags(text)
 107   end
 108
 109   def html_escape(text, "text/plain") do
 110     Regex.split(@link_regex, text, include_captures: true)
 111     |> Enum.map_every(2, fn chunk ->
 112       {:safe, part} = Phoenix.HTML.html_escape(chunk)
 113       part
 114     end)
 115     |> Enum.join("")
 116   end
 117
 118   def truncate(text, max_length \\ 200, omission \\ "...") do
 119     # Remove trailing whitespace
 120     text = Regex.replace(~r/([^ \t\r\n])([ \t]+$)/u, text, "\\g{1}")
 121
 122     if String.length(text) < max_length do
 123       text
 124     else
 125       length_with_omission = max_length - String.length(omission)
 126       String.slice(text, 0, length_with_omission) <> omission
 127     end
 128   end
 129
 130   defp get_ap_id(%User{source_data: %{"url" => url}}) when is_binary(url), do: url
 131   defp get_ap_id(%User{ap_id: ap_id}), do: ap_id
 132
 133   defp get_nickname_text(nickname, %{mentions_format: :full}), do: User.full_nickname(nickname)
 134   defp get_nickname_text(nickname, _), do: User.local_nickname(nickname)
 135 end