git.squeep.com Git - akkoma/blob - lib/pleroma/config/config_db.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.ConfigDB do
   6   use Ecto.Schema
   7   import Ecto.Changeset
   8   import Ecto.Query
   9   import Pleroma.Web.Gettext
  10   alias __MODULE__
  11   alias Pleroma.Repo
  12
  13   @type t :: %__MODULE__{}
  14
  15   schema "config" do
  16     field(:key, :string)
  17     field(:group, :string)
  18     field(:value, :binary)
  19     field(:db, {:array, :string}, virtual: true, default: [])
  20
  21     timestamps()
  22   end
  23
  24   @spec get_all_as_keyword() :: keyword()
  25   def get_all_as_keyword do
  26     ConfigDB
  27     |> select([c], {c.group, c.key, c.value})
  28     |> Repo.all()
  29     |> Enum.reduce([], fn {group, key, value}, acc ->
  30       group = ConfigDB.from_string(group)
  31       key = ConfigDB.from_string(key)
  32       value = from_binary(value)
  33
  34       Keyword.update(acc, group, [{key, value}], &Keyword.merge(&1, [{key, value}]))
  35     end)
  36   end
  37
  38   @spec get_by_params(map()) :: ConfigDB.t() | nil
  39   def get_by_params(params), do: Repo.get_by(ConfigDB, params)
  40
  41   @spec changeset(ConfigDB.t(), map()) :: Changeset.t()
  42   def changeset(config, params \\ %{}) do
  43     params = Map.put(params, :value, transform(params[:value]))
  44
  45     config
  46     |> cast(params, [:key, :group, :value])
  47     |> validate_required([:key, :group, :value])
  48     |> unique_constraint(:key, name: :config_group_key_index)
  49   end
  50
  51   @spec create(map()) :: {:ok, ConfigDB.t()} | {:error, Changeset.t()}
  52   def create(params) do
  53     %ConfigDB{}
  54     |> changeset(params)
  55     |> Repo.insert()
  56   end
  57
  58   @spec update(ConfigDB.t(), map()) :: {:ok, ConfigDB.t()} | {:error, Changeset.t()}
  59   def update(%ConfigDB{} = config, %{value: value}) do
  60     config
  61     |> changeset(%{value: value})
  62     |> Repo.update()
  63   end
  64
  65   @spec get_db_keys(ConfigDB.t()) :: [String.t()]
  66   def get_db_keys(%ConfigDB{} = config) do
  67     config.value
  68     |> ConfigDB.from_binary()
  69     |> get_db_keys(config.key)
  70   end
  71
  72   @spec get_db_keys(keyword() | any()) :: [String.t()]
  73   def get_db_keys(value, key) do
  74     if Keyword.keyword?(value) do
  75       value |> Keyword.keys() |> Enum.map(&convert(&1))
  76     else
  77       [convert(key)]
  78     end
  79   end
  80
  81   @full_key_update [
  82     {:pleroma, :ecto_repos},
  83     {:pleroma, :assets},
  84     {:quack, :meta},
  85     {:mime, :types},
  86     {:cors_plug, [:max_age, :methods, :expose, :headers]},
  87     {:auto_linker, :opts},
  88     {:swarm, :node_blacklist},
  89     {:logger, :backends}
  90   ]
  91
  92   defp only_full_update?(%ConfigDB{} = config) do
  93     config_group = ConfigDB.from_string(config.group)
  94     config_key = ConfigDB.from_string(config.key)
  95
  96     Enum.any?(@full_key_update, fn
  97       {group, key} when is_list(key) ->
  98         config_group == group and config_key in key
  99
 100       {group, key} ->
 101         config_group == group and config_key == key
 102     end)
 103   end
 104
 105   defp can_be_partially_updated?(%ConfigDB{} = config), do: not only_full_update?(config)
 106
 107   @spec update_or_create(map()) :: {:ok, ConfigDB.t()} | {:error, Changeset.t()}
 108   def update_or_create(params) do
 109     search_opts = Map.take(params, [:group, :key])
 110
 111     with %ConfigDB{} = config <- ConfigDB.get_by_params(search_opts),
 112          {:partial_update, true, config} <-
 113            {:partial_update, can_be_partially_updated?(config), config},
 114          old_value <- from_binary(config.value),
 115          transformed_value <- do_transform(params[:value]),
 116          {:can_be_merged, true, config} <- {:can_be_merged, is_list(transformed_value), config},
 117          new_value <- DeepMerge.deep_merge(old_value, transformed_value) do
 118       ConfigDB.update(config, %{value: new_value, transformed?: true})
 119     else
 120       {reason, false, config} when reason in [:partial_update, :can_be_merged] ->
 121         ConfigDB.update(config, params)
 122
 123       nil ->
 124         ConfigDB.create(params)
 125     end
 126   end
 127
 128   @spec delete(map()) :: {:ok, ConfigDB.t()} | {:error, Changeset.t()} | {:ok, nil}
 129   def delete(params) do
 130     search_opts = Map.delete(params, :subkeys)
 131
 132     with %ConfigDB{} = config <- ConfigDB.get_by_params(search_opts),
 133          {config, sub_keys} when is_list(sub_keys) <- {config, params[:subkeys]},
 134          old_value <- from_binary(config.value),
 135          keys <- Enum.map(sub_keys, &do_transform_string(&1)),
 136          new_value <- Keyword.drop(old_value, keys) do
 137       ConfigDB.update(config, %{value: new_value})
 138     else
 139       {config, nil} ->
 140         Repo.delete(config)
 141         {:ok, nil}
 142
 143       nil ->
 144         err =
 145           dgettext("errors", "Config with params %{params} not found", params: inspect(params))
 146
 147         {:error, err}
 148     end
 149   end
 150
 151   @spec from_binary(binary()) :: term()
 152   def from_binary(binary), do: :erlang.binary_to_term(binary)
 153
 154   @spec from_binary_with_convert(binary()) :: any()
 155   def from_binary_with_convert(binary) do
 156     binary
 157     |> from_binary()
 158     |> do_convert()
 159   end
 160
 161   @spec from_string(String.t()) :: atom() | no_return()
 162   def from_string(":" <> entity), do: String.to_existing_atom(entity)
 163
 164   def from_string(entity) when is_binary(entity) do
 165     if is_module_name?(entity) do
 166       String.to_existing_atom("Elixir.#{entity}")
 167     else
 168       entity
 169     end
 170   end
 171
 172   @spec convert(any()) :: any()
 173   def convert(entity), do: do_convert(entity)
 174
 175   defp do_convert(entity) when is_list(entity) do
 176     for v <- entity, into: [], do: do_convert(v)
 177   end
 178
 179   defp do_convert(%Regex{} = entity), do: inspect(entity)
 180
 181   defp do_convert(entity) when is_map(entity) do
 182     for {k, v} <- entity, into: %{}, do: {do_convert(k), do_convert(v)}
 183   end
 184
 185   defp do_convert({:proxy_url, {type, :localhost, port}}) do
 186     %{"tuple" => [":proxy_url", %{"tuple" => [do_convert(type), "localhost", port]}]}
 187   end
 188
 189   defp do_convert({:proxy_url, {type, host, port}}) when is_tuple(host) do
 190     ip =
 191       host
 192       |> :inet_parse.ntoa()
 193       |> to_string()
 194
 195     %{
 196       "tuple" => [
 197         ":proxy_url",
 198         %{"tuple" => [do_convert(type), ip, port]}
 199       ]
 200     }
 201   end
 202
 203   defp do_convert({:proxy_url, {type, host, port}}) do
 204     %{
 205       "tuple" => [
 206         ":proxy_url",
 207         %{"tuple" => [do_convert(type), to_string(host), port]}
 208       ]
 209     }
 210   end
 211
 212   # TODO: will become useless after removing hackney
 213   defp do_convert({:partial_chain, entity}), do: %{"tuple" => [":partial_chain", inspect(entity)]}
 214
 215   defp do_convert(entity) when is_tuple(entity),
 216     do: %{"tuple" => do_convert(Tuple.to_list(entity))}
 217
 218   defp do_convert(entity) when is_boolean(entity) or is_number(entity) or is_nil(entity),
 219     do: entity
 220
 221   defp do_convert(entity)
 222        when is_atom(entity) and entity in [:"tlsv1.1", :"tlsv1.2", :"tlsv1.3"] do
 223     ":#{to_string(entity)}"
 224   end
 225
 226   defp do_convert(entity) when is_atom(entity), do: inspect(entity)
 227
 228   defp do_convert(entity) when is_binary(entity), do: entity
 229
 230   @spec transform(any()) :: binary() | no_return()
 231   def transform(entity) when is_binary(entity) or is_map(entity) or is_list(entity) do
 232     entity
 233     |> do_transform()
 234     |> to_binary()
 235   end
 236
 237   def transform(entity), do: to_binary(entity)
 238
 239   @spec to_binary(any()) :: binary()
 240   def to_binary(entity), do: :erlang.term_to_binary(entity)
 241
 242   defp do_transform(%Regex{} = entity), do: entity
 243
 244   defp do_transform(%{"tuple" => [":proxy_url", %{"tuple" => [type, host, port]}]}) do
 245     {:proxy_url, {do_transform_string(type), parse_host(host), port}}
 246   end
 247
 248   # TODO: will become useless after removing hackney
 249   defp do_transform(%{"tuple" => [":partial_chain", entity]}) do
 250     {partial_chain, []} =
 251       entity
 252       |> String.replace(~r/[^\w|^{:,[|^,|^[|^\]^}|^\/|^\.|^"]^\s/, "")
 253       |> Code.eval_string()
 254
 255     {:partial_chain, partial_chain}
 256   end
 257
 258   defp do_transform(%{"tuple" => entity}) do
 259     Enum.reduce(entity, {}, fn val, acc -> Tuple.append(acc, do_transform(val)) end)
 260   end
 261
 262   defp do_transform(entity) when is_map(entity) do
 263     for {k, v} <- entity, into: %{}, do: {do_transform(k), do_transform(v)}
 264   end
 265
 266   defp do_transform(entity) when is_list(entity) do
 267     for v <- entity, into: [], do: do_transform(v)
 268   end
 269
 270   defp do_transform(entity) when is_binary(entity) do
 271     entity
 272     |> String.trim()
 273     |> do_transform_string()
 274   end
 275
 276   defp do_transform(entity), do: entity
 277
 278   defp parse_host("localhost"), do: :localhost
 279
 280   defp parse_host(host) do
 281     charlist = to_charlist(host)
 282
 283     case :inet.parse_address(charlist) do
 284       {:error, :einval} ->
 285         charlist
 286
 287       {:ok, ip} ->
 288         ip
 289     end
 290   end
 291
 292   @delimiters ["/", "|", "\"", "'", {"(", ")"}, {"[", "]"}, {"{", "}"}, {"<", ">"}]
 293
 294   defp find_valid_delimiter([], _string, _),
 295     do: raise(ArgumentError, message: "valid delimiter for Regex expression not found")
 296
 297   defp find_valid_delimiter([{leading, closing} = delimiter | others], pattern, regex_delimiter)
 298        when is_tuple(delimiter) do
 299     if String.contains?(pattern, closing) do
 300       find_valid_delimiter(others, pattern, regex_delimiter)
 301     else
 302       {:ok, {leading, closing}}
 303     end
 304   end
 305
 306   defp find_valid_delimiter([delimiter | others], pattern, regex_delimiter) do
 307     if String.contains?(pattern, delimiter) do
 308       find_valid_delimiter(others, pattern, regex_delimiter)
 309     else
 310       {:ok, {delimiter, delimiter}}
 311     end
 312   end
 313
 314   @regex_parts ~r/^~r(?'delimiter'[\/|"'([{<]{1})(?'pattern'.+)[\/|"')\]}>]{1}(?'modifier'[uismxfU]*)/u
 315
 316   defp do_transform_string("~r" <> _pattern = regex) do
 317     with %{"modifier" => modifier, "pattern" => pattern, "delimiter" => regex_delimiter} <-
 318            Regex.named_captures(@regex_parts, regex),
 319          {:ok, {leading, closing}} <- find_valid_delimiter(@delimiters, pattern, regex_delimiter),
 320          {result, _} <- Code.eval_string("~r#{leading}#{pattern}#{closing}#{modifier}") do
 321       result
 322     end
 323   end
 324
 325   defp do_transform_string(":" <> atom), do: String.to_atom(atom)
 326
 327   defp do_transform_string(value) do
 328     if is_module_name?(value) do
 329       String.to_existing_atom("Elixir." <> value)
 330     else
 331       value
 332     end
 333   end
 334
 335   @spec is_module_name?(String.t()) :: boolean()
 336   def is_module_name?(string) do
 337     Regex.match?(~r/^(Pleroma|Phoenix|Tesla|Quack|Ueberauth)\./, string) or
 338       string in ["Oban", "Ueberauth", "ExSyslogger"]
 339   end
 340 end