git.squeep.com Git - akkoma/blob - lib/pleroma/elasticsearch/store.ex

   1 defmodule Pleroma.Elasticsearch do
   2   alias Pleroma.Activity
   3   alias Pleroma.User
   4   alias Pleroma.Elasticsearch.DocumentMappings
   5   alias Pleroma.Config
   6   require Logger
   7
   8   defp url do
   9     Config.get([:elasticsearch, :url])
  10   end
  11
  12   defp enabled? do
  13     Config.get([:search, :provider]) == Pleroma.Search.Elasticsearch
  14   end
  15
  16   def put_by_id(:activity, id) do
  17     id
  18     |> Activity.get_by_id_with_object()
  19     |> maybe_put_into_elasticsearch()
  20   end
  21
  22   def maybe_put_into_elasticsearch({:ok, item}) do
  23     maybe_put_into_elasticsearch(item)
  24   end
  25
  26   def maybe_put_into_elasticsearch(
  27         %{data: %{"type" => "Create"}, object: %{data: %{"type" => "Note"}}} = activity
  28       ) do
  29     if enabled?() do
  30       actor = Pleroma.Activity.user_actor(activity)
  31
  32       activity
  33       |> Map.put(:user_actor, actor)
  34       |> put()
  35     end
  36   end
  37
  38   def maybe_put_into_elasticsearch(%User{} = user) do
  39     if enabled?() do
  40       put(user)
  41     end
  42   end
  43
  44   def maybe_put_into_elasticsearch(_) do
  45     {:ok, :skipped}
  46   end
  47
  48   def put(%Activity{} = activity) do
  49     {:ok, _} =
  50       Elastix.Document.index(
  51         url(),
  52         "activities",
  53         "activity",
  54         DocumentMappings.Activity.id(activity),
  55         DocumentMappings.Activity.encode(activity)
  56       )
  57
  58     {:ok, _} =
  59       bulk_post(
  60         activity.object.hashtags,
  61         :hashtags
  62       )
  63   end
  64
  65   def put(%User{} = user) do
  66     {:ok, _} =
  67       Elastix.Document.index(
  68         url(),
  69         "users",
  70         "user",
  71         DocumentMappings.User.id(user),
  72         DocumentMappings.User.encode(user)
  73       )
  74   end
  75
  76   def bulk_post(data, :activities) do
  77     d =
  78       data
  79       |> Enum.filter(fn x ->
  80         t =
  81           x.object
  82           |> Map.get(:data, %{})
  83           |> Map.get("type", "")
  84
  85         t == "Note"
  86       end)
  87       |> Enum.map(fn d ->
  88         [
  89           %{index: %{_id: DocumentMappings.Activity.id(d)}},
  90           DocumentMappings.Activity.encode(d)
  91         ]
  92       end)
  93       |> List.flatten()
  94
  95     {:ok, %{body: %{"errors" => false}}} =
  96       Elastix.Bulk.post(
  97         url(),
  98         d,
  99         index: "activities",
 100         type: "activity"
 101       )
 102   end
 103
 104   def bulk_post(data, :users) do
 105     d =
 106       data
 107       |> Enum.filter(fn x -> x.actor_type == "Person" end)
 108       |> Enum.map(fn d ->
 109         [
 110           %{index: %{_id: DocumentMappings.User.id(d)}},
 111           DocumentMappings.User.encode(d)
 112         ]
 113       end)
 114       |> List.flatten()
 115
 116     Elastix.Bulk.post(
 117       url(),
 118       d,
 119       index: "users",
 120       type: "user"
 121     )
 122   end
 123
 124   def bulk_post([] = data, :hashtags) do
 125     d =
 126       data
 127       |> Enum.map(fn d ->
 128         [
 129           %{index: %{_id: DocumentMappings.Hashtag.id(d)}},
 130           DocumentMappings.Hashtag.encode(d)
 131         ]
 132       end)
 133       |> List.flatten()
 134
 135     Elastix.Bulk.post(
 136       url(),
 137       d,
 138       index: "hashtags",
 139       type: "hashtag"
 140     )
 141   end
 142
 143   def bulk_post(_, :hashtags), do: {:ok, nil}
 144
 145   def search(:raw, index, type, q) do
 146     with {:ok, raw_results} <- Elastix.Search.search(url(), index, [type], q) do
 147       results =
 148         raw_results
 149         |> Map.get(:body, %{})
 150         |> Map.get("hits", %{})
 151         |> Map.get("hits", [])
 152
 153       {:ok, results}
 154     else
 155       {:error, e} ->
 156         Logger.error(e)
 157         {:error, e}
 158     end
 159   end
 160
 161   def search(:activities, q) do
 162     with {:ok, results} <- search(:raw, "activities", "activity", q) do
 163       results
 164       |> Enum.map(fn result -> result["_id"] end)
 165       |> Pleroma.Activity.all_by_ids_with_object()
 166     else
 167       e ->
 168         Logger.error(e)
 169         []
 170     end
 171   end
 172
 173   def search(:users, q) do
 174     with {:ok, results} <- search(:raw, "users", "user", q) do
 175       results
 176       |> Enum.map(fn result -> result["_id"] end)
 177       |> Pleroma.User.get_all_by_ids()
 178     else
 179       e ->
 180         Logger.error(e)
 181         []
 182     end
 183   end
 184
 185   def search(:hashtags, q) do
 186     with {:ok, results} <- search(:raw, "hashtags", "hashtag", q) do
 187       results
 188       |> Enum.map(fn result -> result["_source"]["hashtag"] end)
 189     else
 190       e ->
 191         Logger.error(e)
 192         []
 193     end
 194   end
 195 end