git.squeep.com Git - akkoma/blob - lib/pleroma/config/transfer_task.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Config.TransferTask do
   6   use Task
   7
   8   alias Pleroma.ConfigDB
   9   alias Pleroma.Repo
  10
  11   require Logger
  12
  13   @type env() :: :test | :benchmark | :dev | :prod
  14
  15   @reboot_time_keys [
  16     {:pleroma, :hackney_pools},
  17     {:pleroma, :chat},
  18     {:pleroma, Oban},
  19     {:pleroma, :rate_limit},
  20     {:pleroma, :markup},
  21     {:plerome, :streamer}
  22   ]
  23
  24   @reboot_time_subkeys [
  25     {:pleroma, Pleroma.Captcha, [:seconds_valid]},
  26     {:pleroma, Pleroma.Upload, [:proxy_remote]},
  27     {:pleroma, :instance, [:upload_limit]},
  28     {:pleroma, :email_notifications, [:digest]},
  29     {:pleroma, :oauth2, [:clean_expired_tokens]},
  30     {:pleroma, Pleroma.ActivityExpiration, [:enabled]},
  31     {:pleroma, Pleroma.ScheduledActivity, [:enabled]},
  32     {:pleroma, :gopher, [:enabled]}
  33   ]
  34
  35   @reject [nil, :prometheus]
  36
  37   def start_link(_) do
  38     load_and_update_env()
  39     if Pleroma.Config.get(:env) == :test, do: Ecto.Adapters.SQL.Sandbox.checkin(Repo)
  40     :ignore
  41   end
  42
  43   @spec load_and_update_env([ConfigDB.t()]) :: :ok | false
  44   def load_and_update_env(deleted \\ [], restart_pleroma? \\ true) do
  45     with {:configurable, true} <-
  46            {:configurable, Pleroma.Config.get(:configurable_from_database)},
  47          true <- Ecto.Adapters.SQL.table_exists?(Repo, "config"),
  48          started_applications <- Application.started_applications() do
  49       # We need to restart applications for loaded settings take effect
  50
  51       in_db = Repo.all(ConfigDB)
  52
  53       with_deleted = in_db ++ deleted
  54
  55       reject_for_restart = if restart_pleroma?, do: @reject, else: [:pleroma | @reject]
  56
  57       applications =
  58         with_deleted
  59         |> Enum.map(&merge_and_update(&1))
  60         |> Enum.uniq()
  61         # TODO: some problem with prometheus after restart!
  62         |> Enum.reject(&(&1 in reject_for_restart))
  63
  64       # to be ensured that pleroma will be restarted last
  65       applications =
  66         if :pleroma in applications do
  67           List.delete(applications, :pleroma) ++ [:pleroma]
  68         else
  69           Restarter.Pleroma.rebooted()
  70           applications
  71         end
  72
  73       Enum.each(applications, &restart(started_applications, &1, Pleroma.Config.get(:env)))
  74
  75       :ok
  76     else
  77       {:configurable, false} -> Restarter.Pleroma.rebooted()
  78     end
  79   end
  80
  81   defp merge_and_update(setting) do
  82     try do
  83       key = ConfigDB.from_string(setting.key)
  84       group = ConfigDB.from_string(setting.group)
  85
  86       default = Pleroma.Config.Holder.config(group, key)
  87       value = ConfigDB.from_binary(setting.value)
  88
  89       merged_value =
  90         if Ecto.get_meta(setting, :state) == :deleted do
  91           default
  92         else
  93           if can_be_merged?(default, value) do
  94             ConfigDB.merge_group(group, key, default, value)
  95           else
  96             value
  97           end
  98         end
  99
 100       :ok = update_env(group, key, merged_value)
 101
 102       if group != :logger do
 103         if group != :pleroma or pleroma_need_restart?(group, key, value) do
 104           group
 105         end
 106       else
 107         # change logger configuration in runtime, without restart
 108         if Keyword.keyword?(merged_value) and
 109              key not in [:compile_time_application, :backends, :compile_time_purge_matching] do
 110           Logger.configure_backend(key, merged_value)
 111         else
 112           Logger.configure([{key, merged_value}])
 113         end
 114
 115         nil
 116       end
 117     rescue
 118       error ->
 119         error_msg =
 120           "updating env causes error, group: " <>
 121             inspect(setting.group) <>
 122             " key: " <>
 123             inspect(setting.key) <>
 124             " value: " <>
 125             inspect(ConfigDB.from_binary(setting.value)) <> " error: " <> inspect(error)
 126
 127         Logger.warn(error_msg)
 128
 129         nil
 130     end
 131   end
 132
 133   @spec pleroma_need_restart?(atom(), atom(), any()) :: boolean()
 134   def pleroma_need_restart?(group, key, value) do
 135     group_and_key_need_reboot?(group, key) or group_and_subkey_need_reboot?(group, key, value)
 136   end
 137
 138   defp group_and_key_need_reboot?(group, key) do
 139     Enum.any?(@reboot_time_keys, fn {g, k} -> g == group and k == key end)
 140   end
 141
 142   defp group_and_subkey_need_reboot?(group, key, value) do
 143     Keyword.keyword?(value) and
 144       Enum.any?(@reboot_time_subkeys, fn {g, k, subkeys} ->
 145         g == group and k == key and
 146           Enum.any?(Keyword.keys(value), &(&1 in subkeys))
 147       end)
 148   end
 149
 150   defp update_env(group, key, nil), do: Application.delete_env(group, key)
 151   defp update_env(group, key, value), do: Application.put_env(group, key, value)
 152
 153   defp restart(_, :pleroma, env), do: Restarter.Pleroma.restart_after_boot(env)
 154
 155   defp restart(started_applications, app, _) do
 156     with {^app, _, _} <- List.keyfind(started_applications, app, 0),
 157          :ok <- Application.stop(app) do
 158       :ok = Application.start(app)
 159     else
 160       nil ->
 161         Logger.warn("#{app} is not started.")
 162
 163       error ->
 164         error
 165         |> inspect()
 166         |> Logger.warn()
 167     end
 168   end
 169
 170   defp can_be_merged?(val1, val2) when is_list(val1) and is_list(val2) do
 171     Keyword.keyword?(val1) and Keyword.keyword?(val2)
 172   end
 173
 174   defp can_be_merged?(_val1, _val2), do: false
 175 end