git.squeep.com Git - akkoma/blob - lib/pleroma/emoji.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2021 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Emoji do
   6   @moduledoc """
   7   This GenServer stores in an ETS table the list of the loaded emojis,
   8   and also allows to reload the list at runtime.
   9   """
  10   use GenServer
  11
  12   alias Pleroma.Emoji.Loader
  13
  14   require Logger
  15
  16   @ets __MODULE__.Ets
  17   @ets_options [
  18     :ordered_set,
  19     :protected,
  20     :named_table,
  21     {:read_concurrency, true}
  22   ]
  23
  24   defstruct [:code, :file, :tags, :safe_code, :safe_file]
  25
  26   @doc "Build emoji struct"
  27   def build({code, file, tags}) do
  28     %__MODULE__{
  29       code: code,
  30       file: file,
  31       tags: tags,
  32       safe_code: Pleroma.HTML.strip_tags(code),
  33       safe_file: Pleroma.HTML.strip_tags(file)
  34     }
  35   end
  36
  37   def build({code, file}), do: build({code, file, []})
  38
  39   @doc false
  40   def start_link(_) do
  41     GenServer.start_link(__MODULE__, [], name: __MODULE__)
  42   end
  43
  44   @doc "Reloads the emojis from disk."
  45   @spec reload() :: :ok
  46   def reload do
  47     GenServer.call(__MODULE__, :reload)
  48   end
  49
  50   @doc "Returns the path of the emoji `name`."
  51   @spec get(String.t()) :: String.t() | nil
  52   def get(name) do
  53     name = if String.starts_with?(name, ":") do
  54       name
  55       |> String.replace_leading(":", "")
  56       |> String.replace_trailing(":", "")
  57     else
  58       name
  59     end
  60
  61     case :ets.lookup(@ets, name) do
  62       [{_, path}] -> path
  63       _ -> nil
  64     end
  65   end
  66
  67   @spec exist?(String.t()) :: boolean()
  68   def exist?(name), do: not is_nil(get(name))
  69
  70   @doc "Returns all the emojos!!"
  71   @spec get_all() :: list({String.t(), String.t(), String.t()})
  72   def get_all do
  73     :ets.tab2list(@ets)
  74   end
  75
  76   @doc "Clear out old emojis"
  77   def clear_all, do: :ets.delete_all_objects(@ets)
  78
  79   @doc false
  80   def init(_) do
  81     @ets = :ets.new(@ets, @ets_options)
  82     GenServer.cast(self(), :reload)
  83     {:ok, nil}
  84   end
  85
  86   @doc false
  87   def handle_cast(:reload, state) do
  88     update_emojis(Loader.load())
  89     {:noreply, state}
  90   end
  91
  92   @doc false
  93   def handle_call(:reload, _from, state) do
  94     update_emojis(Loader.load())
  95     {:reply, :ok, state}
  96   end
  97
  98   @doc false
  99   def terminate(_, _) do
 100     :ok
 101   end
 102
 103   @doc false
 104   def code_change(_old_vsn, state, _extra) do
 105     update_emojis(Loader.load())
 106     {:ok, state}
 107   end
 108
 109   defp update_emojis(emojis) do
 110     :ets.insert(@ets, emojis)
 111   end
 112
 113   @external_resource "lib/pleroma/emoji-test.txt"
 114
 115   regional_indicators =
 116     Enum.map(127_462..127_487, fn codepoint ->
 117       <<codepoint::utf8>>
 118     end)
 119
 120   emojis =
 121     @external_resource
 122     |> File.read!()
 123     |> String.split("\n")
 124     |> Enum.filter(fn line ->
 125       line != "" and not String.starts_with?(line, "#") and
 126         String.contains?(line, "qualified")
 127     end)
 128     |> Enum.map(fn line ->
 129       line
 130       |> String.split(";", parts: 2)
 131       |> hd()
 132       |> String.trim()
 133       |> String.split()
 134       |> Enum.map(fn codepoint ->
 135         <<String.to_integer(codepoint, 16)::utf8>>
 136       end)
 137       |> Enum.join()
 138     end)
 139     |> Enum.uniq()
 140
 141   emojis = emojis ++ regional_indicators
 142
 143   for emoji <- emojis do
 144     def is_unicode_emoji?(unquote(emoji)), do: true
 145   end
 146
 147   def is_unicode_emoji?(_), do: false
 148 end