git.squeep.com Git - akkoma/blob - lib/pleroma/captcha/kocaptcha.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2018 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Captcha.Kocaptcha do
   6   alias Calendar.DateTime
   7
   8   alias Pleroma.Captcha.Service
   9   @behaviour Service
  10
  11   @ets __MODULE__.Ets
  12
  13   @impl Service
  14   def new() do
  15     endpoint = Pleroma.Config.get!([__MODULE__, :endpoint])
  16
  17     case Tesla.get(endpoint <> "/new") do
  18       {:error, _} ->
  19         %{error: "Kocaptcha service unavailable"}
  20
  21       {:ok, res} ->
  22         json_resp = Poison.decode!(res.body)
  23
  24         token = json_resp["token"]
  25
  26         true =
  27           :ets.insert(
  28             @ets,
  29             {token, json_resp["md5"], DateTime.now_utc() |> DateTime.Format.unix()}
  30           )
  31
  32         %{type: :kocaptcha, token: token, url: endpoint <> json_resp["url"]}
  33     end
  34   end
  35
  36   @impl Service
  37   def validate(token, captcha) do
  38     with false <- is_nil(captcha),
  39          [{^token, saved_md5, _}] <- :ets.lookup(@ets, token),
  40          true <- :crypto.hash(:md5, captcha) |> Base.encode16() == String.upcase(saved_md5) do
  41       # Clear the saved value
  42       :ets.delete(@ets, token)
  43
  44       true
  45     else
  46       _ -> false
  47     end
  48   end
  49
  50   @impl Service
  51   def cleanup() do
  52     seconds_retained = Pleroma.Config.get!([Pleroma.Captcha, :seconds_retained])
  53     # If the time in ETS is less than current_time - seconds_retained, then the time has
  54     # already passed
  55     delete_after =
  56       DateTime.subtract!(DateTime.now_utc(), seconds_retained) |> DateTime.Format.unix()
  57
  58     :ets.select_delete(
  59       @ets,
  60       [
  61         {
  62           {:_, :_, :"$1"},
  63           [{:<, :"$1", {:const, delete_after}}],
  64           [true]
  65         }
  66       ]
  67     )
  68
  69     :ok
  70   end
  71 end