git.squeep.com Git - akkoma/blob - lib/pleroma/emoji/loader.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2021 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Emoji.Loader do
   6   @moduledoc """
   7   The Loader emoji from:
   8
   9     * emoji packs in INSTANCE-DIR/emoji
  10     * the files: `config/emoji.txt` and `config/custom_emoji.txt`
  11     * glob paths, nested folder is used as tag name for grouping e.g. priv/static/emoji/custom/nested_folder
  12   """
  13   alias Pleroma.Config
  14   alias Pleroma.Emoji
  15
  16   require Logger
  17
  18   @mix_env Mix.env()
  19
  20   @type pattern :: Regex.t() | module() | String.t()
  21   @type patterns :: pattern() | [pattern()]
  22   @type group_patterns :: keyword(patterns())
  23   @type emoji :: {String.t(), Emoji.t()}
  24
  25   @doc """
  26   Loads emojis from files/packs.
  27
  28   returns list emojis in format:
  29   `{"000", "/emoji/freespeechextremist.com/000.png", ["Custom"]}`
  30   """
  31   @spec load() :: list(emoji)
  32   def load do
  33     emoji_dir_path = Path.join(Config.get!([:instance, :static_dir]), "emoji")
  34
  35     emoji_groups = Config.get([:emoji, :groups])
  36
  37     emojis =
  38       case File.ls(emoji_dir_path) do
  39         {:error, :enoent} ->
  40           # The custom emoji directory doesn't exist,
  41           # don't do anything
  42           []
  43
  44         {:error, e} ->
  45           # There was some other error
  46           Logger.error("Could not access the custom emoji directory #{emoji_dir_path}: #{e}")
  47           []
  48
  49         {:ok, results} ->
  50           grouped =
  51             Enum.group_by(results, fn file ->
  52               File.dir?(Path.join(emoji_dir_path, file))
  53             end)
  54
  55           packs = grouped[true] || []
  56           files = grouped[false] || []
  57
  58           # Print the packs we've found
  59           Logger.info("Found emoji packs: #{Enum.join(packs, ", ")}")
  60
  61           if not Enum.empty?(files) do
  62             Logger.warn(
  63               "Found files in the emoji folder. These will be ignored, please move them to a subdirectory\nFound files: #{Enum.join(files, ", ")}"
  64             )
  65           end
  66
  67           emojis =
  68             Enum.flat_map(packs, fn pack ->
  69               load_pack(Path.join(emoji_dir_path, pack), emoji_groups)
  70             end)
  71
  72           Emoji.clear_all()
  73           emojis
  74       end
  75
  76     # Compat thing for old custom emoji handling & default emoji,
  77     # it should run even if there are no emoji packs
  78     shortcode_globs = Config.get([:emoji, :shortcode_globs], [])
  79
  80     # for testing emoji.txt entries we do not want exposed in normal operation
  81     test_emoji =
  82       if @mix_env == :test do
  83         load_from_file("test/config/emoji.txt", emoji_groups)
  84       else
  85         []
  86       end
  87
  88     emojis_txt =
  89       (load_from_file("config/emoji.txt", emoji_groups) ++
  90          load_from_file("config/custom_emoji.txt", emoji_groups) ++
  91          load_from_globs(shortcode_globs, emoji_groups) ++
  92          test_emoji)
  93       |> Enum.reject(fn value -> value == nil end)
  94
  95     Enum.map(emojis ++ emojis_txt, &prepare_emoji/1)
  96   end
  97
  98   defp prepare_emoji({code, _, _} = emoji), do: {code, Emoji.build(emoji)}
  99
 100   defp load_pack(pack_dir, emoji_groups) do
 101     pack_name = Path.basename(pack_dir)
 102
 103     pack_file = Path.join(pack_dir, "pack.json")
 104
 105     if File.exists?(pack_file) do
 106       Logger.info("Loading emoji pack from JSON: #{pack_file}")
 107       contents = Jason.decode!(File.read!(pack_file))
 108
 109       contents["files"]
 110       |> Enum.map(fn {name, rel_file} ->
 111         filename = Path.join("/emoji/#{pack_name}", rel_file)
 112         {name, filename, ["pack:#{pack_name}"]}
 113       end)
 114     else
 115       # Load from emoji.txt / all files
 116       emoji_txt = Path.join(pack_dir, "emoji.txt")
 117
 118       if File.exists?(emoji_txt) do
 119         Logger.info("Loading emoji pack from emoji.txt: #{emoji_txt}")
 120         load_from_file(emoji_txt, emoji_groups)
 121       else
 122         extensions = Config.get([:emoji, :pack_extensions])
 123
 124         Logger.info(
 125           "No emoji.txt found for pack \"#{pack_name}\", assuming all #{Enum.join(extensions, ", ")} files are emoji"
 126         )
 127
 128         make_shortcode_to_file_map(pack_dir, extensions)
 129         |> Enum.map(fn {shortcode, rel_file} ->
 130           filename = Path.join("/emoji/#{pack_name}", rel_file)
 131
 132           {shortcode, filename, [to_string(match_extra(emoji_groups, filename))]}
 133         end)
 134       end
 135     end
 136   end
 137
 138   def make_shortcode_to_file_map(pack_dir, exts) do
 139     find_all_emoji(pack_dir, exts)
 140     |> Enum.map(&Path.relative_to(&1, pack_dir))
 141     |> Enum.map(fn f -> {f |> Path.basename() |> Path.rootname(), f} end)
 142     |> Enum.into(%{})
 143   end
 144
 145   def find_all_emoji(dir, exts) do
 146     dir
 147     |> File.ls!()
 148     |> Enum.flat_map(fn f ->
 149       filepath = Path.join(dir, f)
 150
 151       if File.dir?(filepath) do
 152         find_all_emoji(filepath, exts)
 153       else
 154         [filepath]
 155       end
 156     end)
 157     |> Enum.filter(fn f -> Path.extname(f) in exts end)
 158   end
 159
 160   defp load_from_file(file, emoji_groups) do
 161     if File.exists?(file) do
 162       load_from_file_stream(File.stream!(file), emoji_groups)
 163     else
 164       []
 165     end
 166   end
 167
 168   defp load_from_file_stream(stream, emoji_groups) do
 169     stream
 170     |> Stream.map(&String.trim/1)
 171     |> Stream.map(fn line ->
 172       case String.split(line, ~r/,\s*/) do
 173         [name, file] ->
 174           {name, file, [to_string(match_extra(emoji_groups, file))]}
 175
 176         [name, file | tags] ->
 177           {name, file, tags}
 178
 179         _ ->
 180           nil
 181       end
 182     end)
 183     |> Enum.to_list()
 184   end
 185
 186   defp load_from_globs(globs, emoji_groups) do
 187     static_path = Path.join(:code.priv_dir(:pleroma), "static")
 188
 189     paths =
 190       Enum.map(globs, fn glob ->
 191         Path.join(static_path, glob)
 192         |> Path.wildcard()
 193       end)
 194       |> Enum.concat()
 195
 196     Enum.map(paths, fn path ->
 197       tag = match_extra(emoji_groups, Path.join("/", Path.relative_to(path, static_path)))
 198       shortcode = Path.basename(path, Path.extname(path))
 199       external_path = Path.join("/", Path.relative_to(path, static_path))
 200       {shortcode, external_path, [to_string(tag)]}
 201     end)
 202   end
 203
 204   @doc """
 205   Finds a matching group for the given emoji filename
 206   """
 207   @spec match_extra(group_patterns(), String.t()) :: atom() | nil
 208   def match_extra(group_patterns, filename) do
 209     match_group_patterns(group_patterns, fn pattern ->
 210       case pattern do
 211         %Regex{} = regex -> Regex.match?(regex, filename)
 212         string when is_binary(string) -> filename == string
 213       end
 214     end)
 215   end
 216
 217   defp match_group_patterns(group_patterns, matcher) do
 218     Enum.find_value(group_patterns, fn {group, patterns} ->
 219       patterns =
 220         patterns
 221         |> List.wrap()
 222         |> Enum.map(fn pattern ->
 223           if String.contains?(pattern, "*") do
 224             ~r(#{String.replace(pattern, "*", ".*")})
 225           else
 226             pattern
 227           end
 228         end)
 229
 230       Enum.any?(patterns, matcher) && group
 231     end)
 232   end
 233 end