git.squeep.com Git - akkoma/blob - lib/pleroma/config/transfer_task.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Config.TransferTask do
   6   use Task
   7
   8   alias Pleroma.ConfigDB
   9   alias Pleroma.Repo
  10
  11   require Logger
  12
  13   @type env() :: :test | :benchmark | :dev | :prod
  14
  15   @reboot_time_keys [
  16     {:pleroma, :hackney_pools},
  17     {:pleroma, :chat},
  18     {:pleroma, Oban},
  19     {:pleroma, :rate_limit},
  20     {:pleroma, :markup},
  21     {:pleroma, :streamer},
  22     {:pleroma, :pools},
  23     {:pleroma, :connections_pool},
  24     {:tesla, :adapter}
  25   ]
  26
  27   @reboot_time_subkeys [
  28     {:pleroma, Pleroma.Captcha, [:seconds_valid]},
  29     {:pleroma, Pleroma.Upload, [:proxy_remote]},
  30     {:pleroma, :instance, [:upload_limit]},
  31     {:pleroma, :email_notifications, [:digest]},
  32     {:pleroma, :oauth2, [:clean_expired_tokens]},
  33     {:pleroma, Pleroma.ActivityExpiration, [:enabled]},
  34     {:pleroma, Pleroma.ScheduledActivity, [:enabled]},
  35     {:pleroma, :gopher, [:enabled]}
  36   ]
  37
  38   @reject [nil, :prometheus]
  39
  40   def start_link(_) do
  41     load_and_update_env()
  42     if Pleroma.Config.get(:env) == :test, do: Ecto.Adapters.SQL.Sandbox.checkin(Repo)
  43     :ignore
  44   end
  45
  46   @spec load_and_update_env([ConfigDB.t()]) :: :ok | false
  47   def load_and_update_env(deleted \\ [], restart_pleroma? \\ true) do
  48     with {:configurable, true} <-
  49            {:configurable, Pleroma.Config.get(:configurable_from_database)},
  50          true <- Ecto.Adapters.SQL.table_exists?(Repo, "config"),
  51          started_applications <- Application.started_applications() do
  52       # We need to restart applications for loaded settings take effect
  53
  54       in_db = Repo.all(ConfigDB)
  55
  56       with_deleted = in_db ++ deleted
  57
  58       reject_for_restart = if restart_pleroma?, do: @reject, else: [:pleroma | @reject]
  59
  60       applications =
  61         with_deleted
  62         |> Enum.map(&merge_and_update(&1))
  63         |> Enum.uniq()
  64         # TODO: some problem with prometheus after restart!
  65         |> Enum.reject(&(&1 in reject_for_restart))
  66
  67       # to be ensured that pleroma will be restarted last
  68       applications =
  69         if :pleroma in applications do
  70           List.delete(applications, :pleroma) ++ [:pleroma]
  71         else
  72           Restarter.Pleroma.rebooted()
  73           applications
  74         end
  75
  76       Enum.each(applications, &restart(started_applications, &1, Pleroma.Config.get(:env)))
  77
  78       :ok
  79     else
  80       {:configurable, false} -> Restarter.Pleroma.rebooted()
  81     end
  82   end
  83
  84   defp group_for_restart(:logger, key, _, merged_value) do
  85     # change logger configuration in runtime, without restart
  86     if Keyword.keyword?(merged_value) and
  87          key not in [:compile_time_application, :backends, :compile_time_purge_matching] do
  88       Logger.configure_backend(key, merged_value)
  89     else
  90       Logger.configure([{key, merged_value}])
  91     end
  92
  93     nil
  94   end
  95
  96   defp group_for_restart(:tesla, _, _, _), do: :pleroma
  97
  98   defp group_for_restart(group, _, _, _) when group != :pleroma, do: group
  99
 100   defp group_for_restart(group, key, value, _) do
 101     if pleroma_need_restart?(group, key, value) do
 102       group
 103     end
 104   end
 105
 106   defp merge_and_update(setting) do
 107     try do
 108       key = ConfigDB.from_string(setting.key)
 109       group = ConfigDB.from_string(setting.group)
 110
 111       default = Pleroma.Config.Holder.config(group, key)
 112       value = ConfigDB.from_binary(setting.value)
 113
 114       merged_value =
 115         if Ecto.get_meta(setting, :state) == :deleted do
 116           default
 117         else
 118           if can_be_merged?(default, value) do
 119             ConfigDB.merge_group(group, key, default, value)
 120           else
 121             value
 122           end
 123         end
 124
 125       :ok = update_env(group, key, merged_value)
 126
 127       group_for_restart(group, key, value, merged_value)
 128     rescue
 129       error ->
 130         error_msg =
 131           "updating env causes error, group: " <>
 132             inspect(setting.group) <>
 133             " key: " <>
 134             inspect(setting.key) <>
 135             " value: " <>
 136             inspect(ConfigDB.from_binary(setting.value)) <> " error: " <> inspect(error)
 137
 138         Logger.warn(error_msg)
 139
 140         nil
 141     end
 142   end
 143
 144   @spec pleroma_need_restart?(atom(), atom(), any()) :: boolean()
 145   def pleroma_need_restart?(group, key, value) do
 146     group_and_key_need_reboot?(group, key) or group_and_subkey_need_reboot?(group, key, value)
 147   end
 148
 149   defp group_and_key_need_reboot?(group, key) do
 150     Enum.any?(@reboot_time_keys, fn {g, k} -> g == group and k == key end)
 151   end
 152
 153   defp group_and_subkey_need_reboot?(group, key, value) do
 154     Keyword.keyword?(value) and
 155       Enum.any?(@reboot_time_subkeys, fn {g, k, subkeys} ->
 156         g == group and k == key and
 157           Enum.any?(Keyword.keys(value), &(&1 in subkeys))
 158       end)
 159   end
 160
 161   defp update_env(group, key, nil), do: Application.delete_env(group, key)
 162   defp update_env(group, key, value), do: Application.put_env(group, key, value)
 163
 164   defp restart(_, :pleroma, env), do: Restarter.Pleroma.restart_after_boot(env)
 165
 166   defp restart(started_applications, app, _) do
 167     with {^app, _, _} <- List.keyfind(started_applications, app, 0),
 168          :ok <- Application.stop(app) do
 169       :ok = Application.start(app)
 170     else
 171       nil ->
 172         Logger.warn("#{app} is not started.")
 173
 174       error ->
 175         error
 176         |> inspect()
 177         |> Logger.warn()
 178     end
 179   end
 180
 181   defp can_be_merged?(val1, val2) when is_list(val1) and is_list(val2) do
 182     Keyword.keyword?(val1) and Keyword.keyword?(val2)
 183   end
 184
 185   defp can_be_merged?(_val1, _val2), do: false
 186 end