git.squeep.com Git - akkoma/blob - lib/pleroma/conversation/participation.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Conversation.Participation do
   6   use Ecto.Schema
   7   alias Pleroma.Conversation
   8   alias Pleroma.Conversation.Participation.RecipientShip
   9   alias Pleroma.Repo
  10   alias Pleroma.User
  11   alias Pleroma.Web.ActivityPub.ActivityPub
  12   import Ecto.Changeset
  13   import Ecto.Query
  14
  15   schema "conversation_participations" do
  16     belongs_to(:user, User, type: Pleroma.FlakeId)
  17     belongs_to(:conversation, Conversation)
  18     field(:read, :boolean, default: false)
  19     field(:last_activity_id, Pleroma.FlakeId, virtual: true)
  20
  21     has_many(:recipient_ships, RecipientShip)
  22     has_many(:recipients, through: [:recipient_ships, :user])
  23
  24     timestamps()
  25   end
  26
  27   def creation_cng(struct, params) do
  28     struct
  29     |> cast(params, [:user_id, :conversation_id, :read])
  30     |> validate_required([:user_id, :conversation_id])
  31   end
  32
  33   def create_for_user_and_conversation(user, conversation, opts \\ []) do
  34     read = !!opts[:read]
  35
  36     %__MODULE__{}
  37     |> creation_cng(%{user_id: user.id, conversation_id: conversation.id, read: read})
  38     |> Repo.insert(
  39       on_conflict: [set: [read: read, updated_at: NaiveDateTime.utc_now()]],
  40       returning: true,
  41       conflict_target: [:user_id, :conversation_id]
  42     )
  43   end
  44
  45   def read_cng(struct, params) do
  46     struct
  47     |> cast(params, [:read])
  48     |> validate_required([:read])
  49   end
  50
  51   def mark_as_read(participation) do
  52     participation
  53     |> read_cng(%{read: true})
  54     |> Repo.update()
  55   end
  56
  57   def mark_as_unread(participation) do
  58     participation
  59     |> read_cng(%{read: false})
  60     |> Repo.update()
  61   end
  62
  63   def for_user(user, params \\ %{}) do
  64     from(p in __MODULE__,
  65       where: p.user_id == ^user.id,
  66       order_by: [desc: p.updated_at],
  67       preload: [conversation: [:users]]
  68     )
  69     |> Pleroma.Pagination.fetch_paginated(params)
  70     |> Map.get(:items)
  71   end
  72
  73   def for_user_and_conversation(user, conversation) do
  74     from(p in __MODULE__,
  75       where: p.user_id == ^user.id,
  76       where: p.conversation_id == ^conversation.id
  77     )
  78     |> Repo.one()
  79   end
  80
  81   def for_user_with_last_activity_id(user, params \\ %{}) do
  82     for_user(user, params)
  83     |> Enum.map(fn participation ->
  84       activity_id =
  85         ActivityPub.fetch_latest_activity_id_for_context(participation.conversation.ap_id, %{
  86           "user" => user,
  87           "blocking_user" => user
  88         })
  89
  90       %{
  91         participation
  92         | last_activity_id: activity_id
  93       }
  94     end)
  95     |> Enum.filter(& &1.last_activity_id)
  96   end
  97
  98   def get(_, _ \\ [])
  99   def get(nil, _), do: nil
 100
 101   def get(id, params) do
 102     query =
 103       if preload = params[:preload] do
 104         from(p in __MODULE__,
 105           preload: ^preload
 106         )
 107       else
 108         __MODULE__
 109       end
 110
 111     Repo.get(query, id)
 112   end
 113
 114   def set_recipients(participation, user_ids) do
 115     user_ids =
 116       [participation.user_id | user_ids]
 117       |> Enum.uniq()
 118
 119     Repo.transaction(fn ->
 120       query =
 121         from(r in RecipientShip,
 122           where: r.participation_id == ^participation.id
 123         )
 124
 125       Repo.delete_all(query)
 126
 127       users =
 128         from(u in User,
 129           where: u.id in ^user_ids
 130         )
 131         |> Repo.all()
 132
 133       RecipientShip.create(users, participation)
 134       :ok
 135     end)
 136
 137     {:ok, Repo.preload(participation, :recipients, force: true)}
 138   end
 139 end