git.squeep.com Git - akkoma/blob - lib/pleroma/captcha/kocaptcha.ex

   1 defmodule Pleroma.Captcha.Kocaptcha do
   2   alias Plug.Crypto.KeyGenerator
   3   alias Plug.Crypto.MessageEncryptor
   4   alias Calendar.DateTime
   5
   6   alias Pleroma.Captcha.Service
   7   @behaviour Service
   8
   9   @impl Service
  10   def new() do
  11     endpoint = Pleroma.Config.get!([__MODULE__, :endpoint])
  12
  13     case Tesla.get(endpoint <> "/new") do
  14       {:error, _} ->
  15         %{error: "Kocaptcha service unavailable"}
  16
  17       {:ok, res} ->
  18         json_resp = Poison.decode!(res.body)
  19
  20         token = json_resp["token"]
  21         answer_md5 = json_resp["md5"]
  22
  23         secret_key_base = Pleroma.Config.get!([Pleroma.Web.Endpoint, :secret_key_base])
  24
  25         # This make salt a little different for two keys
  26         secret = KeyGenerator.generate(secret_key_base, token <> "_encrypt")
  27         sign_secret = KeyGenerator.generate(secret_key_base, token <> "_sign")
  28         # Basicallty copy what Phoenix.Token does here, add the time to
  29         # the actual data and make it a binary to then encrypt it
  30         encrypted_captcha_answer =
  31           %{
  32             at: DateTime.now_utc(),
  33             answer_md5: answer_md5
  34           }
  35           |> :erlang.term_to_binary()
  36           |> MessageEncryptor.encrypt(secret, sign_secret)
  37
  38         %{
  39           type: :kocaptcha,
  40           token: token,
  41           url: endpoint <> json_resp["url"],
  42           answer_data: encrypted_captcha_answer
  43         }
  44     end
  45   end
  46
  47   @impl Service
  48   def validate(token, captcha, answer_data) do
  49     secret_key_base = Pleroma.Config.get!([Pleroma.Web.Endpoint, :secret_key_base])
  50     secret = KeyGenerator.generate(secret_key_base, token <> "_encrypt")
  51     sign_secret = KeyGenerator.generate(secret_key_base, token <> "_sign")
  52
  53     # If the time found is less than (current_time - seconds_valid), then the time has already passed.
  54     # Later we check that the time found is more than the presumed invalidatation time, that means
  55     # that the data is still valid and the captcha can be checked
  56     seconds_valid = Pleroma.Config.get!([Pleroma.Captcha, :seconds_valid])
  57     valid_if_after = DateTime.subtract!(DateTime.now_utc(), seconds_valid)
  58
  59     with {:ok, data} <- MessageEncryptor.decrypt(answer_data, secret, sign_secret),
  60          %{at: at, answer_md5: answer_md5} <- :erlang.binary_to_term(data) do
  61       if DateTime.after?(at, valid_if_after) do
  62         if not is_nil(captcha) and
  63              :crypto.hash(:md5, captcha) |> Base.encode16() == String.upcase(answer_md5),
  64            do: :ok,
  65            else: {:error, "Invalid CAPTCHA"}
  66       else
  67         {:error, "CAPTCHA expired"}
  68       end
  69     else
  70       _ -> {:error, "Invalid answer data"}
  71     end
  72   end
  73 end