git.squeep.com Git - akkoma/blob - lib/pleroma/config/transfer_task.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2021 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Config.TransferTask do
   6   use Task
   7
   8   alias Pleroma.Config
   9   alias Pleroma.ConfigDB
  10   alias Pleroma.Repo
  11
  12   require Logger
  13
  14   @type env() :: :test | :benchmark | :dev | :prod
  15
  16   defp reboot_time_keys,
  17     do: [
  18       {:pleroma, Oban},
  19       {:pleroma, :rate_limit},
  20       {:pleroma, :markup},
  21       {:pleroma, :streamer}
  22     ]
  23
  24   defp reboot_time_subkeys,
  25     do: [
  26       {:pleroma, Pleroma.Captcha, [:seconds_valid]},
  27       {:pleroma, Pleroma.Upload, [:proxy_remote]},
  28       {:pleroma, :instance, [:upload_limit]}
  29     ]
  30
  31   def start_link(restart_pleroma? \\ true) do
  32     load_and_update_env([], restart_pleroma?)
  33     if Config.get(:env) == :test, do: Ecto.Adapters.SQL.Sandbox.checkin(Repo)
  34     :ignore
  35   end
  36
  37   @spec load_and_update_env([ConfigDB.t()], boolean()) :: :ok
  38   def load_and_update_env(deleted_settings \\ [], restart_pleroma? \\ true) do
  39     with {_, true} <- {:configurable, Config.get(:configurable_from_database)} do
  40       # We need to restart applications for loaded settings take effect
  41
  42       {logger, other} =
  43         (Repo.all(ConfigDB) ++ deleted_settings)
  44         |> Enum.map(&merge_with_default/1)
  45         |> Enum.split_with(fn {group, _, _, _} -> group in [:logger, :quack] end)
  46
  47       logger
  48       |> Enum.sort()
  49       |> Enum.each(&configure/1)
  50
  51       started_applications = Application.started_applications()
  52
  53       # TODO: some problem with prometheus after restart!
  54       reject = [nil, :prometheus, :postgrex]
  55
  56       reject =
  57         if restart_pleroma? do
  58           reject
  59         else
  60           [:pleroma | reject]
  61         end
  62
  63       other
  64       |> Enum.map(&update/1)
  65       |> Enum.uniq()
  66       |> Enum.reject(&(&1 in reject))
  67       |> maybe_set_pleroma_last()
  68       |> Enum.each(&restart(started_applications, &1, Config.get(:env)))
  69
  70       :ok
  71     else
  72       {:configurable, false} -> Restarter.Pleroma.rebooted()
  73     end
  74   end
  75
  76   defp maybe_set_pleroma_last(apps) do
  77     # to be ensured that pleroma will be restarted last
  78     if :pleroma in apps do
  79       apps
  80       |> List.delete(:pleroma)
  81       |> List.insert_at(-1, :pleroma)
  82     else
  83       Restarter.Pleroma.rebooted()
  84       apps
  85     end
  86   end
  87
  88   defp merge_with_default(%{group: group, key: key, value: value} = setting) do
  89     default = Config.Holder.default_config(group, key)
  90
  91     merged =
  92       cond do
  93         Ecto.get_meta(setting, :state) == :deleted -> default
  94         can_be_merged?(default, value) -> ConfigDB.merge_group(group, key, default, value)
  95         true -> value
  96       end
  97
  98     {group, key, value, merged}
  99   end
 100
 101   # change logger configuration in runtime, without restart
 102   defp configure({:quack, key, _, merged}) do
 103     Logger.configure_backend(Quack.Logger, [{key, merged}])
 104     :ok = update_env(:quack, key, merged)
 105   end
 106
 107   defp configure({_, :backends, _, merged}) do
 108     # removing current backends
 109     Enum.each(Application.get_env(:logger, :backends), &Logger.remove_backend/1)
 110
 111     Enum.each(merged, &Logger.add_backend/1)
 112
 113     :ok = update_env(:logger, :backends, merged)
 114   end
 115
 116   defp configure({_, key, _, merged}) when key in [:console, :ex_syslogger] do
 117     merged =
 118       if key == :console do
 119         put_in(merged[:format], merged[:format] <> "\n")
 120       else
 121         merged
 122       end
 123
 124     backend =
 125       if key == :ex_syslogger,
 126         do: {ExSyslogger, :ex_syslogger},
 127         else: key
 128
 129     Logger.configure_backend(backend, merged)
 130     :ok = update_env(:logger, key, merged)
 131   end
 132
 133   defp configure({_, key, _, merged}) do
 134     Logger.configure([{key, merged}])
 135     :ok = update_env(:logger, key, merged)
 136   end
 137
 138   defp update({group, key, value, merged}) do
 139     try do
 140       :ok = update_env(group, key, merged)
 141
 142       if group != :pleroma or pleroma_need_restart?(group, key, value), do: group
 143     rescue
 144       error ->
 145         error_msg =
 146           "updating env causes error, group: #{inspect(group)}, key: #{inspect(key)}, value: #{inspect(value)} error: #{inspect(error)}"
 147
 148         Logger.warn(error_msg)
 149
 150         nil
 151     end
 152   end
 153
 154   defp update_env(group, key, nil), do: Application.delete_env(group, key)
 155   defp update_env(group, key, value), do: Application.put_env(group, key, value)
 156
 157   @spec pleroma_need_restart?(atom(), atom(), any()) :: boolean()
 158   def pleroma_need_restart?(group, key, value) do
 159     group_and_key_need_reboot?(group, key) or group_and_subkey_need_reboot?(group, key, value)
 160   end
 161
 162   defp group_and_key_need_reboot?(group, key) do
 163     Enum.any?(reboot_time_keys(), fn {g, k} -> g == group and k == key end)
 164   end
 165
 166   defp group_and_subkey_need_reboot?(group, key, value) do
 167     Keyword.keyword?(value) and
 168       Enum.any?(reboot_time_subkeys(), fn {g, k, subkeys} ->
 169         g == group and k == key and
 170           Enum.any?(Keyword.keys(value), &(&1 in subkeys))
 171       end)
 172   end
 173
 174   defp restart(_, :pleroma, env), do: Restarter.Pleroma.restart_after_boot(env)
 175
 176   defp restart(started_applications, app, _) do
 177     with {^app, _, _} <- List.keyfind(started_applications, app, 0),
 178          :ok <- Application.stop(app) do
 179       :ok = Application.start(app)
 180     else
 181       nil ->
 182         Logger.warn("#{app} is not started.")
 183
 184       error ->
 185         error
 186         |> inspect()
 187         |> Logger.warn()
 188     end
 189   end
 190
 191   defp can_be_merged?(val1, val2) when is_list(val1) and is_list(val2) do
 192     Keyword.keyword?(val1) and Keyword.keyword?(val2)
 193   end
 194
 195   defp can_be_merged?(_val1, _val2), do: false
 196 end