git.squeep.com Git - akkoma/blob - lib/pleroma/config.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Config do
   6   defmodule Error do
   7     defexception [:message]
   8   end
   9
  10   def get(key), do: get(key, nil)
  11
  12   def get([key], default), do: get(key, default)
  13
  14   def get([_ | _] = path, default) do
  15     case fetch(path) do
  16       {:ok, value} -> value
  17       :error -> default
  18     end
  19   end
  20
  21   def get(key, default) do
  22     Application.get_env(:pleroma, key, default)
  23   end
  24
  25   def get!(key) do
  26     value = get(key, nil)
  27
  28     if value == nil do
  29       raise(Error, message: "Missing configuration value: #{inspect(key)}")
  30     else
  31       value
  32     end
  33   end
  34
  35   def fetch([root_key | keys]) do
  36     Enum.reduce_while(keys, Application.fetch_env(:pleroma, root_key), fn
  37       key, {:ok, config} when is_map(config) or is_list(config) ->
  38         case Access.fetch(config, key) do
  39           :error ->
  40             {:halt, :error}
  41
  42           value ->
  43             {:cont, value}
  44         end
  45
  46       _key, _config ->
  47         {:halt, :error}
  48     end)
  49   end
  50
  51   def put([key], value), do: put(key, value)
  52
  53   def put([parent_key | keys], value) do
  54     parent =
  55       Application.get_env(:pleroma, parent_key, [])
  56       |> put_in(keys, value)
  57
  58     Application.put_env(:pleroma, parent_key, parent)
  59   end
  60
  61   def put(key, value) do
  62     Application.put_env(:pleroma, key, value)
  63   end
  64
  65   def delete([key]), do: delete(key)
  66
  67   def delete([parent_key | keys] = path) do
  68     with {:ok, _} <- fetch(path) do
  69       {_, parent} =
  70         parent_key
  71         |> get()
  72         |> get_and_update_in(keys, fn _ -> :pop end)
  73
  74       Application.put_env(:pleroma, parent_key, parent)
  75     end
  76   end
  77
  78   def delete(key) do
  79     Application.delete_env(:pleroma, key)
  80   end
  81
  82   def oauth_consumer_strategies, do: get([:auth, :oauth_consumer_strategies], [])
  83
  84   def oauth_consumer_enabled?, do: oauth_consumer_strategies() != []
  85
  86   def enforce_oauth_admin_scope_usage?, do: !!get([:auth, :enforce_oauth_admin_scope_usage])
  87
  88   def oauth_admin_scopes(scopes) when is_list(scopes) do
  89     Enum.flat_map(
  90       scopes,
  91       fn scope ->
  92         ["admin:#{scope}"] ++
  93           if enforce_oauth_admin_scope_usage?(), do: [], else: [scope]
  94       end
  95     )
  96   end
  97 end