git.squeep.com Git - akkoma/blob - lib/pleroma/config/transfer_task.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Config.TransferTask do
   6   use Task
   7
   8   alias Pleroma.Config
   9   alias Pleroma.ConfigDB
  10   alias Pleroma.Repo
  11
  12   require Logger
  13
  14   @type env() :: :test | :benchmark | :dev | :prod
  15
  16   @reboot_time_keys [
  17     {:pleroma, :hackney_pools},
  18     {:pleroma, :chat},
  19     {:pleroma, Oban},
  20     {:pleroma, :rate_limit},
  21     {:pleroma, :markup},
  22     {:pleroma, :streamer},
  23     {:pleroma, :pools},
  24     {:pleroma, :connections_pool}
  25   ]
  26
  27   @reboot_time_subkeys [
  28     {:pleroma, Pleroma.Captcha, [:seconds_valid]},
  29     {:pleroma, Pleroma.Upload, [:proxy_remote]},
  30     {:pleroma, :instance, [:upload_limit]},
  31     {:pleroma, :email_notifications, [:digest]},
  32     {:pleroma, :oauth2, [:clean_expired_tokens]},
  33     {:pleroma, Pleroma.ActivityExpiration, [:enabled]},
  34     {:pleroma, Pleroma.ScheduledActivity, [:enabled]},
  35     {:pleroma, :gopher, [:enabled]}
  36   ]
  37
  38   def start_link(_) do
  39     load_and_update_env()
  40     if Config.get(:env) == :test, do: Ecto.Adapters.SQL.Sandbox.checkin(Repo)
  41     :ignore
  42   end
  43
  44   @spec load_and_update_env([ConfigDB.t()], boolean()) :: :ok
  45   def load_and_update_env(deleted_settings \\ [], restart_pleroma? \\ true) do
  46     with {_, true} <- {:configurable, Config.get(:configurable_from_database)} do
  47       # We need to restart applications for loaded settings take effect
  48
  49       # TODO: some problem with prometheus after restart!
  50       reject_restart =
  51         if restart_pleroma? do
  52           [nil, :prometheus]
  53         else
  54           [:pleroma, nil, :prometheus]
  55         end
  56
  57       started_applications = Application.started_applications()
  58
  59       (Repo.all(ConfigDB) ++ deleted_settings)
  60       |> Enum.map(&merge_and_update/1)
  61       |> Enum.uniq()
  62       |> Enum.reject(&(&1 in reject_restart))
  63       |> maybe_set_pleroma_last()
  64       |> Enum.each(&restart(started_applications, &1, Config.get(:env)))
  65
  66       :ok
  67     else
  68       {:configurable, false} -> Restarter.Pleroma.rebooted()
  69     end
  70   end
  71
  72   defp maybe_set_pleroma_last(apps) do
  73     # to be ensured that pleroma will be restarted last
  74     if :pleroma in apps do
  75       apps
  76       |> List.delete(:pleroma)
  77       |> List.insert_at(-1, :pleroma)
  78     else
  79       Restarter.Pleroma.rebooted()
  80       apps
  81     end
  82   end
  83
  84   defp group_for_restart(:logger, key, _, merged_value) do
  85     # change logger configuration in runtime, without restart
  86     if Keyword.keyword?(merged_value) and
  87          key not in [:compile_time_application, :backends, :compile_time_purge_matching] do
  88       Logger.configure_backend(key, merged_value)
  89     else
  90       Logger.configure([{key, merged_value}])
  91     end
  92
  93     nil
  94   end
  95
  96   defp group_for_restart(group, _, _, _) when group != :pleroma, do: group
  97
  98   defp group_for_restart(group, key, value, _) do
  99     if pleroma_need_restart?(group, key, value), do: group
 100   end
 101
 102   defp merge_and_update(setting) do
 103     try do
 104       key = ConfigDB.from_string(setting.key)
 105       group = ConfigDB.from_string(setting.group)
 106
 107       default = Config.Holder.default_config(group, key)
 108       value = ConfigDB.from_binary(setting.value)
 109
 110       merged_value =
 111         cond do
 112           Ecto.get_meta(setting, :state) == :deleted -> default
 113           can_be_merged?(default, value) -> ConfigDB.merge_group(group, key, default, value)
 114           true -> value
 115         end
 116
 117       :ok = update_env(group, key, merged_value)
 118
 119       group_for_restart(group, key, value, merged_value)
 120     rescue
 121       error ->
 122         error_msg =
 123           "updating env causes error, group: " <>
 124             inspect(setting.group) <>
 125             " key: " <>
 126             inspect(setting.key) <>
 127             " value: " <>
 128             inspect(ConfigDB.from_binary(setting.value)) <> " error: " <> inspect(error)
 129
 130         Logger.warn(error_msg)
 131
 132         nil
 133     end
 134   end
 135
 136   @spec pleroma_need_restart?(atom(), atom(), any()) :: boolean()
 137   def pleroma_need_restart?(group, key, value) do
 138     group_and_key_need_reboot?(group, key) or group_and_subkey_need_reboot?(group, key, value)
 139   end
 140
 141   defp group_and_key_need_reboot?(group, key) do
 142     Enum.any?(@reboot_time_keys, fn {g, k} -> g == group and k == key end)
 143   end
 144
 145   defp group_and_subkey_need_reboot?(group, key, value) do
 146     Keyword.keyword?(value) and
 147       Enum.any?(@reboot_time_subkeys, fn {g, k, subkeys} ->
 148         g == group and k == key and
 149           Enum.any?(Keyword.keys(value), &(&1 in subkeys))
 150       end)
 151   end
 152
 153   defp update_env(group, key, nil), do: Application.delete_env(group, key)
 154   defp update_env(group, key, value), do: Application.put_env(group, key, value)
 155
 156   defp restart(_, :pleroma, env), do: Restarter.Pleroma.restart_after_boot(env)
 157
 158   defp restart(started_applications, app, _) do
 159     with {^app, _, _} <- List.keyfind(started_applications, app, 0),
 160          :ok <- Application.stop(app) do
 161       :ok = Application.start(app)
 162     else
 163       nil ->
 164         Logger.warn("#{app} is not started.")
 165
 166       error ->
 167         error
 168         |> inspect()
 169         |> Logger.warn()
 170     end
 171   end
 172
 173   defp can_be_merged?(val1, val2) when is_list(val1) and is_list(val2) do
 174     Keyword.keyword?(val1) and Keyword.keyword?(val2)
 175   end
 176
 177   defp can_be_merged?(_val1, _val2), do: false
 178 end