git.squeep.com Git - akkoma/blob - lib/pleroma/config.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Config do
   6   defmodule Error do
   7     defexception [:message]
   8   end
   9
  10   def get(key), do: get(key, nil)
  11
  12   def get([key], default), do: get(key, default)
  13
  14   def get([root_key | keys], default) do
  15     # This is to mimic Application.get_env/3 behaviour that returns `nil` if the
  16     # actual value is `nil`.
  17     Enum.reduce_while(keys, Application.get_env(:pleroma, root_key), fn key, config ->
  18       case key do
  19         [last_key] when is_map(config) ->
  20           {:halt, Map.get(config, last_key, default)}
  21
  22         [last_key] when is_list(config) ->
  23           {:halt, Keyword.get(config, last_key, default)}
  24
  25         _ ->
  26           case config do
  27             %{^key => value} ->
  28               {:cont, value}
  29
  30             [_ | _] ->
  31               case :lists.keyfind(key, 1, config) do
  32                 {_, value} -> {:cont, value}
  33                 _ -> {:halt, default}
  34               end
  35
  36             _ ->
  37               {:halt, default}
  38           end
  39       end
  40     end)
  41   end
  42
  43   def get(key, default) do
  44     Application.get_env(:pleroma, key, default)
  45   end
  46
  47   def get!(key) do
  48     value = get(key, nil)
  49
  50     if value == nil do
  51       raise(Error, message: "Missing configuration value: #{inspect(key)}")
  52     else
  53       value
  54     end
  55   end
  56
  57   def put([key], value), do: put(key, value)
  58
  59   def put([parent_key | keys], value) do
  60     parent =
  61       Application.get_env(:pleroma, parent_key, [])
  62       |> put_in(keys, value)
  63
  64     Application.put_env(:pleroma, parent_key, parent)
  65   end
  66
  67   def put(key, value) do
  68     Application.put_env(:pleroma, key, value)
  69   end
  70
  71   def delete([key]), do: delete(key)
  72
  73   def delete([parent_key | keys]) do
  74     {_, parent} =
  75       Application.get_env(:pleroma, parent_key)
  76       |> get_and_update_in(keys, fn _ -> :pop end)
  77
  78     Application.put_env(:pleroma, parent_key, parent)
  79   end
  80
  81   def delete(key) do
  82     Application.delete_env(:pleroma, key)
  83   end
  84
  85   def oauth_consumer_strategies, do: get([:auth, :oauth_consumer_strategies], [])
  86
  87   def oauth_consumer_enabled?, do: oauth_consumer_strategies() != []
  88
  89   def enforce_oauth_admin_scope_usage?, do: !!get([:auth, :enforce_oauth_admin_scope_usage])
  90
  91   def oauth_admin_scopes(scopes) when is_list(scopes) do
  92     Enum.flat_map(
  93       scopes,
  94       fn scope ->
  95         ["admin:#{scope}"] ++
  96           if enforce_oauth_admin_scope_usage?(), do: [], else: [scope]
  97       end
  98     )
  99   end
 100 end