git.squeep.com Git - akkoma/blob - lib/pleroma/filter.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Filter do
   6   use Ecto.Schema
   7
   8   import Ecto.Changeset
   9   import Ecto.Query
  10
  11   alias Pleroma.User
  12   alias Pleroma.Repo
  13
  14   schema "filters" do
  15     belongs_to(:user, User, type: Pleroma.FlakeId)
  16     field(:filter_id, :integer)
  17     field(:hide, :boolean, default: false)
  18     field(:whole_word, :boolean, default: true)
  19     field(:phrase, :string)
  20     field(:context, {:array, :string})
  21     field(:expires_at, :utc_datetime)
  22
  23     timestamps()
  24   end
  25
  26   def get(id, %{id: user_id} = _user) do
  27     query =
  28       from(
  29         f in Pleroma.Filter,
  30         where: f.filter_id == ^id,
  31         where: f.user_id == ^user_id
  32       )
  33
  34     Repo.one(query)
  35   end
  36
  37   def get_filters(%User{id: user_id} = _user) do
  38     query =
  39       from(
  40         f in Pleroma.Filter,
  41         where: f.user_id == ^user_id
  42       )
  43
  44     Repo.all(query)
  45   end
  46
  47   def create(%Pleroma.Filter{user_id: user_id, filter_id: nil} = filter) do
  48     # If filter_id wasn't given, use the max filter_id for this user plus 1.
  49     # XXX This could result in a race condition if a user tries to add two
  50     # different filters for their account from two different clients at the
  51     # same time, but that should be unlikely.
  52
  53     max_id_query =
  54       from(
  55         f in Pleroma.Filter,
  56         where: f.user_id == ^user_id,
  57         select: max(f.filter_id)
  58       )
  59
  60     filter_id =
  61       case Repo.one(max_id_query) do
  62         # Start allocating from 1
  63         nil ->
  64           1
  65
  66         max_id ->
  67           max_id + 1
  68       end
  69
  70     filter
  71     |> Map.put(:filter_id, filter_id)
  72     |> Repo.insert()
  73   end
  74
  75   def create(%Pleroma.Filter{} = filter) do
  76     Repo.insert(filter)
  77   end
  78
  79   def delete(%Pleroma.Filter{id: filter_key} = filter) when is_number(filter_key) do
  80     Repo.delete(filter)
  81   end
  82
  83   def delete(%Pleroma.Filter{id: filter_key} = filter) when is_nil(filter_key) do
  84     %Pleroma.Filter{id: id} = get(filter.filter_id, %{id: filter.user_id})
  85
  86     filter
  87     |> Map.put(:id, id)
  88     |> Repo.delete()
  89   end
  90
  91   def update(%Pleroma.Filter{} = filter) do
  92     destination = Map.from_struct(filter)
  93
  94     Pleroma.Filter.get(filter.filter_id, %{id: filter.user_id})
  95     |> cast(destination, [:phrase, :context, :hide, :expires_at, :whole_word])
  96     |> Repo.update()
  97   end
  98 end