git.squeep.com Git - akkoma/blob - lib/pleroma/bbs/handler.ex

   1 defmodule Pleroma.BBS.Handler do
   2   use Sshd.ShellHandler
   3   alias Pleroma.Activity
   4   alias Pleroma.Web.ActivityPub.ActivityPub
   5   alias Pleroma.Web.CommonAPI
   6
   7   def on_shell(username, _pubkey, _ip, _port) do
   8     :ok = IO.puts("Welcome to #{Pleroma.Config.get([:instance, :name])}!")
   9     user = Pleroma.User.get_cached_by_nickname(to_string(username))
  10     Logger.debug("#{inspect(user)}")
  11     loop(run_state(user: user))
  12   end
  13
  14   def on_connect(username, ip, port, method) do
  15     Logger.debug(fn ->
  16       """
  17       Incoming SSH shell #{inspect(self())} requested for #{username} from #{inspect(ip)}:#{
  18         inspect(port)
  19       } using #{inspect(method)}
  20       """
  21     end)
  22   end
  23
  24   def on_disconnect(username, ip, port) do
  25     Logger.debug(fn ->
  26       "Disconnecting SSH shell for #{username} from #{inspect(ip)}:#{inspect(port)}"
  27     end)
  28   end
  29
  30   defp loop(state) do
  31     self_pid = self()
  32     counter = state.counter
  33     prefix = state.prefix
  34     user = state.user
  35
  36     input = spawn(fn -> io_get(self_pid, prefix, counter, user.nickname) end)
  37     wait_input(state, input)
  38   end
  39
  40   def puts_activity(activity) do
  41     status = Pleroma.Web.MastodonAPI.StatusView.render("status.json", %{activity: activity})
  42     IO.puts("-- #{status.id} by #{status.account.display_name} (#{status.account.acct})")
  43     IO.puts(HtmlSanitizeEx.strip_tags(status.content))
  44     IO.puts("")
  45   end
  46
  47   def handle_command(state, "help") do
  48     IO.puts("Available commands:")
  49     IO.puts("help - This help")
  50     IO.puts("home - Show the home timeline")
  51     IO.puts("p <text> - Post the given text")
  52     IO.puts("r <id> <text> - Reply to the post with the given id")
  53     IO.puts("quit - Quit")
  54
  55     state
  56   end
  57
  58   def handle_command(%{user: user} = state, "r " <> text) do
  59     text = String.trim(text)
  60     [activity_id, rest] = String.split(text, " ", parts: 2)
  61
  62     with %Activity{} <- Activity.get_by_id(activity_id),
  63          {:ok, _activity} <-
  64            CommonAPI.post(user, %{"status" => rest, "in_reply_to_status_id" => activity_id}) do
  65       IO.puts("Replied!")
  66     else
  67       _e -> IO.puts("Could not reply...")
  68     end
  69
  70     state
  71   end
  72
  73   def handle_command(%{user: user} = state, "p " <> text) do
  74     text = String.trim(text)
  75
  76     with {:ok, _activity} <- CommonAPI.post(user, %{"status" => text}) do
  77       IO.puts("Posted!")
  78     else
  79       _e -> IO.puts("Could not post...")
  80     end
  81
  82     state
  83   end
  84
  85   def handle_command(state, "home") do
  86     user = state.user
  87
  88     params =
  89       %{}
  90       |> Map.put("type", ["Create"])
  91       |> Map.put("blocking_user", user)
  92       |> Map.put("muting_user", user)
  93       |> Map.put("user", user)
  94
  95     activities =
  96       [user.ap_id | user.following]
  97       |> ActivityPub.fetch_activities(params)
  98
  99     Enum.each(activities, fn activity ->
 100       puts_activity(activity)
 101     end)
 102
 103     state
 104   end
 105
 106   def handle_command(state, command) do
 107     IO.puts("Unknown command '#{command}'")
 108     state
 109   end
 110
 111   defp wait_input(state, input) do
 112     receive do
 113       {:input, ^input, "quit\n"} ->
 114         IO.puts("Exiting...")
 115
 116       {:input, ^input, code} when is_binary(code) ->
 117         code = String.trim(code)
 118
 119         state = handle_command(state, code)
 120
 121         loop(%{state | counter: state.counter + 1})
 122
 123       {:error, :interrupted} ->
 124         IO.puts("Caught Ctrl+C...")
 125         loop(%{state | counter: state.counter + 1})
 126
 127       {:input, ^input, msg} ->
 128         :ok = Logger.warn("received unknown message: #{inspect(msg)}")
 129         loop(%{state | counter: state.counter + 1})
 130     end
 131   end
 132
 133   defp run_state(opts) do
 134     %{prefix: "pleroma", counter: 1, user: opts[:user]}
 135   end
 136
 137   defp io_get(pid, prefix, counter, username) do
 138     prompt = prompt(prefix, counter, username)
 139     send(pid, {:input, self(), IO.gets(:stdio, prompt)})
 140   end
 141
 142   defp prompt(prefix, counter, username) do
 143     prompt = "#{username}@#{prefix}:#{counter}>"
 144     prompt <> " "
 145   end
 146 end