git.squeep.com Git - akkoma/blob - lib/pleroma/config/transfer_task.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Config.TransferTask do
   6   use Task
   7
   8   alias Pleroma.ConfigDB
   9   alias Pleroma.Repo
  10
  11   require Logger
  12
  13   @type env() :: :test | :benchmark | :dev | :prod
  14
  15   @reboot_time_keys [
  16     {:pleroma, :hackney_pools},
  17     {:pleroma, :chat},
  18     {:pleroma, Oban},
  19     {:pleroma, :rate_limit},
  20     {:pleroma, :markup},
  21     {:plerome, :streamer}
  22   ]
  23
  24   @reboot_time_subkeys [
  25     {:pleroma, Pleroma.Captcha, [:seconds_valid]},
  26     {:pleroma, Pleroma.Upload, [:proxy_remote]},
  27     {:pleroma, :instance, [:upload_limit]},
  28     {:pleroma, :email_notifications, [:digest]},
  29     {:pleroma, :oauth2, [:clean_expired_tokens]},
  30     {:pleroma, Pleroma.ActivityExpiration, [:enabled]},
  31     {:pleroma, Pleroma.ScheduledActivity, [:enabled]},
  32     {:pleroma, :gopher, [:enabled]}
  33   ]
  34
  35   @reject [nil, :prometheus]
  36
  37   def start_link(_) do
  38     load_and_update_env()
  39     if Pleroma.Config.get(:env) == :test, do: Ecto.Adapters.SQL.Sandbox.checkin(Repo)
  40     :ignore
  41   end
  42
  43   @spec load_and_update_env([ConfigDB.t()]) :: :ok | false
  44   def load_and_update_env(deleted \\ [], restart_pleroma? \\ true) do
  45     with true <- Pleroma.Config.get(:configurable_from_database),
  46          true <- Ecto.Adapters.SQL.table_exists?(Repo, "config"),
  47          started_applications <- Application.started_applications() do
  48       # We need to restart applications for loaded settings take effect
  49
  50       in_db = Repo.all(ConfigDB)
  51
  52       with_deleted = in_db ++ deleted
  53
  54       reject_for_restart = if restart_pleroma?, do: @reject, else: [:pleroma | @reject]
  55
  56       applications =
  57         with_deleted
  58         |> Enum.map(&merge_and_update(&1))
  59         |> Enum.uniq()
  60         # TODO: some problem with prometheus after restart!
  61         |> Enum.reject(&(&1 in reject_for_restart))
  62
  63       # to be ensured that pleroma will be restarted last
  64       applications =
  65         if :pleroma in applications do
  66           List.delete(applications, :pleroma) ++ [:pleroma]
  67         else
  68           applications
  69         end
  70
  71       Enum.each(applications, &restart(started_applications, &1, Pleroma.Config.get(:env)))
  72
  73       :ok
  74     end
  75   end
  76
  77   defp merge_and_update(setting) do
  78     try do
  79       key = ConfigDB.from_string(setting.key)
  80       group = ConfigDB.from_string(setting.group)
  81
  82       default = Pleroma.Config.Holder.config(group, key)
  83       value = ConfigDB.from_binary(setting.value)
  84
  85       merged_value =
  86         if Ecto.get_meta(setting, :state) == :deleted do
  87           default
  88         else
  89           if can_be_merged?(default, value) do
  90             ConfigDB.merge_group(group, key, default, value)
  91           else
  92             value
  93           end
  94         end
  95
  96       :ok = update_env(group, key, merged_value)
  97
  98       if group != :logger do
  99         if group != :pleroma or pleroma_need_restart?(group, key, value) do
 100           group
 101         end
 102       else
 103         # change logger configuration in runtime, without restart
 104         if Keyword.keyword?(merged_value) and
 105              key not in [:compile_time_application, :backends, :compile_time_purge_matching] do
 106           Logger.configure_backend(key, merged_value)
 107         else
 108           Logger.configure([{key, merged_value}])
 109         end
 110
 111         nil
 112       end
 113     rescue
 114       error ->
 115         error_msg =
 116           "updating env causes error, group: " <>
 117             inspect(setting.group) <>
 118             " key: " <>
 119             inspect(setting.key) <>
 120             " value: " <>
 121             inspect(ConfigDB.from_binary(setting.value)) <> " error: " <> inspect(error)
 122
 123         Logger.warn(error_msg)
 124
 125         nil
 126     end
 127   end
 128
 129   @spec pleroma_need_restart?(atom(), atom(), any()) :: boolean()
 130   def pleroma_need_restart?(group, key, value) do
 131     group_and_key_need_reboot?(group, key) or group_and_subkey_need_reboot?(group, key, value)
 132   end
 133
 134   defp group_and_key_need_reboot?(group, key) do
 135     Enum.any?(@reboot_time_keys, fn {g, k} -> g == group and k == key end)
 136   end
 137
 138   defp group_and_subkey_need_reboot?(group, key, value) do
 139     Keyword.keyword?(value) and
 140       Enum.any?(@reboot_time_subkeys, fn {g, k, subkeys} ->
 141         g == group and k == key and
 142           Enum.any?(Keyword.keys(value), &(&1 in subkeys))
 143       end)
 144   end
 145
 146   defp update_env(group, key, nil), do: Application.delete_env(group, key)
 147   defp update_env(group, key, value), do: Application.put_env(group, key, value)
 148
 149   defp restart(_, :pleroma, env), do: Restarter.Pleroma.restart_after_boot(env)
 150
 151   defp restart(started_applications, app, _) do
 152     with {^app, _, _} <- List.keyfind(started_applications, app, 0),
 153          :ok <- Application.stop(app) do
 154       :ok = Application.start(app)
 155     else
 156       nil ->
 157         Logger.warn("#{app} is not started.")
 158
 159       error ->
 160         error
 161         |> inspect()
 162         |> Logger.warn()
 163     end
 164   end
 165
 166   defp can_be_merged?(val1, val2) when is_list(val1) and is_list(val2) do
 167     Keyword.keyword?(val1) and Keyword.keyword?(val2)
 168   end
 169
 170   defp can_be_merged?(_val1, _val2), do: false
 171 end