git.squeep.com Git - akkoma/blob - lib/pleroma/config/deprecation_warnings.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2021 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Config.DeprecationWarnings do
   6   alias Pleroma.Config
   7
   8   require Logger
   9   alias Pleroma.Config
  10
  11   @type config_namespace() :: atom() | [atom()]
  12   @type config_map() :: {config_namespace(), config_namespace(), String.t()}
  13
  14   @mrf_config_map [
  15     {[:instance, :rewrite_policy], [:mrf, :policies],
  16      "\n* `config :pleroma, :instance, rewrite_policy` is now `config :pleroma, :mrf, policies`"},
  17     {[:instance, :mrf_transparency], [:mrf, :transparency],
  18      "\n* `config :pleroma, :instance, mrf_transparency` is now `config :pleroma, :mrf, transparency`"},
  19     {[:instance, :mrf_transparency_exclusions], [:mrf, :transparency_exclusions],
  20      "\n* `config :pleroma, :instance, mrf_transparency_exclusions` is now `config :pleroma, :mrf, transparency_exclusions`"},
  21     {[:instance, :quarantined_instances], [:mrf_simple, :reject],
  22      "\n* `config :pleroma, :instance, :quarantined_instances` is now covered by `:pleroma, :mrf_simple, :reject`"}
  23   ]
  24
  25   def check_simple_policy_tuples do
  26     has_strings =
  27       Config.get([:mrf_simple])
  28       |> Enum.any?(fn {_, v} -> is_list(v) and Enum.any?(v, &is_binary/1) end)
  29
  30     if has_strings do
  31       Logger.warn("""
  32       !!!DEPRECATION WARNING!!!
  33       Your config is using strings in the SimplePolicy configuration instead of tuples. They should work for now, but you are advised to change to the new configuration to prevent possible issues later:
  34
  35       ```
  36       config :pleroma, :mrf_simple,
  37         media_removal: ["instance.tld"],
  38         media_nsfw: ["instance.tld"],
  39         federated_timeline_removal: ["instance.tld"],
  40         report_removal: ["instance.tld"],
  41         reject: ["instance.tld"],
  42         followers_only: ["instance.tld"],
  43         accept: ["instance.tld"],
  44         avatar_removal: ["instance.tld"],
  45         banner_removal: ["instance.tld"],
  46         reject_deletes: ["instance.tld"]
  47       ```
  48
  49       Is now
  50
  51
  52       ```
  53       config :pleroma, :mrf_simple,
  54         media_removal: [{"instance.tld", "Reason for media removal"}],
  55         media_nsfw: [{"instance.tld", "Reason for media nsfw"}],
  56         federated_timeline_removal: [{"instance.tld", "Reason for federated timeline removal"}],
  57         report_removal: [{"instance.tld", "Reason for report removal"}],
  58         reject: [{"instance.tld", "Reason for reject"}],
  59         followers_only: [{"instance.tld", "Reason for followers only"}],
  60         accept: [{"instance.tld", "Reason for accept"}],
  61         avatar_removal: [{"instance.tld", "Reason for avatar removal"}],
  62         banner_removal: [{"instance.tld", "Reason for banner removal"}],
  63         reject_deletes: [{"instance.tld", "Reason for reject deletes"}]
  64       ```
  65       """)
  66
  67       new_config =
  68         Config.get([:mrf_simple])
  69         |> Enum.filter(fn {_k, v} -> not is_atom(v) end)
  70         |> Enum.map(fn {k, v} ->
  71           {k,
  72            Enum.map(v, fn
  73              {instance, reason} -> {instance, reason}
  74              instance -> {instance, ""}
  75            end)}
  76         end)
  77
  78       Config.put([:mrf_simple], new_config)
  79
  80       :error
  81     else
  82       :ok
  83     end
  84   end
  85
  86   def check_quarantined_instances_tuples do
  87     has_strings = Config.get([:instance, :quarantined_instances], []) |> Enum.any?(&is_binary/1)
  88
  89     if has_strings do
  90       Logger.warn("""
  91       !!!DEPRECATION WARNING!!!
  92       Your config is using strings in the quarantined_instances configuration instead of tuples. They should work for now, but you are advised to change to the new configuration to prevent possible issues later:
  93
  94       ```
  95       config :pleroma, :instance,
  96         quarantined_instances: ["instance.tld"]
  97       ```
  98
  99       Is now
 100
 101
 102       ```
 103       config :pleroma, :instance,
 104         quarantined_instances: [{"instance.tld", "Reason for quarantine"}]
 105       ```
 106       """)
 107
 108       new_config =
 109         Config.get([:instance, :quarantined_instances])
 110         |> Enum.map(fn
 111           {instance, reason} -> {instance, reason}
 112           instance -> {instance, ""}
 113         end)
 114
 115       Config.put([:instance, :quarantined_instances], new_config)
 116
 117       :error
 118     else
 119       :ok
 120     end
 121   end
 122
 123   def check_transparency_exclusions_tuples do
 124     has_strings = Config.get([:mrf, :transparency_exclusions]) |> Enum.any?(&is_binary/1)
 125
 126     if has_strings do
 127       Logger.warn("""
 128       !!!DEPRECATION WARNING!!!
 129       Your config is using strings in the transparency_exclusions configuration instead of tuples. They should work for now, but you are advised to change to the new configuration to prevent possible issues later:
 130
 131       ```
 132       config :pleroma, :mrf,
 133         transparency_exclusions: ["instance.tld"]
 134       ```
 135
 136       Is now
 137
 138
 139       ```
 140       config :pleroma, :mrf,
 141         transparency_exclusions: [{"instance.tld", "Reason to exlude transparency"}]
 142       ```
 143       """)
 144
 145       new_config =
 146         Config.get([:mrf, :transparency_exclusions])
 147         |> Enum.map(fn
 148           {instance, reason} -> {instance, reason}
 149           instance -> {instance, ""}
 150         end)
 151
 152       Config.put([:mrf, :transparency_exclusions], new_config)
 153
 154       :error
 155     else
 156       :ok
 157     end
 158   end
 159
 160   def check_hellthread_threshold do
 161     if Config.get([:mrf_hellthread, :threshold]) do
 162       Logger.warn("""
 163       !!!DEPRECATION WARNING!!!
 164       You are using the old configuration mechanism for the hellthread filter. Please check config.md.
 165       """)
 166
 167       :error
 168     else
 169       :ok
 170     end
 171   end
 172
 173   def warn do
 174     [
 175       check_hellthread_threshold(),
 176       check_old_mrf_config(),
 177       check_media_proxy_whitelist_config(),
 178       check_welcome_message_config(),
 179       check_activity_expiration_config(),
 180       check_remote_ip_plug_name(),
 181       check_uploders_s3_public_endpoint(),
 182       check_quarantined_instances_tuples(),
 183       check_transparency_exclusions_tuples(),
 184       check_simple_policy_tuples(),
 185       check_http_adapter()
 186     ]
 187     |> Enum.reduce(:ok, fn
 188       :ok, :ok -> :ok
 189       _, _ -> :error
 190     end)
 191   end
 192
 193   def check_welcome_message_config do
 194     instance_config = Pleroma.Config.get([:instance])
 195
 196     use_old_config =
 197       Keyword.has_key?(instance_config, :welcome_user_nickname) or
 198         Keyword.has_key?(instance_config, :welcome_message)
 199
 200     if use_old_config do
 201       Logger.error("""
 202       !!!DEPRECATION WARNING!!!
 203       Your config is using the old namespace for Welcome messages configuration. You need to convert to the new namespace. e.g.,
 204       \n* `config :pleroma, :instance, welcome_user_nickname` and `config :pleroma, :instance, welcome_message` are now equal to:
 205       \n* `config :pleroma, :welcome, direct_message: [enabled: true, sender_nickname: "NICKNAME", message: "Your welcome message"]`"
 206       """)
 207
 208       :error
 209     else
 210       :ok
 211     end
 212   end
 213
 214   def check_http_adapter do
 215     http_adapter = Application.get_env(:tesla, :adapter)
 216
 217     case http_adapter do
 218       {Tesla.Adapter.Finch, _} ->
 219         :ok
 220
 221       Tesla.Mock ->
 222         # tests do be testing
 223         :ok
 224
 225       _anything_else ->
 226         Logger.error("""
 227         !!!CONFIG ERROR!!!
 228         Your config is using a custom tesla adapter, this was standardised
 229         to finch in 2022.06, and alternate adapters were removed in 2023.02.
 230         Please ensure you either:
 231         \n* do not have any custom value for `:tesla, :adapter`, or
 232         \n* have `config :tesla, :adapter, {Tesla.Adapter.Finch, name: MyFinch}`
 233         (your current value is #{inspect(http_adapter)})
 234         """)
 235
 236         :error
 237     end
 238   end
 239
 240   def check_old_mrf_config do
 241     warning_preface = """
 242     !!!DEPRECATION WARNING!!!
 243     Your config is using old namespaces for MRF configuration. They should work for now, but you are advised to change to new namespaces to prevent possible issues later:
 244     """
 245
 246     move_namespace_and_warn(@mrf_config_map, warning_preface)
 247   end
 248
 249   @spec move_namespace_and_warn([config_map()], String.t()) :: :ok | nil
 250   def move_namespace_and_warn(config_map, warning_preface) do
 251     warning =
 252       Enum.reduce(config_map, "", fn
 253         {old, new, err_msg}, acc ->
 254           old_config = Config.get(old)
 255
 256           if old_config do
 257             Config.put(new, old_config)
 258             acc <> err_msg
 259           else
 260             acc
 261           end
 262       end)
 263
 264     if warning == "" do
 265       :ok
 266     else
 267       Logger.warn(warning_preface <> warning)
 268       :error
 269     end
 270   end
 271
 272   @spec check_media_proxy_whitelist_config() :: :ok | nil
 273   def check_media_proxy_whitelist_config do
 274     whitelist = Config.get([:media_proxy, :whitelist])
 275
 276     if Enum.any?(whitelist, &(not String.starts_with?(&1, "http"))) do
 277       Logger.warn("""
 278       !!!DEPRECATION WARNING!!!
 279       Your config is using old format (only domain) for MediaProxy whitelist option. Setting should work for now, but you are advised to change format to scheme with port to prevent possible issues later.
 280       """)
 281
 282       :error
 283     else
 284       :ok
 285     end
 286   end
 287
 288   @spec check_activity_expiration_config() :: :ok | nil
 289   def check_activity_expiration_config do
 290     warning_preface = """
 291     !!!DEPRECATION WARNING!!!
 292       Your config is using old namespace for activity expiration configuration. Setting should work for now, but you are advised to change to new namespace to prevent possible issues later:
 293     """
 294
 295     move_namespace_and_warn(
 296       [
 297         {Pleroma.ActivityExpiration, Pleroma.Workers.PurgeExpiredActivity,
 298          "\n* `config :pleroma, Pleroma.ActivityExpiration` is now `config :pleroma, Pleroma.Workers.PurgeExpiredActivity`"}
 299       ],
 300       warning_preface
 301     )
 302   end
 303
 304   @spec check_remote_ip_plug_name() :: :ok | nil
 305   def check_remote_ip_plug_name do
 306     warning_preface = """
 307     !!!DEPRECATION WARNING!!!
 308     Your config is using old namespace for RemoteIp Plug. Setting should work for now, but you are advised to change to new namespace to prevent possible issues later:
 309     """
 310
 311     move_namespace_and_warn(
 312       [
 313         {Pleroma.Plugs.RemoteIp, Pleroma.Web.Plugs.RemoteIp,
 314          "\n* `config :pleroma, Pleroma.Plugs.RemoteIp` is now `config :pleroma, Pleroma.Web.Plugs.RemoteIp`"}
 315       ],
 316       warning_preface
 317     )
 318   end
 319
 320   @spec check_uploders_s3_public_endpoint() :: :ok | nil
 321   def check_uploders_s3_public_endpoint do
 322     s3_config = Pleroma.Config.get([Pleroma.Uploaders.S3])
 323
 324     use_old_config = Keyword.has_key?(s3_config, :public_endpoint)
 325
 326     if use_old_config do
 327       Logger.error("""
 328       !!!DEPRECATION WARNING!!!
 329       Your config is using the old setting for controlling the URL of media uploaded to your S3 bucket.\n
 330       Please make the following change at your earliest convenience.\n
 331       \n* `config :pleroma, Pleroma.Uploaders.S3, public_endpoint` is now equal to:
 332       \n* `config :pleroma, Pleroma.Upload, base_url`
 333       """)
 334
 335       :error
 336     else
 337       :ok
 338     end
 339   end
 340 end