git.squeep.com Git - akkoma/blob - lib/pleroma/config/release_runtime_provider.ex

   1 defmodule Pleroma.Config.ReleaseRuntimeProvider do
   2   @moduledoc """
   3   Imports runtime config and `{env}.exported_from_db.secret.exs` for releases.
   4   """
   5   @behaviour Config.Provider
   6
   7   @impl true
   8   def init(opts), do: opts
   9
  10   @impl true
  11   def load(config, opts) do
  12     with_defaults = Config.Reader.merge(config, Pleroma.Config.Holder.release_defaults())
  13
  14     config_path = opts[:config_path]
  15
  16     with_runtime_config =
  17       if config_path && File.exists?(config_path) do
  18         runtime_config = Config.Reader.read!(config_path)
  19
  20         with_defaults
  21         |> Config.Reader.merge(pleroma: [config_path: config_path])
  22         |> Config.Reader.merge(runtime_config)
  23       else
  24         warning = [
  25           IO.ANSI.red(),
  26           IO.ANSI.bright(),
  27           "!!! Config path is not declared! Please ensure it exists and that PLEROMA_CONFIG_PATH is unset or points to an existing file",
  28           IO.ANSI.reset()
  29         ]
  30
  31         IO.puts(warning)
  32         with_defaults
  33       end
  34
  35     exported_config_path = opts[:exported_config_path]
  36
  37     with_exported =
  38       if exported_config_path && File.exists?(exported_config_path) do
  39         exported_config = Config.Reader.read!(exported_config_path)
  40         Config.Reader.merge(with_runtime_config, exported_config)
  41       else
  42         with_runtime_config
  43       end
  44
  45     with_exported
  46   end
  47 end