git.squeep.com Git - akkoma/blob - lib/pleroma/config/transfer_task.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2021 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Config.TransferTask do
   6   use Task
   7
   8   alias Pleroma.Config
   9   alias Pleroma.ConfigDB
  10   alias Pleroma.Repo
  11
  12   require Logger
  13
  14   @type env() :: :test | :benchmark | :dev | :prod
  15
  16   defp reboot_time_keys,
  17     do: [
  18       {:pleroma, :shout},
  19       {:pleroma, Oban},
  20       {:pleroma, :rate_limit},
  21       {:pleroma, :markup},
  22       {:pleroma, :streamer}
  23     ]
  24
  25   defp reboot_time_subkeys,
  26     do: [
  27       {:pleroma, Pleroma.Captcha, [:seconds_valid]},
  28       {:pleroma, Pleroma.Upload, [:proxy_remote]},
  29       {:pleroma, :instance, [:upload_limit]}
  30     ]
  31
  32   def start_link(restart_pleroma? \\ true) do
  33     load_and_update_env([], restart_pleroma?)
  34     if Config.get(:env) == :test, do: Ecto.Adapters.SQL.Sandbox.checkin(Repo)
  35     :ignore
  36   end
  37
  38   @spec load_and_update_env([ConfigDB.t()], boolean()) :: :ok
  39   def load_and_update_env(deleted_settings \\ [], restart_pleroma? \\ true) do
  40     with {_, true} <- {:configurable, Config.get(:configurable_from_database)} do
  41       # We need to restart applications for loaded settings take effect
  42
  43       {logger, other} =
  44         (Repo.all(ConfigDB) ++ deleted_settings)
  45         |> Enum.map(&merge_with_default/1)
  46         |> Enum.split_with(fn {group, _, _, _} -> group in [:logger, :quack] end)
  47
  48       logger
  49       |> Enum.sort()
  50       |> Enum.each(&configure/1)
  51
  52       started_applications = Application.started_applications()
  53
  54       # TODO: some problem with prometheus after restart!
  55       reject = [nil, :prometheus, :postgrex]
  56
  57       reject =
  58         if restart_pleroma? do
  59           reject
  60         else
  61           [:pleroma | reject]
  62         end
  63
  64       other
  65       |> Enum.map(&update/1)
  66       |> Enum.uniq()
  67       |> Enum.reject(&(&1 in reject))
  68       |> maybe_set_pleroma_last()
  69       |> Enum.each(&restart(started_applications, &1, Config.get(:env)))
  70
  71       :ok
  72     else
  73       {:configurable, false} -> Restarter.Pleroma.rebooted()
  74     end
  75   end
  76
  77   defp maybe_set_pleroma_last(apps) do
  78     # to be ensured that pleroma will be restarted last
  79     if :pleroma in apps do
  80       apps
  81       |> List.delete(:pleroma)
  82       |> List.insert_at(-1, :pleroma)
  83     else
  84       Restarter.Pleroma.rebooted()
  85       apps
  86     end
  87   end
  88
  89   defp merge_with_default(%{group: group, key: key, value: value} = setting) do
  90     default = Config.Holder.default_config(group, key)
  91
  92     merged =
  93       cond do
  94         Ecto.get_meta(setting, :state) == :deleted -> default
  95         can_be_merged?(default, value) -> ConfigDB.merge_group(group, key, default, value)
  96         true -> value
  97       end
  98
  99     {group, key, value, merged}
 100   end
 101
 102   # change logger configuration in runtime, without restart
 103   defp configure({:quack, key, _, merged}) do
 104     Logger.configure_backend(Quack.Logger, [{key, merged}])
 105     :ok = update_env(:quack, key, merged)
 106   end
 107
 108   defp configure({_, :backends, _, merged}) do
 109     # removing current backends
 110     Enum.each(Application.get_env(:logger, :backends), &Logger.remove_backend/1)
 111
 112     Enum.each(merged, &Logger.add_backend/1)
 113
 114     :ok = update_env(:logger, :backends, merged)
 115   end
 116
 117   defp configure({_, key, _, merged}) when key in [:console, :ex_syslogger] do
 118     merged =
 119       if key == :console do
 120         put_in(merged[:format], merged[:format] <> "\n")
 121       else
 122         merged
 123       end
 124
 125     backend =
 126       if key == :ex_syslogger,
 127         do: {ExSyslogger, :ex_syslogger},
 128         else: key
 129
 130     Logger.configure_backend(backend, merged)
 131     :ok = update_env(:logger, key, merged)
 132   end
 133
 134   defp configure({_, key, _, merged}) do
 135     Logger.configure([{key, merged}])
 136     :ok = update_env(:logger, key, merged)
 137   end
 138
 139   defp update({group, key, value, merged}) do
 140     try do
 141       :ok = update_env(group, key, merged)
 142
 143       if group != :pleroma or pleroma_need_restart?(group, key, value), do: group
 144     rescue
 145       error ->
 146         error_msg =
 147           "updating env causes error, group: #{inspect(group)}, key: #{inspect(key)}, value: #{inspect(value)} error: #{inspect(error)}"
 148
 149         Logger.warn(error_msg)
 150
 151         nil
 152     end
 153   end
 154
 155   defp update_env(group, key, nil), do: Application.delete_env(group, key)
 156   defp update_env(group, key, value), do: Application.put_env(group, key, value)
 157
 158   @spec pleroma_need_restart?(atom(), atom(), any()) :: boolean()
 159   def pleroma_need_restart?(group, key, value) do
 160     group_and_key_need_reboot?(group, key) or group_and_subkey_need_reboot?(group, key, value)
 161   end
 162
 163   defp group_and_key_need_reboot?(group, key) do
 164     Enum.any?(reboot_time_keys(), fn {g, k} -> g == group and k == key end)
 165   end
 166
 167   defp group_and_subkey_need_reboot?(group, key, value) do
 168     Keyword.keyword?(value) and
 169       Enum.any?(reboot_time_subkeys(), fn {g, k, subkeys} ->
 170         g == group and k == key and
 171           Enum.any?(Keyword.keys(value), &(&1 in subkeys))
 172       end)
 173   end
 174
 175   defp restart(_, :pleroma, env), do: Restarter.Pleroma.restart_after_boot(env)
 176
 177   defp restart(started_applications, app, _) do
 178     with {^app, _, _} <- List.keyfind(started_applications, app, 0),
 179          :ok <- Application.stop(app) do
 180       :ok = Application.start(app)
 181     else
 182       nil ->
 183         Logger.warn("#{app} is not started.")
 184
 185       error ->
 186         error
 187         |> inspect()
 188         |> Logger.warn()
 189     end
 190   end
 191
 192   defp can_be_merged?(val1, val2) when is_list(val1) and is_list(val2) do
 193     Keyword.keyword?(val1) and Keyword.keyword?(val2)
 194   end
 195
 196   defp can_be_merged?(_val1, _val2), do: false
 197 end