git.squeep.com Git - akkoma/blob - lib/pleroma/config/config_db.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.ConfigDB do
   6   use Ecto.Schema
   7   import Ecto.Changeset
   8   import Ecto.Query
   9   import Pleroma.Web.Gettext
  10   alias __MODULE__
  11   alias Pleroma.Repo
  12
  13   @type t :: %__MODULE__{}
  14
  15   schema "config" do
  16     field(:key, :string)
  17     field(:group, :string)
  18     field(:value, :binary)
  19
  20     timestamps()
  21   end
  22
  23   @spec get_all_as_keyword() :: keyword()
  24   def get_all_as_keyword do
  25     ConfigDB
  26     |> select([c], {c.group, c.key, c.value})
  27     |> Repo.all()
  28     |> Enum.reduce([], fn {group, key, value}, acc ->
  29       group = ConfigDB.from_string(group)
  30       key = ConfigDB.from_string(key)
  31       value = from_binary(value)
  32
  33       Keyword.update(acc, group, [{key, value}], &Keyword.merge(&1, [{key, value}]))
  34     end)
  35   end
  36
  37   @spec get_by_params(map()) :: ConfigDB.t() | nil
  38   def get_by_params(params), do: Repo.get_by(ConfigDB, params)
  39
  40   @spec changeset(ConfigDB.t(), map()) :: Changeset.t()
  41   def changeset(config, params \\ %{}) do
  42     params = Map.put(params, :value, transform(params[:value]))
  43
  44     config
  45     |> cast(params, [:key, :group, :value])
  46     |> validate_required([:key, :group, :value])
  47     |> unique_constraint(:key, name: :config_group_key_index)
  48   end
  49
  50   @spec create(map()) :: {:ok, ConfigDB.t()} | {:error, Changeset.t()}
  51   def create(params) do
  52     %ConfigDB{}
  53     |> changeset(params)
  54     |> Repo.insert()
  55   end
  56
  57   @spec update(ConfigDB.t(), map()) :: {:ok, ConfigDB.t()} | {:error, Changeset.t()}
  58   def update(%ConfigDB{} = config, %{value: value}) do
  59     config
  60     |> changeset(%{value: value})
  61     |> Repo.update()
  62   end
  63
  64   @full_key_update [
  65     {:pleroma, :ecto_repos},
  66     {:pleroma, :assets},
  67     {:quack, :meta},
  68     {:mime, :types},
  69     {:cors_plug, [:max_age, :methods, :expose, :headers]},
  70     {:auto_linker, :opts},
  71     {:swarm, :node_blacklist},
  72     {:logger, :backends}
  73   ]
  74
  75   defp only_full_update?(%ConfigDB{} = config) do
  76     config_group = ConfigDB.from_string(config.group)
  77     config_key = ConfigDB.from_string(config.key)
  78
  79     Enum.any?(@full_key_update, fn
  80       {group, key} when is_list(key) ->
  81         config_group == group and config_key in key
  82
  83       {group, key} ->
  84         config_group == group and config_key == key
  85     end)
  86   end
  87
  88   defp can_be_partially_updated?(%ConfigDB{} = config), do: not only_full_update?(config)
  89
  90   @spec update_or_create(map()) :: {:ok, ConfigDB.t()} | {:error, Changeset.t()}
  91   def update_or_create(params) do
  92     search_opts = Map.take(params, [:group, :key])
  93
  94     with %ConfigDB{} = config <- ConfigDB.get_by_params(search_opts),
  95          {:partial_update, true, config} <-
  96            {:partial_update, can_be_partially_updated?(config), config},
  97          old_value <- from_binary(config.value),
  98          transformed_value <- do_transform(params[:value]),
  99          {:can_be_merged, true, config} <- {:can_be_merged, is_list(transformed_value), config},
 100          new_value <- DeepMerge.deep_merge(old_value, transformed_value) do
 101       ConfigDB.update(config, %{value: new_value, transformed?: true})
 102     else
 103       {reason, false, config} when reason in [:partial_update, :can_be_merged] ->
 104         ConfigDB.update(config, params)
 105
 106       nil ->
 107         ConfigDB.create(params)
 108     end
 109   end
 110
 111   @spec delete(map()) :: {:ok, ConfigDB.t()} | {:error, Changeset.t()} | {:ok, nil}
 112   def delete(params) do
 113     search_opts = Map.delete(params, :subkeys)
 114
 115     with %ConfigDB{} = config <- ConfigDB.get_by_params(search_opts),
 116          {config, sub_keys} when is_list(sub_keys) <- {config, params[:subkeys]},
 117          old_value <- from_binary(config.value),
 118          keys <- Enum.map(sub_keys, &do_transform_string(&1)),
 119          new_value <- Keyword.drop(old_value, keys) do
 120       ConfigDB.update(config, %{value: new_value})
 121     else
 122       {config, nil} ->
 123         Repo.delete(config)
 124         {:ok, nil}
 125
 126       nil ->
 127         err =
 128           dgettext("errors", "Config with params %{params} not found", params: inspect(params))
 129
 130         {:error, err}
 131     end
 132   end
 133
 134   @spec from_binary(binary()) :: term()
 135   def from_binary(binary), do: :erlang.binary_to_term(binary)
 136
 137   @spec from_binary_with_convert(binary()) :: any()
 138   def from_binary_with_convert(binary) do
 139     binary
 140     |> from_binary()
 141     |> do_convert()
 142   end
 143
 144   @spec from_string(String.t()) :: atom() | no_return()
 145   def from_string(":" <> entity), do: String.to_existing_atom(entity)
 146
 147   def from_string(entity) when is_binary(entity) do
 148     if is_module_name?(entity) do
 149       String.to_existing_atom("Elixir.#{entity}")
 150     else
 151       entity
 152     end
 153   end
 154
 155   @spec convert(any()) :: any()
 156   def convert(entity), do: do_convert(entity)
 157
 158   defp do_convert(entity) when is_list(entity) do
 159     for v <- entity, into: [], do: do_convert(v)
 160   end
 161
 162   defp do_convert(%Regex{} = entity), do: inspect(entity)
 163
 164   defp do_convert(entity) when is_map(entity) do
 165     for {k, v} <- entity, into: %{}, do: {do_convert(k), do_convert(v)}
 166   end
 167
 168   defp do_convert({:proxy_url, {type, :localhost, port}}) do
 169     %{"tuple" => [":proxy_url", %{"tuple" => [do_convert(type), "localhost", port]}]}
 170   end
 171
 172   defp do_convert({:proxy_url, {type, host, port}}) when is_tuple(host) do
 173     ip =
 174       host
 175       |> :inet_parse.ntoa()
 176       |> to_string()
 177
 178     %{
 179       "tuple" => [
 180         ":proxy_url",
 181         %{"tuple" => [do_convert(type), ip, port]}
 182       ]
 183     }
 184   end
 185
 186   defp do_convert({:proxy_url, {type, host, port}}) do
 187     %{
 188       "tuple" => [
 189         ":proxy_url",
 190         %{"tuple" => [do_convert(type), to_string(host), port]}
 191       ]
 192     }
 193   end
 194
 195   # TODO: will become useless after removing hackney
 196   defp do_convert({:partial_chain, entity}), do: %{"tuple" => [":partial_chain", inspect(entity)]}
 197
 198   defp do_convert(entity) when is_tuple(entity),
 199     do: %{"tuple" => do_convert(Tuple.to_list(entity))}
 200
 201   defp do_convert(entity) when is_boolean(entity) or is_number(entity) or is_nil(entity),
 202     do: entity
 203
 204   defp do_convert(entity)
 205        when is_atom(entity) and entity in [:"tlsv1.1", :"tlsv1.2", :"tlsv1.3"] do
 206     ":#{to_string(entity)}"
 207   end
 208
 209   defp do_convert(entity) when is_atom(entity), do: inspect(entity)
 210
 211   defp do_convert(entity) when is_binary(entity), do: entity
 212
 213   @spec transform(any()) :: binary() | no_return()
 214   def transform(entity) when is_binary(entity) or is_map(entity) or is_list(entity) do
 215     entity
 216     |> do_transform()
 217     |> to_binary()
 218   end
 219
 220   def transform(entity), do: to_binary(entity)
 221
 222   @spec to_binary(any()) :: binary()
 223   def to_binary(entity), do: :erlang.term_to_binary(entity)
 224
 225   defp do_transform(%Regex{} = entity), do: entity
 226
 227   defp do_transform(%{"tuple" => [":proxy_url", %{"tuple" => [type, host, port]}]}) do
 228     {:proxy_url, {do_transform_string(type), parse_host(host), port}}
 229   end
 230
 231   # TODO: will become useless after removing hackney
 232   defp do_transform(%{"tuple" => [":partial_chain", entity]}) do
 233     {partial_chain, []} =
 234       entity
 235       |> String.replace(~r/[^\w|^{:,[|^,|^[|^\]^}|^\/|^\.|^"]^\s/, "")
 236       |> Code.eval_string()
 237
 238     {:partial_chain, partial_chain}
 239   end
 240
 241   defp do_transform(%{"tuple" => entity}) do
 242     Enum.reduce(entity, {}, fn val, acc -> Tuple.append(acc, do_transform(val)) end)
 243   end
 244
 245   defp do_transform(entity) when is_map(entity) do
 246     for {k, v} <- entity, into: %{}, do: {do_transform(k), do_transform(v)}
 247   end
 248
 249   defp do_transform(entity) when is_list(entity) do
 250     for v <- entity, into: [], do: do_transform(v)
 251   end
 252
 253   defp do_transform(entity) when is_binary(entity) do
 254     entity
 255     |> String.trim()
 256     |> do_transform_string()
 257   end
 258
 259   defp do_transform(entity), do: entity
 260
 261   defp parse_host("localhost"), do: :localhost
 262
 263   defp parse_host(host) do
 264     charlist = to_charlist(host)
 265
 266     case :inet.parse_address(charlist) do
 267       {:error, :einval} ->
 268         charlist
 269
 270       {:ok, ip} ->
 271         ip
 272     end
 273   end
 274
 275   @delimiters ["/", "|", "\"", "'", {"(", ")"}, {"[", "]"}, {"{", "}"}, {"<", ">"}]
 276
 277   defp find_valid_delimiter([], _string, _),
 278     do: raise(ArgumentError, message: "valid delimiter for Regex expression not found")
 279
 280   defp find_valid_delimiter([{leading, closing} = delimiter | others], pattern, regex_delimiter)
 281        when is_tuple(delimiter) do
 282     if String.contains?(pattern, closing) do
 283       find_valid_delimiter(others, pattern, regex_delimiter)
 284     else
 285       {:ok, {leading, closing}}
 286     end
 287   end
 288
 289   defp find_valid_delimiter([delimiter | others], pattern, regex_delimiter) do
 290     if String.contains?(pattern, delimiter) do
 291       find_valid_delimiter(others, pattern, regex_delimiter)
 292     else
 293       {:ok, {delimiter, delimiter}}
 294     end
 295   end
 296
 297   @regex_parts ~r/^~r(?'delimiter'[\/|"'([{<]{1})(?'pattern'.+)[\/|"')\]}>]{1}(?'modifier'[uismxfU]*)/u
 298
 299   defp do_transform_string("~r" <> _pattern = regex) do
 300     with %{"modifier" => modifier, "pattern" => pattern, "delimiter" => regex_delimiter} <-
 301            Regex.named_captures(@regex_parts, regex),
 302          {:ok, {leading, closing}} <- find_valid_delimiter(@delimiters, pattern, regex_delimiter),
 303          {result, _} <- Code.eval_string("~r#{leading}#{pattern}#{closing}#{modifier}") do
 304       result
 305     end
 306   end
 307
 308   defp do_transform_string(":" <> atom), do: String.to_atom(atom)
 309
 310   defp do_transform_string(value) do
 311     if is_module_name?(value) do
 312       String.to_existing_atom("Elixir." <> value)
 313     else
 314       value
 315     end
 316   end
 317
 318   @spec is_module_name?(String.t()) :: boolean()
 319   def is_module_name?(string) do
 320     Regex.match?(~r/^(Pleroma|Phoenix|Tesla|Quack)\./, string) or
 321       string in ["Oban", "Ueberauth", "ExSyslogger"]
 322   end
 323 end