git.squeep.com Git - akkoma/blob - lib/pleroma/config/config_db.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.ConfigDB do
   6   use Ecto.Schema
   7   import Ecto.Changeset
   8   import Ecto.Query
   9   import Pleroma.Web.Gettext
  10   alias __MODULE__
  11   alias Pleroma.Repo
  12
  13   @type t :: %__MODULE__{}
  14
  15   schema "config" do
  16     field(:key, :string)
  17     field(:group, :string)
  18     field(:value, :binary)
  19     field(:db, {:array, :string}, virtual: true, default: [])
  20
  21     timestamps()
  22   end
  23
  24   @spec get_all_as_keyword() :: keyword()
  25   def get_all_as_keyword do
  26     ConfigDB
  27     |> select([c], {c.group, c.key, c.value})
  28     |> Repo.all()
  29     |> Enum.reduce([], fn {group, key, value}, acc ->
  30       group = ConfigDB.from_string(group)
  31       key = ConfigDB.from_string(key)
  32       value = from_binary(value)
  33
  34       Keyword.update(acc, group, [{key, value}], &Keyword.merge(&1, [{key, value}]))
  35     end)
  36   end
  37
  38   @spec get_by_params(map()) :: ConfigDB.t() | nil
  39   def get_by_params(params), do: Repo.get_by(ConfigDB, params)
  40
  41   @spec changeset(ConfigDB.t(), map()) :: Changeset.t()
  42   def changeset(config, params \\ %{}) do
  43     params = Map.put(params, :value, transform(params[:value]))
  44
  45     config
  46     |> cast(params, [:key, :group, :value])
  47     |> validate_required([:key, :group, :value])
  48     |> unique_constraint(:key, name: :config_group_key_index)
  49   end
  50
  51   @spec create(map()) :: {:ok, ConfigDB.t()} | {:error, Changeset.t()}
  52   def create(params) do
  53     %ConfigDB{}
  54     |> changeset(params)
  55     |> Repo.insert()
  56   end
  57
  58   @spec update(ConfigDB.t(), map()) :: {:ok, ConfigDB.t()} | {:error, Changeset.t()}
  59   def update(%ConfigDB{} = config, %{value: value}) do
  60     config
  61     |> changeset(%{value: value})
  62     |> Repo.update()
  63   end
  64
  65   @spec get_db_keys(ConfigDB.t()) :: [String.t()]
  66   def get_db_keys(%ConfigDB{} = config) do
  67     config.value
  68     |> ConfigDB.from_binary()
  69     |> get_db_keys(config.key)
  70   end
  71
  72   @spec get_db_keys(keyword(), any()) :: [String.t()]
  73   def get_db_keys(value, key) do
  74     if Keyword.keyword?(value) do
  75       value |> Keyword.keys() |> Enum.map(&convert(&1))
  76     else
  77       [convert(key)]
  78     end
  79   end
  80
  81   @full_subkey_update [
  82     {:pleroma, :assets, :mascots},
  83     {:pleroma, :emoji, :groups},
  84     {:pleroma, :workers, :retries},
  85     {:pleroma, :mrf_subchain, :match_actor},
  86     {:pleroma, :mrf_keyword, :replace}
  87   ]
  88
  89   @spec deep_merge(atom(), atom(), keyword(), keyword()) :: keyword()
  90   def deep_merge(group, key, old_value, new_value) do
  91     old_keys =
  92       old_value
  93       |> Keyword.keys()
  94       |> MapSet.new()
  95
  96     new_keys =
  97       new_value
  98       |> Keyword.keys()
  99       |> MapSet.new()
 100
 101     intersect_keys = old_keys |> MapSet.intersection(new_keys) |> MapSet.to_list()
 102
 103     subkeys = sub_key_full_update(group, key, intersect_keys)
 104
 105     merged_value = DeepMerge.deep_merge(old_value, new_value)
 106
 107     Enum.reduce(subkeys, merged_value, fn subkey, acc ->
 108       Keyword.put(acc, subkey, new_value[subkey])
 109     end)
 110   end
 111
 112   @spec sub_key_full_update?(atom(), atom(), [Keyword.key()]) :: boolean()
 113   def sub_key_full_update?(group, key, subkeys) do
 114     Enum.any?(@full_subkey_update, fn {g, k, subkey} ->
 115       g == group and k == key and subkey in subkeys
 116     end)
 117   end
 118
 119   defp sub_key_full_update(group, key, subkeys) do
 120     Enum.map(@full_subkey_update, fn
 121       {g, k, subkey} when g == group and k == key ->
 122         if subkey in subkeys, do: subkey, else: []
 123
 124       _ ->
 125         []
 126     end)
 127     |> List.flatten()
 128   end
 129
 130   @full_key_update [
 131     {:pleroma, :ecto_repos},
 132     {:quack, :meta},
 133     {:mime, :types},
 134     {:cors_plug, [:max_age, :methods, :expose, :headers]},
 135     {:auto_linker, :opts},
 136     {:swarm, :node_blacklist},
 137     {:logger, :backends}
 138   ]
 139
 140   defp only_full_update?(%ConfigDB{} = config) do
 141     config_group = ConfigDB.from_string(config.group)
 142     config_key = ConfigDB.from_string(config.key)
 143
 144     Enum.any?(@full_key_update, fn
 145       {group, key} when is_list(key) ->
 146         config_group == group and config_key in key
 147
 148       {group, key} ->
 149         config_group == group and config_key == key
 150     end)
 151   end
 152
 153   defp can_be_partially_updated?(%ConfigDB{} = config), do: not only_full_update?(config)
 154
 155   @spec update_or_create(map()) :: {:ok, ConfigDB.t()} | {:error, Changeset.t()}
 156   def update_or_create(params) do
 157     search_opts = Map.take(params, [:group, :key])
 158
 159     with %ConfigDB{} = config <- ConfigDB.get_by_params(search_opts),
 160          {:partial_update, true, config} <-
 161            {:partial_update, can_be_partially_updated?(config), config},
 162          old_value <- from_binary(config.value),
 163          transformed_value <- do_transform(params[:value]),
 164          {:can_be_merged, true, config} <- {:can_be_merged, is_list(transformed_value), config},
 165          new_value <-
 166            deep_merge(
 167              ConfigDB.from_string(config.group),
 168              ConfigDB.from_string(config.key),
 169              old_value,
 170              transformed_value
 171            ) do
 172       ConfigDB.update(config, %{value: new_value})
 173     else
 174       {reason, false, config} when reason in [:partial_update, :can_be_merged] ->
 175         ConfigDB.update(config, params)
 176
 177       nil ->
 178         ConfigDB.create(params)
 179     end
 180   end
 181
 182   @spec delete(map()) :: {:ok, ConfigDB.t()} | {:error, Changeset.t()} | {:ok, nil}
 183   def delete(params) do
 184     search_opts = Map.delete(params, :subkeys)
 185
 186     with %ConfigDB{} = config <- ConfigDB.get_by_params(search_opts),
 187          {config, sub_keys} when is_list(sub_keys) <- {config, params[:subkeys]},
 188          old_value <- from_binary(config.value),
 189          keys <- Enum.map(sub_keys, &do_transform_string(&1)),
 190          new_value <- Keyword.drop(old_value, keys) do
 191       ConfigDB.update(config, %{value: new_value})
 192     else
 193       {config, nil} ->
 194         Repo.delete(config)
 195         {:ok, nil}
 196
 197       nil ->
 198         err =
 199           dgettext("errors", "Config with params %{params} not found", params: inspect(params))
 200
 201         {:error, err}
 202     end
 203   end
 204
 205   @spec from_binary(binary()) :: term()
 206   def from_binary(binary), do: :erlang.binary_to_term(binary)
 207
 208   @spec from_binary_with_convert(binary()) :: any()
 209   def from_binary_with_convert(binary) do
 210     binary
 211     |> from_binary()
 212     |> do_convert()
 213   end
 214
 215   @spec from_string(String.t()) :: atom() | no_return()
 216   def from_string(":" <> entity), do: String.to_existing_atom(entity)
 217
 218   def from_string(entity) when is_binary(entity) do
 219     if is_module_name?(entity) do
 220       String.to_existing_atom("Elixir.#{entity}")
 221     else
 222       entity
 223     end
 224   end
 225
 226   @spec convert(any()) :: any()
 227   def convert(entity), do: do_convert(entity)
 228
 229   defp do_convert(entity) when is_list(entity) do
 230     for v <- entity, into: [], do: do_convert(v)
 231   end
 232
 233   defp do_convert(%Regex{} = entity), do: inspect(entity)
 234
 235   defp do_convert(entity) when is_map(entity) do
 236     for {k, v} <- entity, into: %{}, do: {do_convert(k), do_convert(v)}
 237   end
 238
 239   defp do_convert({:proxy_url, {type, :localhost, port}}) do
 240     %{"tuple" => [":proxy_url", %{"tuple" => [do_convert(type), "localhost", port]}]}
 241   end
 242
 243   defp do_convert({:proxy_url, {type, host, port}}) when is_tuple(host) do
 244     ip =
 245       host
 246       |> :inet_parse.ntoa()
 247       |> to_string()
 248
 249     %{
 250       "tuple" => [
 251         ":proxy_url",
 252         %{"tuple" => [do_convert(type), ip, port]}
 253       ]
 254     }
 255   end
 256
 257   defp do_convert({:proxy_url, {type, host, port}}) do
 258     %{
 259       "tuple" => [
 260         ":proxy_url",
 261         %{"tuple" => [do_convert(type), to_string(host), port]}
 262       ]
 263     }
 264   end
 265
 266   # TODO: will become useless after removing hackney
 267   defp do_convert({:partial_chain, entity}), do: %{"tuple" => [":partial_chain", inspect(entity)]}
 268
 269   defp do_convert(entity) when is_tuple(entity),
 270     do: %{"tuple" => do_convert(Tuple.to_list(entity))}
 271
 272   defp do_convert(entity) when is_boolean(entity) or is_number(entity) or is_nil(entity),
 273     do: entity
 274
 275   defp do_convert(entity)
 276        when is_atom(entity) and entity in [:"tlsv1.1", :"tlsv1.2", :"tlsv1.3"] do
 277     ":#{to_string(entity)}"
 278   end
 279
 280   defp do_convert(entity) when is_atom(entity), do: inspect(entity)
 281
 282   defp do_convert(entity) when is_binary(entity), do: entity
 283
 284   @spec transform(any()) :: binary() | no_return()
 285   def transform(entity) when is_binary(entity) or is_map(entity) or is_list(entity) do
 286     entity
 287     |> do_transform()
 288     |> to_binary()
 289   end
 290
 291   def transform(entity), do: to_binary(entity)
 292
 293   @spec transform_with_out_binary(any()) :: any()
 294   def transform_with_out_binary(entity), do: do_transform(entity)
 295
 296   @spec to_binary(any()) :: binary()
 297   def to_binary(entity), do: :erlang.term_to_binary(entity)
 298
 299   defp do_transform(%Regex{} = entity), do: entity
 300
 301   defp do_transform(%{"tuple" => [":proxy_url", %{"tuple" => [type, host, port]}]}) do
 302     {:proxy_url, {do_transform_string(type), parse_host(host), port}}
 303   end
 304
 305   # TODO: will become useless after removing hackney
 306   defp do_transform(%{"tuple" => [":partial_chain", entity]}) do
 307     {partial_chain, []} =
 308       entity
 309       |> String.replace(~r/[^\w|^{:,[|^,|^[|^\]^}|^\/|^\.|^"]^\s/, "")
 310       |> Code.eval_string()
 311
 312     {:partial_chain, partial_chain}
 313   end
 314
 315   defp do_transform(%{"tuple" => entity}) do
 316     Enum.reduce(entity, {}, fn val, acc -> Tuple.append(acc, do_transform(val)) end)
 317   end
 318
 319   defp do_transform(entity) when is_map(entity) do
 320     for {k, v} <- entity, into: %{}, do: {do_transform(k), do_transform(v)}
 321   end
 322
 323   defp do_transform(entity) when is_list(entity) do
 324     for v <- entity, into: [], do: do_transform(v)
 325   end
 326
 327   defp do_transform(entity) when is_binary(entity) do
 328     entity
 329     |> String.trim()
 330     |> do_transform_string()
 331   end
 332
 333   defp do_transform(entity), do: entity
 334
 335   defp parse_host("localhost"), do: :localhost
 336
 337   defp parse_host(host) do
 338     charlist = to_charlist(host)
 339
 340     case :inet.parse_address(charlist) do
 341       {:error, :einval} ->
 342         charlist
 343
 344       {:ok, ip} ->
 345         ip
 346     end
 347   end
 348
 349   @delimiters ["/", "|", "\"", "'", {"(", ")"}, {"[", "]"}, {"{", "}"}, {"<", ">"}]
 350
 351   defp find_valid_delimiter([], _string, _),
 352     do: raise(ArgumentError, message: "valid delimiter for Regex expression not found")
 353
 354   defp find_valid_delimiter([{leading, closing} = delimiter | others], pattern, regex_delimiter)
 355        when is_tuple(delimiter) do
 356     if String.contains?(pattern, closing) do
 357       find_valid_delimiter(others, pattern, regex_delimiter)
 358     else
 359       {:ok, {leading, closing}}
 360     end
 361   end
 362
 363   defp find_valid_delimiter([delimiter | others], pattern, regex_delimiter) do
 364     if String.contains?(pattern, delimiter) do
 365       find_valid_delimiter(others, pattern, regex_delimiter)
 366     else
 367       {:ok, {delimiter, delimiter}}
 368     end
 369   end
 370
 371   @regex_parts ~r/^~r(?'delimiter'[\/|"'([{<]{1})(?'pattern'.+)[\/|"')\]}>]{1}(?'modifier'[uismxfU]*)/u
 372
 373   defp do_transform_string("~r" <> _pattern = regex) do
 374     with %{"modifier" => modifier, "pattern" => pattern, "delimiter" => regex_delimiter} <-
 375            Regex.named_captures(@regex_parts, regex),
 376          {:ok, {leading, closing}} <- find_valid_delimiter(@delimiters, pattern, regex_delimiter),
 377          {result, _} <- Code.eval_string("~r#{leading}#{pattern}#{closing}#{modifier}") do
 378       result
 379     end
 380   end
 381
 382   defp do_transform_string(":" <> atom), do: String.to_atom(atom)
 383
 384   defp do_transform_string(value) do
 385     if is_module_name?(value) do
 386       String.to_existing_atom("Elixir." <> value)
 387     else
 388       value
 389     end
 390   end
 391
 392   @spec is_module_name?(String.t()) :: boolean()
 393   def is_module_name?(string) do
 394     Regex.match?(~r/^(Pleroma|Phoenix|Tesla|Quack|Ueberauth)\./, string) or
 395       string in ["Oban", "Ueberauth", "ExSyslogger"]
 396   end
 397 end