git.squeep.com Git - akkoma/blob - lib/pleroma/config/transfer_task.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2021 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Config.TransferTask do
   6   use Task
   7
   8   alias Pleroma.Config
   9   alias Pleroma.ConfigDB
  10   alias Pleroma.Repo
  11
  12   require Logger
  13
  14   @type env() :: :test | :benchmark | :dev | :prod
  15
  16   defp reboot_time_keys,
  17     do: [
  18       {:pleroma, Oban},
  19       {:pleroma, :rate_limit},
  20       {:pleroma, :markup},
  21       {:pleroma, :streamer}
  22     ]
  23
  24   defp reboot_time_subkeys,
  25     do: [
  26       {:pleroma, Pleroma.Captcha, [:seconds_valid]},
  27       {:pleroma, Pleroma.Upload, [:proxy_remote]},
  28       {:pleroma, :instance, [:upload_limit]},
  29       {:pleroma, :http, [:pool_size]},
  30       {:pleroma, :http, [:proxy_url]}
  31     ]
  32
  33   def start_link(restart_pleroma? \\ true) do
  34     load_and_update_env([], restart_pleroma?)
  35     if Config.get(:env) == :test, do: Ecto.Adapters.SQL.Sandbox.checkin(Repo)
  36     :ignore
  37   end
  38
  39   @spec load_and_update_env([ConfigDB.t()], boolean()) :: :ok
  40   def load_and_update_env(deleted_settings \\ [], restart_pleroma? \\ true) do
  41     with {_, true} <- {:configurable, Config.get(:configurable_from_database)} do
  42       # We need to restart applications for loaded settings take effect
  43       {logger, other} =
  44         (Repo.all(ConfigDB) ++ deleted_settings)
  45         |> Enum.reject(&invalid_key_or_group/1)
  46         |> Enum.map(&merge_with_default/1)
  47         |> Enum.split_with(fn {group, _, _, _} -> group == :logger end)
  48
  49       logger
  50       |> Enum.sort()
  51       |> Enum.each(&configure/1)
  52
  53       started_applications = Application.started_applications()
  54
  55       reject = [nil, :postgrex]
  56
  57       reject =
  58         if restart_pleroma? do
  59           reject
  60         else
  61           [:pleroma | reject]
  62         end
  63
  64       other
  65       |> Enum.map(&update/1)
  66       |> Enum.uniq()
  67       |> Enum.reject(&(&1 in reject))
  68       |> maybe_set_pleroma_last()
  69       |> Enum.each(&restart(started_applications, &1, Config.get(:env)))
  70
  71       :ok
  72     else
  73       {:configurable, false} -> Restarter.Pleroma.rebooted()
  74     end
  75   end
  76
  77   defp maybe_set_pleroma_last(apps) do
  78     # to be ensured that pleroma will be restarted last
  79     if :pleroma in apps do
  80       apps
  81       |> List.delete(:pleroma)
  82       |> List.insert_at(-1, :pleroma)
  83     else
  84       Restarter.Pleroma.rebooted()
  85       apps
  86     end
  87   end
  88
  89   defp invalid_key_or_group(%ConfigDB{key: :invalid_atom}), do: true
  90   defp invalid_key_or_group(%ConfigDB{group: :invalid_atom}), do: true
  91   defp invalid_key_or_group(_), do: false
  92
  93   defp merge_with_default(%{group: group, key: key, value: value} = setting) do
  94     default =
  95       if group == :pleroma do
  96         Config.get([key], Config.Holder.default_config(group, key))
  97       else
  98         Config.Holder.default_config(group, key)
  99       end
 100
 101     merged =
 102       cond do
 103         Ecto.get_meta(setting, :state) == :deleted -> default
 104         can_be_merged?(default, value) -> ConfigDB.merge_group(group, key, default, value)
 105         true -> value
 106       end
 107
 108     {group, key, value, merged}
 109   end
 110
 111   defp configure({_, :backends, _, merged}) do
 112     # removing current backends
 113     Enum.each(Application.get_env(:logger, :backends), &Logger.remove_backend/1)
 114
 115     Enum.each(merged, &Logger.add_backend/1)
 116
 117     :ok = update_env(:logger, :backends, merged)
 118   end
 119
 120   defp configure({_, key, _, merged}) when key in [:console, :ex_syslogger] do
 121     merged =
 122       if key == :console do
 123         put_in(merged[:format], merged[:format] <> "\n")
 124       else
 125         merged
 126       end
 127
 128     backend =
 129       if key == :ex_syslogger,
 130         do: {ExSyslogger, :ex_syslogger},
 131         else: key
 132
 133     Logger.configure_backend(backend, merged)
 134     :ok = update_env(:logger, key, merged)
 135   end
 136
 137   defp configure({_, key, _, merged}) do
 138     Logger.configure([{key, merged}])
 139     :ok = update_env(:logger, key, merged)
 140   end
 141
 142   defp update({group, key, value, merged}) do
 143     try do
 144       :ok = update_env(group, key, merged)
 145
 146       if group != :pleroma or pleroma_need_restart?(group, key, value), do: group
 147     rescue
 148       error ->
 149         error_msg =
 150           "updating env causes error, group: #{inspect(group)}, key: #{inspect(key)}, value: #{inspect(value)} error: #{inspect(error)}"
 151
 152         Logger.warn(error_msg)
 153
 154         nil
 155     end
 156   end
 157
 158   defp update_env(group, key, nil), do: Application.delete_env(group, key)
 159   defp update_env(group, key, value), do: Application.put_env(group, key, value)
 160
 161   @spec pleroma_need_restart?(atom(), atom(), any()) :: boolean()
 162   def pleroma_need_restart?(group, key, value) do
 163     group_and_key_need_reboot?(group, key) or group_and_subkey_need_reboot?(group, key, value)
 164   end
 165
 166   defp group_and_key_need_reboot?(group, key) do
 167     Enum.any?(reboot_time_keys(), fn {g, k} -> g == group and k == key end)
 168   end
 169
 170   defp group_and_subkey_need_reboot?(group, key, value) do
 171     Keyword.keyword?(value) and
 172       Enum.any?(reboot_time_subkeys(), fn {g, k, subkeys} ->
 173         g == group and k == key and
 174           Enum.any?(Keyword.keys(value), &(&1 in subkeys))
 175       end)
 176   end
 177
 178   defp restart(_, :pleroma, env), do: Restarter.Pleroma.restart_after_boot(env)
 179
 180   defp restart(started_applications, app, _) do
 181     with {^app, _, _} <- List.keyfind(started_applications, app, 0),
 182          :ok <- Application.stop(app) do
 183       :ok = Application.start(app)
 184     else
 185       nil ->
 186         Logger.warn("#{app} is not started.")
 187
 188       error ->
 189         error
 190         |> inspect()
 191         |> Logger.warn()
 192     end
 193   end
 194
 195   defp can_be_merged?(val1, val2) when is_list(val1) and is_list(val2) do
 196     Keyword.keyword?(val1) and Keyword.keyword?(val2)
 197   end
 198
 199   defp can_be_merged?(_val1, _val2), do: false
 200 end